Pasting into SciTE editor

[JohnSAutoIt]

I've written a simple snippet holder that works fine with my common scripts that are in a fixed path, say c:\myscripts\autoit.

To paste the snippet I copy the selected code to the clipboard then use:

Opt("WinTitleMatchMode", 2)
WinActivate("myscripts\autoit")
Send("^v")

The problem arises when I'm trying to paste into a script from another folder or a new unsaved script. The only constant in the window title for the SciTE editor is "SciTE".

A typical full title would be C:\myscripts\autoit \Snippets.au3 - SciTE [1 of 4]

A typical full title for an unsaved script would be (Untitled) * SciTE [3 of 4]

If I use "SciTE":

Opt("WinTitleMatchMode", 2)
WinActivate("SciTE")
Send("^v")

it does not work and I have no idea why. This code will work for one of my regular scripts or an Include file I am editing (different folder path) but not for an unsaved script.

I tried using handles but that did not work either. Anyway, I'm more interested in finding out why the above does not work.

[JohnSAutoIt]

I believe I've found the cause of the problem though I can't explain it.

As I've been working on my Snippets script, I've been testing by hitting Tools - Go. That opens my Snippet GUI and I've then checked it out in conjunction with the SciTE editor. What I have found since is that if I compile the script into an exe and start the script by double-clicking the exe, it works fine with the "SciTE" window title matching and any script listing in the editor including unsaved ones.

[BrewManNH]

If you want to paste text into the editor part of SciTE, then you can use this set of functions to do it much easier. It doesn't rely on pasting from the clipboard, and doesn't need to know the title of the SciTE window.

; Send the function _SciTE_InsertText the text you want to paste into SciTE and it does all the work for you.


Func _SciTE_InsertText($sString)
    Return _SciTE_Send_Command(0, WinGetHandle("DirectorExtension"), "insert:" & $sString)
EndFunc   ;==>_SciTE_InsertText
Func _SciTE_Send_Command($hHandle, $hSciTE, $sString)
    Local $ilParam, $tData
    If StringStripWS($sString, 8) = "" Then
        Return SetError(2, 0, 0) ; String is blank.
    EndIf
    $sString = ":" & Dec(StringTrimLeft($hHandle, 2)) & ":" & $sString
    $tData = DllStructCreate("char[" & StringLen($sString) + 1 & "]") ; wchar
    DllStructSetData($tData, 1, $sString)
    $ilParam = DllStructCreate("ptr;dword;ptr") ; ulong_ptr;dword;ptr
    DllStructSetData($ilParam, 1, 1) ; $ilParam, 1, 1
    DllStructSetData($ilParam, 2, DllStructGetSize($tData))
    DllStructSetData($ilParam, 3, DllStructGetPtr($tData))
    _SendMessage($hSciTE, $WM_COPYDATA, $hHandle, DllStructGetPtr($ilParam))
    Return Number(Not @error)
EndFunc   ;==>_SciTE_Send_Command

EDIT: I got this idea for a project of mine from something guiness posted, I'm not the author of it.

Edited August 16, 2012 by BrewManNH

[JohnSAutoIt]

Guiness, BrewMan, is there a pattern here?

Wow, that's some code. I don't know how you guys dream that stuff up. Nice to know thanks.

I'll probably stick with my WinActivate and ^v, ^c which also seems to be highly adaptable to any other programming editor or text application. Even with error trapping it's only about 4 lines. I find the other snippet holders way to complicated. Mine is very basic and I only have about a dozen snippets. Perhaps that's a measure of my programming IQ.

[guinness]

The initial idea I got from Jos.