Help with GUIGetCursorInfo

[TTalma]

I am new to Autoit and am having a problem with GUIGetCursorInfo.

I am using Autoit to automate some testing for my project for one part a user clicks on an image and then clicks on a different image, and Autoit logs some data. I have all this working except for 1 part I need to know the distance the mouse was moved. My Autoit script has no Gui (except a little one I am using for debug) and the main window is the only one I am concerned about. Here is the code I am using to get the distance:

expandcollapse popup

Global $handle = 0

;get the active window
$lst = WinList()
For $i = 0 To $lst[0][0]
    If $lst[$i][0] == "Tracer" And IsVisible($lst[$i][1]) Then
        GUICtrlSetData($lblHndlInfo, "Title= " & $lst[$i][0] & ", Handle= x" & $lst[$i][1])
        $handle = $lst[$i][1]
    EndIf
Next

Func IsVisible($handle)
    If BitAND(WinGetState($handle), 2) Then
        Return 1
    Else
        Return 0
    EndIf
EndFunc

;buncha code here
$distInPix = MoveAndMeasure($newImgX, $newImgY, Rand(4, 14))
;more code here


Func MoveAndMeasure($xPos, $yPos, $speed = 10)
    ;calc the distance from current position to the final postion
    $curPos = GUIGetCursorInfo($handle);
    $dist = getdistance($curPos[0], $xPos, $curPos[1], $yPos)
    ;Move the mouse to the final position
    MouseMove($xPos, $yPos, $speed)
    Return $dist
EndFunc

Func getdistance($x1, $x2, $y1, $y2)
    ;Pythagoras' Theorm, C^2 = A^2 + B^2
    $dist = Sqrt(subMax($x1, $x2)^2 + subMax($y1, $y2)^2))
    Return $dist
EndFunc

Func subMax($s_Num1, $s_Num2)
    If $s_Num1 > $s_Num2 Then Return $s_Num1-$s_Num2
    Return $s_Num2-$s_Num1
EndFunc

The line in the function MoveAndMeasure

$curPos = GUIGetCursorInfo($handle);

is always returning 0 and @error is always set to 1.

The handle value I am reciving from winlist seems to be valid, And my program is the active window but I am not sure why this function is failing. if anyone has an idea of if you need more information please let me know.

[Melba23]

TTalma,

GUIGetCursorInfo only works on GUIs that you create within your script, not any others. Run this from SciTE and you will see that you only get the results relative to the created GUI, not SciTE even if it is active.

I would suggest using MouseGetPos - as you can see you get that all the time:

#include <GUIConstantsEx.au3>

$hHandle = WinGetHandle("[CLASS:SciTEWindow]")
ConsoleWrite($hHandle & @CRLF)

$hGUI = GUICreate("Test", 500, 500)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    $aInfo = GUIGetCursorInfo($hHandle)
    If Not @error Then
        ConsoleWrite("SciTE: " & $aInfo[0] & " - " & $aInfo[1] & @CRLF)
    EndIf

    $aInfo = GUIGetCursorInfo($hGUI)
    If Not @error Then
        ConsoleWrite("GUI: " & $aInfo[0] & " - " & $aInfo[1] & @CRLF)
    EndIf

    $aPos = MouseGetPos()
    ConsoleWrite("Mouse: " & $aPos[0] & " - " & $aPos[1] & @CRLF)

    Sleep(250)

WEnd

M23

[BrewManNH]

You should try MouseGetPos instead of using GUIGetCursorInfo because as the help file says:

The mouse cursor position is successful only on an window created by a GUICreate. When no winhandle it will be successful if the GUI Windows is active.