Context Menu doesn't work when mouse is above Text Label ?

[vacko]

Hi,

I have some GUI with context menu and with many text labels, but context menu doesn't work when mouse cursor stay above some of these labels.

Is it possible change GUI to let context menu works in any place ? Example is below

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$Form2 = GUICreate("Form2", 347, 137)
$Group1 = GUICtrlCreateGroup("Context menu doesn't work here", 8, 72, 329, 57)
$Label1 = GUICtrlCreateLabel("SomeLabelSomeLabelSome", 16, 88, 316, 33)
GUICtrlSetFont(-1, 14, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)

Local $contextmenu = GUICtrlCreateContextMenu()
$ContextMenuItem1 = GUICtrlCreateMenuItem("Open" &@TAB&"Alt+O", $contextmenu)
$ContextMenuItem2 = GUICtrlCreateMenuItem("Exit" &@TAB&"Alt+X", $contextmenu)

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
  Case $ContextMenuItem2
   Exit
EndSwitch
WEnd

[armoros]

Hello vacko

from help file

Remarks

After creating the context menu main control with this function, each menu item can be created by using GUICtrlCreateMenuItem.

Sub-menus can be created using GUICtrlCreateMenu.

If you use no parameters or -1 in this function then the context menu that is created is associated with the entire GUI window rather than an individual control.

Only one context menu per control is possible. If you wish to create a new context menu one you have to delete the existing menu first.

Note: You can't create context menus for controls that already have system context menus, i.e. edit or input controls.

[vacko]

Hello vacko

from help file

Remarks

After creating the context menu main control with this function, each menu item can be created by using GUICtrlCreateMenuItem.

Sub-menus can be created using GUICtrlCreateMenu.

If you use no parameters or -1 in this function then the context menu that is created is associated with the entire GUI window rather than an individual control.

Only one context menu per control is possible. If you wish to create a new context menu one you have to delete the existing menu first.

Note: You can't create context menus for controls that already have system context menus, i.e. edit or input controls.

I don't get it, I didn't use any parameter, so context menu should apply to entire GUI (include all controls), isn't it ?

[armoros]

vacko as i get it you can have 1 context menu for a control etc.

I made a mistake vacko sorry..so i deleted the code..

I am not a expert so wait for a better advice

Edited May 28, 2012 by armoros

[stormbreaker]

I don't have much time for now... But I suggest you create a dummy control, set its context menu and modify ShowMenu() function (from GuiCtrlCreateContextMenu example in help file) according to your needs (I could do it, but I guess it would be fun doing it yourself..) A bit modification and the context menu could then be displayed on any control...

[Melba23]

vacko,

The context menu does not fire when over the label because the label is reagrded as a separate control which could well have its own context menu. If you remove the default $SS_NOTIFY style from the label it is no longer regarded as a separate control and the GUI context menu will appear:

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$Form2 = GUICreate("Form2", 347, 137)
$Group1 = GUICtrlCreateGroup("Context menu doesn't work here", 8, 72, 329, 57)
$Label1 = GUICtrlCreateLabel("SomeLabelSomeLabelSome", 16, 88, 316, 33)
GUICtrlSetStyle(-1, $SS_LEFT) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
GUICtrlSetFont(-1, 14, 400, 0, "MS Sans Serif")
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)

Local $contextmenu = GUICtrlCreateContextMenu()
$ContextMenuItem1 = GUICtrlCreateMenuItem("Open" & @TAB & "Alt+O", $contextmenu)
$ContextMenuItem2 = GUICtrlCreateMenuItem("Exit" & @TAB & "Alt+X", $contextmenu)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $ContextMenuItem2
            Exit
    EndSwitch
WEnd

All clear?

M23

[armoros]

That is great info Mkish and Melba23.....nice to know.

[vacko]

vacko,

The context menu does not fire when over the label because the label is reagrded as a separate control which could well have its own context menu. If you remove the default $SS_NOTIFY style from the label it is no longer regarded as a separate control and the GUI context menu will appear:

All clear?

M23

Great ! Thank you for help.

I have over 30 labels in my GUI, now just modify them...