How to make this window (with a special style) unresizable?

[SYRAU3]

Hello big-minds... too many questions i'm sorry

i have this simple form:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 345, 368, 192, 146, BitOR($WS_SIZEBOX,$WS_THICKFRAME,$WS_SYSMENU,$WS_POPUP))
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit

EndSwitch
WEnd

i need to make the window unresizable keeping the same style, is that possible?

[BrewManNH]

You want to make the window not able to be resized, yet you included 2 style settings that do just that? Who wrote this for you?

Remove the $WS_SIZEBOX,$WS_THICKFRAME style settings from the GUICreate line and that should do it.

[JohnQSmith]

Remove the $WS_SIZEBOX and the $WS_THICKFRAME. Both of those switches allow resizing.

[SYRAU3]

Hey guys i know what i'm doing!, you didn't get my idea, i want to keep this window style:

but make the window (not able to be resized ).. is that possible?

[AZJIO]

#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 345, 368, -1, -1, BitOR($WS_POPUP, $WS_SYSMENU), BitOR($WS_EX_DLGMODALFRAME, $WS_EX_CONTROLPARENT))

GUISetState()

While 1

    Switch GUIGetMsg()

        Case -3

            Exit

    EndSwitch

WEnd

[SYRAU3]

thank you AZJIO, but the style is DEAD now!

[UEZ]

Try this:

expandcollapse popup

#include <WinAPI.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global Const $SC_DRAGMOVE = 0xF012
Global Const $iW = 345
Global Const $iH = 368
Global Const $hGUI = GUICreate("Unresizable Thickframe Window", $iW, $iH, -1, -1, BitOR($WS_SIZEBOX, $WS_THICKFRAME, $WS_SYSMENU, $WS_POPUP))
GUISetState(@SW_SHOW)

Global Const $iWFrame = _WinAPI_GetSystemMetrics(32) * 2 - 2
Global Const $iHFrame = _WinAPI_GetSystemMetrics(33) * 2 - 2

GUIRegisterMsg($WM_SIZING, "WM_SIZING")
GUIRegisterMsg($WM_LBUTTONDOWN, "WM_LBUTTONDOWN")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            GUIRegisterMsg($WM_SIZING, "")
            GUIRegisterMsg($WM_LBUTTONDOWN, "")
            GUIDelete()
            Exit
    EndSwitch
WEnd

Func WM_SIZING($hWnd, $iMsg, $wParam, $lParam)
    Local $sRect = DllStructCreate("Int[4]", $lParam)
    Local $left = DllStructGetData($sRect, 1, 1)
    Local $top = DllStructGetData($sRect, 1, 2)
    Local $right = DllStructGetData($sRect, 1, 3)
    Local $bottom = DllStructGetData($sRect, 1, 4)
    Local $aWinPos = WinGetPos($hWnd)

    Switch $wParam
        Case 1 ;left
            DllStructSetData($sRect, 1, $aWinPos[0], 1)
        Case 2 ;right
            DllStructSetData($sRect, 1, $aWinPos[0] + $iW + $iWFrame, 3)
        Case 3 ;top
            DllStructSetData($sRect, 1, $aWinPos[1], 2)
        Case 6 ;buttom
            DllStructSetData($sRect, 1, $aWinPos[1] + $iH + $iHFrame, 4)

        Case 4 ;left upper corner
            DllStructSetData($sRect, 1, $aWinPos[0], 1)
            DllStructSetData($sRect, 1, $aWinPos[1], 2)
        Case 5 ;right upper corner
            DllStructSetData($sRect, 1, $aWinPos[1], 2)
            DllStructSetData($sRect, 1, $aWinPos[0] + $iW + $iWFrame, 3)
        Case 7 ;left buttom corner
            DllStructSetData($sRect, 1, $aWinPos[0], 1)
            DllStructSetData($sRect, 1, $aWinPos[1] + $iH + $iHFrame, 4)
        Case 8 ;right buttom corner
            DllStructSetData($sRect, 1, $aWinPos[0] + $iW + $iWFrame, 3)
            DllStructSetData($sRect, 1, $aWinPos[1] + $iH + $iHFrame, 4)
    EndSwitch
    Return "GUI_RUNDEFMSG"
EndFunc   ;==>WM_SIZING

Func WM_LBUTTONDOWN($hWnd, $iMsg, $wParam, $lParam)
    _SendMessage($hGUI, $WM_SYSCOMMAND, $SC_DRAGMOVE, 0)
EndFunc   ;==>_WM_LBUTTONDOWN

Br,

UEZ

Edited June 27, 2012 by UEZ

[Venix]

I was actually looking for something like this myself, thanks UEZ.

[SYRAU3]

UEZ................... I LOVE YOU