How to ignore certain elements in an array

[kor]

Sample Code

What I'm trying to do is, if you run the first loop, if $i = any of the values from the $aIgnore array, then continue loop.

I've tried it this way.

Local $aCheck[10] = ["a", "b", "c", "d", "e", "f", "g", "h", "i", "j"]
Local $aIgnore[3] = ["b", "d", "g"]

For $i = 0 To UBound($aCheck) - 1
For $n = 0 To UBound($aIgnore) - 1
If $i = $aIgnore[$n] Then ContinueLoop
ConsoleWrite($aCheck[$i] & "   ")
Next
Next
ConsoleWrite(@cr)

And this way (which I'm sure is wrong)

Local $aCheck[10] = ["a", "b", "c", "d", "e", "f", "g", "h", "i", "j"]
Local $aIgnore[3] = ["b", "d", "g"]

For $i = 0 To UBound($aCheck) - 1
If $i = $aIgnore Then ContinueLoop
ConsoleWrite($aCheck[$i] & "   ")
Next
ConsoleWrite(@cr)

[Melba23]

kor,

Try this:

Local $aCheck[10] = ["a", "b", "c", "d", "e", "f", "g", "h", "i", "j"]
Local $aIgnore[3] = ["b", "d", "g"]

For $j = 0 To UBound($aCheck) - 1
    ; Get the next item in the array to check
    $sItem = $aCheck[$j]
    ; Set a flag
    $fValid = True
    ; Now loop through the exceptions
    For $i = 0 To UBound($aIgnore) - 1
        ; If it matches clear the flag
        If $sItem == $aIgnore[$i] Then
            $fValid = False
        EndIf
    Next
    ; If the flag is set it is a valid item
    If $fValid Then ConsoleWrite($aCheck[$j] & @CRLF)
Next

All clear?

M23

[kor]

Sort of.

This works

Local $aControls[10] = ["a", "b", "c", "d", "e", "f", "g", "h", "i", "j"]

_Validate($aControls)

Func _Validate(ByRef $aInput)
Local $aOptional[2] = ["b", "c"]
For $i = 0 To UBound($aInput) - 1
;ConsoleWrite($aInput[$i] & " ")
For $n = 0 To UBound($aOptional) - 1
;ConsoleWrite($aOptional[$n] & " ")
If $aInput[$i] == $aOptional[$n] Then
ContinueLoop 2
EndIf
Next
ConsoleWrite($aInput[$i])
Next
EndFunc

However how would I accomplish the same thing with array element ID's rather than the actual value in the array?

Example of code using array element ID's rather than values. But it doesn't work.

Local $aControls[10] = ["a", "b", "c", "d", "e", "f", "g", "h", "i", "j"]

_Validate($aControls)

Func _Validate(ByRef $aInput)
Local $aOptional[2] = [2, 3]
For $i = 0 To UBound($aInput) - 1
;ConsoleWrite($aInput[$i] & " ")
For $n = 0 To UBound($aOptional) - 1
;ConsoleWrite($aOptional[$n] & " ")
If $aInput[$i] == $aOptional[$n] Then
ContinueLoop 2
EndIf
Next
ConsoleWrite($aInput[$i])
Next
EndFunc

[BrewManNH]

If $i = $aOptional[$n] Then

[Melba23]

kor,

Sort of

Good way of making sure you get ignored for a while.

M23

P.S. Only kidding.

[kor]

kor,

Good way of making sure you get ignored for a while.

M23

P.S. Only kidding.

I like to think that me posting sample code insures I don't get ignore. At least it shows I'm trying

[czardas]

Here's a related idea I was playing around with today. This is a possible method to run a check after every 100 loops have been completed. Although the example doesn't skip any loops, it illustrates a potentially viable alternative method for doing so (and therefore a metthod for skipping an array element). It may not be useful in this particular case, but it may be of interest to someone.

For $i = 1 To 1000
    If $i < 1000 - 100 Then ; Only run 100 loops at a time
        For $i = $i To $i + 99 ; Loop 100 times
            ConsoleWrite("Loop " & $i & @LF) ; Checking loop number
            Sleep(10) ; Some process which could take a long time
        Next
        $i -= 1 ; This is necessary to avoid accidentally skipping one in every 100 loops
        ConsoleWrite("Running conditional statement after " & $i & " loops" & @LF) ; Imterrupt
    Else ; Loop through the remaining values for $i
        For $i = $i To 1000
            ConsoleWrite("loop " & $i & @LF) ; Checking loop number
            Sleep(10) ; Same process as above which could take a long time
        Next
        ExitLoop ; Otherwise $i will be incremented twice at the end, and we don't want that!
    EndIf
Next
ConsoleWrite("Completed " & $i -1 & " loops"  & @LF)

Edited August 3, 2012 by czardas

[GMK]

I've also used _ArraySearch for similar tasks.

#include <Array.au3>
Local $aCheck[10] = ["a", "b", "c", "d", "e", "f", "g", "h", "i", "j"]
Local $aIgnore[3] = ["b", "d", "g"]
For $iRow = 0 To UBound($aCheck) - 1
    _ArraySearch($aIgnore, $aCheck[$iRow])
    If @error Then ConsoleWrite($aCheck[$iRow] & @CRLF)
Next

Edit:

However how would I accomplish the same thing with array element ID's rather than the actual value in the array?

#include <Array.au3>

Local $aControls[10] = ["a", "b", "c", "d", "e", "f", "g", "h", "i", "j"]

_Validate($aControls)

Func _Validate(ByRef $aInput)
    Local $aOptional[2] = [2, 3]
    For $i = 0 To UBound($aInput) - 1
        _ArraySearch($aOptional, $i)
        If @error Then ConsoleWrite($aInput[$i])
    Next
    ConsoleWrite(@CRLF)
EndFunc ;==>_Validate

Edited August 3, 2012 by GMK