_SingletonPID() - Enforce only one instance of the program running. Use AutoIt's hidden window.

[guinness]

OK; thanks for your input.

[Abilio_KID]

Hmm... been using this:

...
$p = ProcessList(StringReplace(@ScriptName,".au3",".exe")) ; --- Check if this program is already running. If so then exit.
If $p[0][0] > 1 Then Exit
...

[guinness]

It's flawed, because what happens if I copy the executable (that's already running) and rename it? It runs twice. So hmm yeah, probably not a great post.

[Abilio_KID]

It's flawed, because what happens if I copy the executable (that's already running) and rename it? It runs twice. So hmm yeah, probably not a great post.

If you rename it, then you're running "another" program, so you probably want to be running another copy of it...   (it's a question of logic).

But you are right. It's just I prefer things simpler (I use the same name for both the au3 and exe).

[guinness]

If you rename it's still the same code.

[Abilio_KID]

$s = StringReplace(@ScriptName,".au3",".exe")
$p = ProcessList($s) ; --- Check if this program is already running. If so then exit.
If $p[0][0] > 1 Or $s <> "MyProgram.exe" Then Exit

This works for me. I'll insist I'm not a programmer, I simply do a couple scripts once in a while. Because of it, I try to use the simplest way that works FOR ME.

Well... if then you have a 3rd program that you rename to mine and then you run mine... sure, it will think it's already running.

BTW guiness, I never said mine was a great post. I simply said it was simpler (in other words).

[guinness]

Please stop this now. Simple != better. You will learn this valuable lesson one day.

For others who are programmers, hard coding the application name in the program is such a bad design flaw, that will more than likely lead to additional problems.

[Abilio_KID]

Please stop this now. Simple != better. You will learn this valuable lesson one day.

For others who are programmers, hard coding the application name in the program is such a bad design flaw, that will more than likely lead to additional problems.

You're the one saying that making it "pro" style is better. I never said my way was better nor worse, just simpler FOR ME (incase you didn't read it).

You should also know that there's never a "best design", specially in programming. Take a look at all the modern crap we have in nowadays software. I'm sure you know a lot of good examples.

And to stop this now, as you put it, I don't think it's a good way to stick in everyone's face something like "the ways the pros do it is the right way", specially when AutoIt was made for simplicity. If we wanted to be pros I'm sure we'd all be learning some more advanced language...

You'll have to excuse me though. I'm not a developer. I'm a guy that knows a tiny bit of many things but unfortunently isn't pro at any. I do what I can.

[Guest]

I just copied your example script and tested and got this error:

warning: $STR_REGEXPARRAYGLOBALMATCH: possibly used before declaration.
                    '\|SINGLETON_PID:(\d+)\R', $STR_REGEXPARRAYGLOBALMATCH)

 

When I try

ConsoleWrite($STR_REGEXPARRAYGLOBALMATCH & @CRLF)

Then the error really occurs.

I didn't forget to #include <StringConstants.au3> .

 

I use Autoit 3.3.10.2

 

What $STR_REGEXPARRAYGLOBALMATCH should be ?

Thanks

 

EDIT:

I guess it's supposed to be 3 according to this source:

https://www.autoitscript.com/autoit3/docs/functions/StringRegExp.htm

Edited May 10, 2015 by Guest

[guinness]

Yeah that constant is in v3.3.12.0 and above. Glad you worked it out.

[Guest]

Yeah that constant is in v3.3.12.0 and above. Glad you worked it out.

​Yes it works.
But not as I expected .. Please read what I wrote in the code

expandcollapse popup

#include <StringConstants.au3>
#include <MsgBoxConstants.au3>


If _SingletonPID('appname_main_1', 1) Then _
Exit MsgBox(64,'Error','The script is already running')

; ##########################################################

; In this area there is another global code that may or may not execute the
; command 'Exit'

; ** This area may call to different GUIs functions that I want them to be under 'appname_main_1'

; ..............
; ..............

; let assume that the code didn't execute Exit (didn't exit and the script continues to run and
; perform the next instructions.

; ##########################################################


