Case statement with the "To" argument

[kor]

why does this code work

If _IsPressed("0D") Then ; if enter is pressed
            For $i = 9 To 31
                $aHandles[$i] = GUICtrlGetHandle($aControls[$i]) ; read controls into a new array (not sure this is necessary)
            Next
            Switch _WinAPI_GetFocus()
                Case $aHandles[9], $aHandles[11], $aHandles[13], $aHandles[16], $aHandles[18], $aHandles[20], $aHandles[22], $aHandles[24], $aHandles[27], $aHandles[29], $aHandles[31]
                    GUICtrlSendToDummy($cDummy)
            EndSwitch
            While _IsPressed("0D")
                Sleep(10)
            WEnd
        EndIf

but this code doesn't?

If _IsPressed("0D") Then ; has enter been pressed
            For $i = 9 To 31
                $aHandles[$i] = GUICtrlGetHandle($aControls[$i])
            Next
            Switch _WinAPI_GetFocus()
                Case $aHandles[9] To $aHandles[31]
                    GUICtrlSendToDummy($cDummy)
            EndSwitch
            While _IsPressed("0D")
                Sleep(10)
            WEnd
        EndIf

I'm trying to reduce the case statement down into something easier rather than naming each and every control.

[Melba23]

kor,

It does not work because, unlike Autoit ControlIDs, handles are not consecutive integers and so using To to act on a range does not work.

What you could do is something like this (not tested):

If _IsPressed("0D") Then ; has enter been pressed

    ; Why do this on every pass - why not do it just the once before the loop?
    For $i = 9 To 31
        $aHandles[$i] = GUICtrlGetHandle($aControls[$i])
    Next

    ; Get the focused handle
    $hActive = _WinAPI_GetFocus()
    ; Now loop through the array to see if there is a match
    For $i = 9 To 31
        If $aHandles[$i] = $hActive Then
            ; If there is then action something
            GUICtrlSendToDummy($cDummy)
        EndIf
    Next

    ; Wait until key is released
    While _IsPressed("0D")
        Sleep(10)
    WEnd
EndIf

M23

[kor]

Took your example and came up with this.

It works nicely. thanks!

If _IsPressed("0D") Then ; has enter been pressed
            For $i = 9 To 31
                If GUICtrlGetHandle($aControls[$i]) = _WinAPI_GetFocus() Then GUICtrlSendToDummy($cDummy)
            Next
            While _IsPressed("0D")
                Sleep(10)
            WEnd
        EndIf