Listing Functions in a script with the line number too.

[guinness]

UEZ asked me in the thread if I could find a way to monitor what Function the caret was inside, I said I would happily find out but didn't want to affect performance.

So my question is can the following code be improved in anyway? It finds the functions and then enumerates through the lines to find the function line number. Thanks.

This works, but I would like to see a different approach.

#include <Array.au3>
#include <File.au3>

Local $aFuncsToLine = _FuncsToLine('SciTE Jump.au3')
_ArrayDisplay($aFuncsToLine)

Func _FuncsToLine($sFilePath)
    Local $aArray = StringRegExp(StringRegExpReplace(FileRead($sFilePath), '(?ims)#cs[^#]+#ce', ''), '(?ims)^s*Funcs*([^(]*)', 3), $aRead[1][2] = [[0, 2]]
    If @error Then
        Return SetError(1, 0, $aRead)
    EndIf
    Local $iFunctions = UBound($aArray, 1)

    _FileReadToArray($sFilePath, $aRead)

    Local $aReturn[$iFunctions + 1][2] = [[0, 2]]
    For $i = 0 To $iFunctions - 1 ; Enumerate through the Functions.
        For $j = 1 To $aRead[0] ; Enumerate through the Script to find the line number.
            If StringInStr($aRead[$j], 'Func ' & $aArray[$i] & '(', 2, 1) Then ; If the Function name appears on that line once then add to the array.
                $aReturn[0][0] += 1 ; Increase index 0 by 1.
                $aReturn[$aReturn[0][0]][0] = $aArray[$i] ; Add the Function name to the next available index.
                $aReturn[$aReturn[0][0]][1] = $j ; Add the line number to the next available index.
                ExitLoop ; Exit the loop as we found a line number.
            EndIf
        Next
    Next
    Return $aReturn
EndFunc   ;==>_FuncsToLine

Edited April 26, 2012 by guinness

[Mat]

Combine the two would be better, go through each line and then check if its a function definition, then add it to the array. That way you are only looping through the file once. I'd also store where the corresponding EndFunc is so that you know if the caret is in the global scope between two functions.

Currently you are in effect finding all the functions twice, and reading the file twice.

[guinness]

Yeh good point, I wasn't thinking 'out the box' on this one. Cheers Mat.

Edited April 26, 2012 by guinness

[guinness]

Here >>

#include <Array.au3>
#include <File.au3>

Local $aFuncsToLine = _FuncsToLine('SciTE Jump.au3')
_ArrayDisplay($aFuncsToLine)

Func _FuncsToLine($sFilePath)
    Local $aRead = 0
    _FileReadToArray($sFilePath, $aRead)

    Local $aReturn[$aRead[0] + 1][3] = [[0, 3]]
    For $j = 1 To $aRead[0] ; Enumerate through the Script to find the line number.
        If StringLeft($aRead[$j], 4) == 'Func' Then ; If the Function name appears on that line once then add to the array.
            $aReturn[0][0] += 1 ; Increase index 0 by 1.
            $aReturn[$aReturn[0][0]][0] = StringRegExpReplace($aRead[$j], 's*Funcs*(.*)(.*', '1') ; Add the Function name to the next available index.
            $aReturn[$aReturn[0][0]][1] = $j ; Add the line number to the next available index..
        EndIf
        If StringLeft($aRead[$j], 7) == 'EndFunc' Then ; If the EndFunc is found the store the line number.
            $aReturn[$aReturn[0][0]][2] = $j
        EndIf
    Next
    ReDim $aReturn[$aReturn[0][0] + 1][$aReturn[0][1]]
    Return $aReturn
EndFunc   ;==>_FuncsToLine

[Mat]

Few more points to consider for the future:

• Func can appear at the beginning of the line in other places... `FuncFoo = 42` is a valid local assignment in the latest alpha. You need to check for whitespace afterwards, which could be a tab?
• There can be whitespace before the Func keyword. You want to StringStripWS for leading (and less importantly, trailing)
• You have lost your #cs and #ce support now.
• Technically you could use a line continuation character in a function definition... Func _ (CRLF) MyFunction
• Might be worth adding basic error checking for functions within functions, and EndFuncs without matching Funcs (and vice versa).

But it looks good otherwise The above cases should be in the minority (if present at all) but I guess its better to do it properly first time

[guinness]

You have some some valid points there and it was something I quickly put together as you can tell. The only one I'm not bothered about is the #cs...#ce support as those functions shouldn't show in the list. I'm also taking into consideration people using Jos' Tidy too. But cheers Mat, I'll work on this over the course of tonight.

[UEZ]

My 1st idea (might be silly):

expandcollapse popup

#include <array.au3>
#include <file.au3>

;~ Local $aFuncsToLine = _FuncsToLine('SciTE Jump.au3')
;~ _ArrayDisplay($aFuncsToLine)