; ** Now I want to change 'appname_main_1' to 'appname_main_2' because every GUI that will be here
; Should be under 'appname_main_2'

; So I do this:
If _SingletonPID('appname_main_2', 1) Then _
Exit MsgBox(64,'Error','The script is already do X'&@CRLF& _
'Please close X (what the script doing) and try again')
; ^^^^ but this does not working


; If you run the script twice:
; 1) in mode appname_main_1
; 2) in mode appname_main_2

; then what I expect is that the script will not block itself because there is nothing wrong here
; because each mod run once.
; But it not working..




; #FUNCTION# ====================================================================================================================
; Name ..........: _SingletonPID
; Description ...: Enforce a design paradigm where only one instance of the script may be running.
; Syntax ........: _SingletonPID($sOccurenceName[, $iFlag = 0])
; Parameters ....: $sOccurenceName      - String to identify the occurrence of the script.
;                  $iFlag               - [optional] Optional parameters (see below). Default is 0.
;                       0 - Exit the script with the exit code -1 if another instance already exists.
;                       1 - Return the PID of the initial executable.
; Return values .: Success - 0 (no additional instances exist).
;                  Failure - The PID of the initial instance.
; Author ........: guinness with initial ideas by Valik for _Singleton() & KaFu for _EnforceSingleInstance().
; Example .......: Yes
; ===============================================================================================================================
Func _SingletonPID($sOccurenceName, $iFlag = 0)
    Local $iReturn = 0
    Local $hAutoItWnd = WinGetHandle($sOccurenceName)
    If @error Then
        AutoItWinSetTitle($sOccurenceName & @AutoItPID)
        $hAutoItWnd = WinGetHandle($sOccurenceName & @AutoItPID)
        AutoItWinSetTitle($sOccurenceName)

        Local Const $hControl = ControlGetHandle($hAutoItWnd, '', 'Edit1')
        ControlSetText($hAutoItWnd, '', $hControl, ControlGetText($hAutoItWnd, '', $hControl) & @CRLF & _
                '|SINGLETON_PID:' & @AutoItPID & @CRLF)
    Else
        If $iFlag = Default Then $iFlag = 0
        If BitAND($iFlag, 1) Then ; $SINGLETON_PID
            $iReturn = Int(StringRegExp(ControlGetText($hAutoItWnd, '', ControlGetHandle($hAutoItWnd, '', 'Edit1')) & @CRLF & _
                    '|SINGLETON_PID:0' & @CRLF, _
                    '\|SINGLETON_PID:(\d+)\R', 3)[0])
        Else
            Exit -1
        EndIf
    EndIf
    Return $iReturn
EndFunc   ;==>_SingletonPID

 

Thanks

 

Edited May 10, 2015 by Guest
Fixed code

[guinness]

Your code is wrong. What is $iSingleton for starters?

[Guest]

I did not understand your question about iSingleton.

But I know what I want to achieve and how ..

By definition this UDF should not work this way?

what wrong in the code? the way I use your UDF or the design?

EDIT:

Oops .. I know now what is wrong ..
I was sure I do not need to run it .. good lesson: Always run the code before posting

Edited May 10, 2015 by Guest

[guinness]

OK.

[Guest]

I guess I know what you think ..
This code is not meant to show the problem in reality(show the problem actually occurs in the computer) . That was not my intention when I wrote the code ..
The goal is to show the problem through comments ...
I'm just tired to write anything that presents the problem in reality.

 

But OK I will edit the post and write  better code that actually make the problem to happen in the computer..

 

EDIT:

The new code:

expandcollapse popup

#include <StringConstants.au3>
#include <MsgBoxConstants.au3>


If Not @Compiled Then Exit MsgBox(16,'','You must to compile the script!')

If _SingletonPID('appname_main_1', 1) Then _
Exit MsgBox(64,'Error','The script is already running')

; ##########################################################

; In this area there is another global code that may or may not execute the
; command 'Exit'

; ** This area may call to different GUIs functions that I want them to be under 'appname_main_1'
GUI1()
Func GUI1()
    If MsgBox($MB_YESNO,'Some GUI','Some GUI under appname_main_1'&@CRLF& _
    'Click Yes to Exit the script or No to continume.') = 6 Then Exit
