Time Ticker

[CurtisWhitby]

Hi,

I am writing a piece of code that displays the time.

What I want is for the time (HH:MM:SS) to update every second.

This is my code:

GUICtrlCreateLabel(@HOUR & ":" & @MIN & ":" & @SEC, 615, 150)

If that is not possible then every minute would be fine.

Any help would be appreciated.

Curtis

[BrewManNH]

You would need to use GuiCtrlSetData and the label's controlID, you should put this into a loop or see AdLibRegister to have it update regularly. You'd also want to make sure that you only change the label contents if the time has changed otherwise it will flicker. See the code below

$MainGUI = GUICreate("Timer test")
$Label = GUICtrlCreateLabel(@HOUR & ":" & @MIN & ":" & @SEC, 10, 10, 290, 250)
GUICtrlSetFont(-1, 50, 800)
GUISetState()
AdlibRegister("_Timer") ; register the timer function
While GUIGetMsg() <> -3
     Sleep(10)
WEnd
Func _Timer()
     Static $Lastsecond
     If @SEC <> $Lastsecond Then ; if the seconds have changed, update the label contents
          GUICtrlSetData($Label, @HOUR & ":" & @MIN & ":" & @SEC)
          $Lastsecond = @SEC
     EndIf
EndFunc   ;==>_Timer

[Mechaflash]

After looking at yours Brew... I looked at mine and said "I overcomplicated it" lol

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$hGUI = GUICreate("CLOCK", 200, 75, 192, 124, $WS_BORDER)
$hTime = GUICtrlCreateLabel("", 10, 0, 200, 75)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

HotKeySet("{ESC}", "_Exit")

GUICtrlSetFont($hTime, 32, 600, "Arial")
GUICtrlSetData($hTime, @HOUR & ":" & @MIN & ":" & @SEC)
While 1
    $hTimer = TimerInit()
    Do
        Sleep(10)
    Until _TimerDiff()
WEnd

Func _TimerDiff()
    If TimerDiff($hTimer) >= 1000 Then
        GUICtrlSetData($hTime, @HOUR & ":" & @MIN & ":" & @SEC)
        Return True
    Else
        Return False
    EndIf
EndFunc

Func _Exit()
    Exit
EndFunc

[BrewManNH]

There's always a new way to skin that cat, more information that people have to work with the better.

[CurtisWhitby]

Excellent, thank you very much.

It now works exactly how I wanted it to.