Basic programming question

[robinsiebler]

I have a function. I want to perform 1 action if it is the 1st time through the function and another if it is a subsequent pass. Currently, I am using a (global) counter to keep track of this. Is there a more elegant way of handling this?

Func FindPreviousBuild()
    Dim $aBuild
    If $count = 1 Then    ; 1st time through
        ; Get the actual number part of the Build Folder
        $aBuild = StringSplit($NewestDir, "-", 2)
        $BuildNo = $aBuild[1]
    Else
        $aBuild = StringSplit($BuildNo, "-", 2)
        $BuildNo = $aBuild[1]
    EndIf
    If IsInt($BuildNo) Then
        MsgBox(8240, "Navigation Error!", "I should have a build number, but I do not!")
    EndIf
    $BuildNo = $BuildNo - 1 ; Previous Build No
    $BuildNo = $aBuild[0] & "-" & $BuildNo
    $BuildFolder = $BaseFolder & "\" & $Branch & "\" & $BuildNo
    $RtnVal = FileFindFirstFile($BuildFolder)
    If Not ($RtnVal = -1) Then ; This build number was skipped
        $count = $count + 1
        DetermineBuildFolder(1)
    Else
        $NewestDir = $BuildNo
        FindPreviousBuild()
    EndIf
EndFunc   ;==>FindPreviousBuild

[Melba23]

robinsiebler,

You could use a Static variable - the declaration assignment of which is only actioned on the first pass:

Func Foo()
    ; Set the value only on the first entry into the function
    Static $iFooCount = -1 
    ; Increase the value each time we enter the function
    $iFooCount += 1
    ; Now look at value in the variable
    If $iFooCount Then
        ; Not the first pass because value > 0
    Else
        ; First pass because value = 0
    EndIf
EndFunc

That way you do not have to declare a Global variable just for the one function.

M23

[JohnOne]

I rarely use that, mind I have not looked lately if they took the billboard down in the help file.

[Mechaflash]

robinsiebler,

You could use a Static variable - the declaration assignment of which is only actioned on the first pass:

M23

Warning: This feature is experimental. It may not work, may contain bugs or may be changed or removed without notice.

DO NOT REPORT BUGS OR REQUEST NEW FEATURES FOR THIS FEATURE.

USE AT YOUR OWN RISK.

...

Note: Other than the big sign that says "ENTER AT YOUR OWN RISK"... it looks like what you want =D

EDIT:

What about declaring the counter as a local variable PRIOR to the function, and passing it as a ByRef to the function?

Edited June 7, 2012 by mechaflash213

[Bowmore]

I've been using Static quite a lot since it was introduced and to date I have not encountered any problems. I think the was some doubt if it would work for arrays but I have never had call to use static with arrays. Used as Melba23 showed I have found it to be 100% reliable.

[guinness]

It works with Arrays as well. I think the warning was there to deter users from posting 'silly' bug reports due to it being a new feature with some static variable knowledge. If in doubt ask in the forum is what I say, don't go posting Trac reports because it doesn't work first time.

Edited June 7, 2012 by guinness

[Mechaflash]

Now based on its usage, declaring it as Static is just like declaring it as Local, except if the variable gets changed in the function, and the function is called again later, it will use the updated value. Now does this mean the variable stays held in memory because of this since it doesn't get cleared out at the end of the function?

Edited June 8, 2012 by mechaflash213

[Melba23]

mechaflash213,

Correct - as I understand it. Once declared the variable exists while the script runs, but is only scoped as Local to the function in which it is declared. As previously explained, the declaration assignment is only carried out once - it is ignored after that.

And I believe that thanks to trancexx the "experimental" tag should be removed in the next release. I have been using simple Static variables since they were introduced and have had no problems. The main error was in ReDimming a Static array.

M23

[JohnOne]

So just to clear up the probable next question.

I imagine this means, that using a static variable uses no more or less memory than using a Global variable.

[Melba23]

JohnOne,

Again as I understand it, you are correct. The advantage is that you can do this:

HotKeySet("{ESC}", "On_Exit")

While 1
    _Func_1()
    _Func_2()
    Sleep(1000)
WEnd

Func _Func_1()
    Static $iCount = 0 ; Same variable name <<<<<<<<<<<<<
    $iCount +=1
    ConsoleWrite("Func 1: " & $iCount & @CRLF)
EndFunc

Func _Func_2()
    Static $iCount = 0 ; Same variable name <<<<<<<<<<<<<
    $iCount -=1
    ConsoleWrite("Func 2: " & $iCount & @CRLF)
EndFunc

Func On_Exit()
    Exit
EndFunc

which I think is very useful indeed.

M23

[JohnOne]

It is pretty cool I use it in some of my projects, but like you mentioned had a hiccup with static

arrays last year, but not had the chance to try them since fix.

And speaking of trancexx, I'm looking forward to the next awesome release of Autoit.

I'm ashamed to say I have not tried any betas,

[Melba23]

JohnOne,

You really should try them - there is some good stuff in there.

And yet more comimg, too.......

M23

[guinness]

I concur what Melba23 said e.g.

Local $aArray[] = ['John', 'One', 'Two', 'Three']

[JohnOne]

I've been following the thread closely, but I'm a big baby when it comes to major additions and such.

And to be honest, I don't know how to install a beta alongside a release and use them both.

I'm very excited nonetheless.

[Melba23]

JohnOne,

I don't know how to install a beta alongside a release and use them both

Very easy to do. Just download the beta and install it - it goes into its own "Beta" folder within the main AutoIt folder. If you use SciTE4AutoIt3 you suddenly find a whole bunch of "Beta Run/Compile" menu options appearing. And Robert is your mother's brother.

M23

[JohnOne]

I'm going to dip my e-toe in later then if it's that simple.

Cheers.