$aResult = _FuncLines('SciTE Jump.au3')
_ArrayDisplay($aResult)

Func _FuncsToLine($sFilePath)
    Local $aRead = 0
    _FileReadToArray($sFilePath, $aRead)
    _ArrayDisplay($aRead)

    Local $aReturn[$aRead[0] + 1][3] = [[0, 3]]
    For $j = 1 To $aRead[0] ; Enumerate through the Script to find the line number.
        If StringLeft($aRead[$j], 4) == 'Func' Then ; If the Function name appears on that line once then add to the array.
            $aReturn[0][0] += 1 ; Increase index 0 by 1.
            $aReturn[$aReturn[0][0]][0] = StringRegExpReplace($aRead[$j], 's*Funcs*(.*)(.*', '1') ; Add the Function name to the next available index.
            $aReturn[$aReturn[0][0]][1] = $j ; Add the line number to the next available index..
        EndIf
        If StringLeft($aRead[$j], 7) == 'EndFunc' Then ; If the EndFunc is found the store the line number.
            $aReturn[$aReturn[0][0]][2] = $j
        EndIf
    Next
    ReDim $aReturn[$aReturn[0][0] + 1][$aReturn[0][1]]
    Return $aReturn
EndFunc   ;==>_FuncsToLine

Func _FuncLines($sCode)
    Local $aCode, $aTmp, $sFuncName
    _FileReadToArray($sCode, $aCode)
    Local $aFunctions[$aCode[0] + 1]
    For $i = 1 To $aCode[0]
        $aTmp = StringRegExp($aCode[$i], "(?i).*Funcs+(.*)(", 1)
        If Not @error Then $sFuncName = $aTmp[0]
        $aFunctions[$i] = $sFuncName
        If StringRegExp($aCode[$i], "(?i).*EndFuncs*", 0) Then $sFuncName = ""
    Next
    Return $aFunctions
EndFunc

Write in each Array cell the function name, read out caret position in SciTE and jump to array[caret pos] to get the function name.

When the number of lines has changed in SciTE renew the array.

Br,

UEZ

Edited April 26, 2012 by UEZ

[guinness]

UEZ,

Very nice, a slightly different approach and perhaps a faster one too as I don't have to enumerate through the array each time.

What about this instead?

#include <Array.au3>
#include <File.au3>

Local $aResult = _FuncLines('SciTE Jump.au3')
_ArrayDisplay($aResult)

Func _FuncLines($sFilePath) ; By UEZ.
    Local $aArray, $aFunctions, $aReturn, $sFuncName
    _FileReadToArray($sFilePath, $aArray)
    _AssociativeArray_Startup($aFunctions)
    For $i = 1 To $aArray[0]
        $aReturn = StringRegExp($aArray[$i], "(?i).*Funcs+(.*)(", 1)
        If (Not @error) Then
            $sFuncName = $aReturn[0]
        EndIf
        $aFunctions($i) = $sFuncName
        If StringRegExp($aArray[$i], "(?i).*EndFuncs*", 0) Then
            $sFuncName = ""
        EndIf
    Next
    Return $aFunctions.Items()
EndFunc   ;==>_FuncLines

Func _AssociativeArray_Startup(ByRef $aArray, $iIsCaseSensitive = 0) ; Idea from MilesAhead.
    $aArray = ObjCreate("Scripting.Dictionary")
    ObjEvent("AutoIt.Error", "__AssociativeArray_Error")
    If IsObj($aArray) = 0 Then
        Return SetError(1, 0, 0)
    EndIf
    $aArray.CompareMode = Number(Not $iIsCaseSensitive)
EndFunc   ;==>_AssociativeArray_Startup

P.S. How long did it take you to come up with that idea?

P.P.S. Thanks to all who replied.

[UEZ]

Well guinness,

just after when I saw your array output the idea came to my mind to have an array which reflects the line numbers of the functions.

But the regex I did is not working properly because of line 2866. I just catched it...

What is the benefit by using the associative array function?

And why you change the

if ... then do something

to

if .. then

do something

endif

Is this faster?

Br,

UEZ

[guinness]

Ah, line 2866. With the function I use in SciTE Jump this isn't an issue.

I've found single line If statements to be slower on my machine, I think this is why Yashied uses them in WinAPIEx.au3 >>

Local $iTimer, $iVariable = 1

$iTimer = TimerInit()
For $A = 1 To 100000
    If $iVariable Then $iVariable = 1
Next
ConsoleWrite(Round(TimerDiff($iTimer), 2) & @CRLF) ; Average = 0.00830911064656123

$iTimer = TimerInit()
For $A = 1 To 100000
    If $iVariable Then
        $iVariable = 1
    EndIf
Next
ConsoleWrite(Round(TimerDiff($iTimer), 2) & @CRLF) ; Average = 0.00586525457404322

I was being overly clever with the Associative Array, though I've been messing about in the last 20mins and it's not needed really, you're right.