EndFunc

; ..............
; ..............

; let assume that the code didn't execute Exit (didn't exit and the script continues to run and
; perform the next instructions.

; ##########################################################


; ** Now I want to change 'appname_main_1' to 'appname_main_2' because every GUI that will be here
; Should be under 'appname_main_2'

; So I do this:
If _SingletonPID('appname_main_2', 1) Then _
Exit MsgBox(64,'Error','The script is already do X'&@CRLF& _
'Please close X (what the script doing) and try again')
; ^^^^ but this does not working

GUI2()
Func GUI2()
    MsgBox(0,'Some GUI','Some GUI under appname_main_2')
EndFunc

; If you run the script twice:
; 1) in mode appname_main_1
; 2) in mode appname_main_2

; then what I expect is that the script will not block itself because there is nothing wrong here
; because each mod run once.
; But it not working..




; #FUNCTION# ====================================================================================================================
; Name ..........: _SingletonPID
; Description ...: Enforce a design paradigm where only one instance of the script may be running.
; Syntax ........: _SingletonPID($sOccurenceName[, $iFlag = 0])
; Parameters ....: $sOccurenceName      - String to identify the occurrence of the script.
;                  $iFlag               - [optional] Optional parameters (see below). Default is 0.
;                       0 - Exit the script with the exit code -1 if another instance already exists.
;                       1 - Return the PID of the initial executable.
; Return values .: Success - 0 (no additional instances exist).
;                  Failure - The PID of the initial instance.
; Author ........: guinness with initial ideas by Valik for _Singleton() & KaFu for _EnforceSingleInstance().
; Example .......: Yes
; ===============================================================================================================================
Func _SingletonPID($sOccurenceName, $iFlag = 0)
    Local $iReturn = 0
    Local $hAutoItWnd = WinGetHandle($sOccurenceName)
    If @error Then
        AutoItWinSetTitle($sOccurenceName & @AutoItPID)
        $hAutoItWnd = WinGetHandle($sOccurenceName & @AutoItPID)
        AutoItWinSetTitle($sOccurenceName)

        Local Const $hControl = ControlGetHandle($hAutoItWnd, '', 'Edit1')
        ControlSetText($hAutoItWnd, '', $hControl, ControlGetText($hAutoItWnd, '', $hControl) & @CRLF & _
                '|SINGLETON_PID:' & @AutoItPID & @CRLF)
    Else
        If $iFlag = Default Then $iFlag = 0
        If BitAND($iFlag, 1) Then ; $SINGLETON_PID
            $iReturn = Int(StringRegExp(ControlGetText($hAutoItWnd, '', ControlGetHandle($hAutoItWnd, '', 'Edit1')) & @CRLF & _
                    '|SINGLETON_PID:0' & @CRLF, _
                    '\|SINGLETON_PID:(\d+)\R', 3)[0])
        Else
            Exit -1
        EndIf
    EndIf
    Return $iReturn
EndFunc   ;==>_SingletonPID

BUT this bug does not occur in this case!
so or the bug is in my head or something in my source code caused the bug to happen.

I guess it's the second option.

I'll check it out, debug when I will have time and come here with what I found if there is really a bug..

In any case, the code I posted here maybe useful as good example

Edited May 10, 2015 by Guest

[Deye]

Hi,

is there a clean method to launch a new instance (from shortcut) but tell it to restore and "show" the existing instance before it exits
Or if it would be preferable to exit the existing one and continue with the new one which should show the GUI by default
(For me both ways should suit the purpose)

 can you please give an example on how its done

TIA
 

[TheSaint]

I posted an example here a few months ago.

EDIT

 

 

Edited February 10, 2016 by TheSaint

[Deye]

I know the idea of this function is to do these :
1. while an instance ID already exists and running , exit any newly started Occurrences
2. check what instance of the Occurrence is now running

I'm looking how to run  this with two IDs :
with the first ID I'm interested to somehow to register the instance ID as running and allow other instances of the same ID to start (identifier_2 in code example)
but with the next new ID (when started) while the first ID instance exists,I want it to see the first instance ID and exit
with the second I just want it to runs as _SingletonPID($iSngl, 0)  (as prescribed)

