Help with GUICtrlRead()?

[tsukun03]

Hi,

I am having a little trouble understanding how GUICtrlRead() stores the data that is read from the text input in my GUI. Does GUICtrlRead store its data in an Array or a file? This i am not sure.

I am trying to extract each line of the Edit that is inputted by the user. I tried to use a loop to extract each value line by line but I am unsuccessful. I am also unsure how to determine the number of line that are inputted in.

$Edit1 = GUICtrlCreateEdit("", 8, 48, 425, 385)

$read = GUICtrlRead($Edit1)

Is there a way to read in the data and parse it out line by line directly from the Edit Form?

Thanks

[Melba23]

tsukun03,

GUICtrlRead will store the data as literal text string - not an array and certainly not a file.

Once you have the text, you can use StringSplit to find out how many lines there are and what each contains:

#include <GUIConstantsEx.au3>
#include <Array.au3>

$hGUI = GUICreate("Test", 500, 500)

$cEdit = GUICtrlCreateEdit("", 10, 10, 480, 200)
$cButton = GUICtrlCreateButton("Read", 10, 250, 80, 30)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            ; Read the edit
            $sText = GUICtrlRead($cEdit)
            ; Split into lines.  Note we need the flag parameter set to 1, the Help file explains why
            $aLines = StringSplit($sText, @CRLF, 1)
            ; [0] holds the number of lines, other elements hold the lines themselves
            _ArrayDisplay($aLines)
    EndSwitch
WEnd

All clear?

M23

[tsukun03]

Ok thanks that helps a lot

thanks