I know I need to modify the _SingletonPID function (any ideas how I can accomplish this ?)

this is what I started with : using 'identifier_1' and 'identifier_2'

StringRegExp($CmdLine[1], "r$", 1)
If @error == 0 Then
    _Single('identifier_2')
Else
    _Single('identifier_1')
EndIf

Func _Single($iSngl)
    If @Compiled Then
        If $iSngl = 'identifier_1' Then
            Local $iSingleton = _SingletonPID('identifier_2', 1) ;if an Occurence ID of 'identifier_2'  exists then exit else run as 'identifier_1' with not allowing new instances of 'identifier_1' 
            If $iSingleton Then
                Exit
            Else
                _SingletonPID($iSngl, 0) ;run ID without allowing new instances of this ID
            EndIf
        EndIf
        If $iSngl = 'identifier_2' Then
            Local $iSingleton = _SingletonPID($iSngl, 1) ;accept and recognize running extra instances of 'identifier_2'
            If $iSingleton Then
                Local $iSingleton = _SingletonPID($iSngl, 1)
            EndIf
        EndIf
    EndIf
EndFunc   ;==>_Single

TIA

Edited May 3, 2016 by Deye

[Deye]

having a look at this again, first code I tried was somewhat wrong 
I only changed this part: (worked for me .. )

If $iSngl = 'identifier_2' Then+
    _SingletonPID($iSngl, 1)
EndIf

 

[mexykanu]

This function is great. My use: If another instance of the program is opened, activate it with WinActivate.

Since _SingletonPID() returns the PID and not the handle of the window, we will need another function called _GetHwndFromPID(), which can be found in the Help File. I've included it in the example below:

 

expandcollapse popup

#include <StringConstants.au3>

; Search for another instance of this script
Local $singleton = _SingletonPID('YourScript',1)

; If another instance was found
if $singleton <> 0 Then

    ; Get a handle on that instance
    $handle = _GetHwndFromPID($singleton)
    
    ; Activate that window
    WinActivate($handle)
    
    ; Exit this script
    Exit
EndIf


Func _SingletonPID($sOccurenceName, $iFlag = 0)
    Local $iReturn = 0
    Local $hAutoItWnd = WinGetHandle($sOccurenceName)
    If @error Then
        AutoItWinSetTitle($sOccurenceName & @AutoItPID)
        $hAutoItWnd = WinGetHandle($sOccurenceName & @AutoItPID)
        AutoItWinSetTitle($sOccurenceName)

        Local Const $hControl = ControlGetHandle($hAutoItWnd, '', 'Edit1')
        ControlSetText($hAutoItWnd, '', $hControl, ControlGetText($hAutoItWnd, '', $hControl) & @CRLF & _
                '|SINGLETON_PID:' & @AutoItPID & @CRLF)
    Else
        If $iFlag = Default Then $iFlag = 0
        If BitAND($iFlag, 1) Then ; $SINGLETON_PID
            $iReturn = Int(StringRegExp(ControlGetText($hAutoItWnd, '', ControlGetHandle($hAutoItWnd, '', 'Edit1')) & @CRLF & _
                    '|SINGLETON_PID:0' & @CRLF, _
                    '\|SINGLETON_PID:(\d+)\R', $STR_REGEXPARRAYGLOBALMATCH)[0])
        Else
            Exit -1
        EndIf
    EndIf
    Return $iReturn
EndFunc   ;==>_SingletonPID


Func _GetHwndFromPID($PID)
    $hWnd = 0
    $winlist = WinList()
    Do
        For $i = 1 To $winlist[0][0]
            If $winlist[$i][0] <> "" Then
                $iPID2 = WinGetProcess($winlist[$i][1])
                If $iPID2 = $PID Then
                    $hWnd = $winlist[$i][1]
                    ExitLoop
                EndIf
            EndIf
        Next
    Until $hWnd <> 0
    Return $hWnd
EndFunc;==>_GetHwndFromPID

 

Edited November 4, 2016 by mexykanu