~ Sorting grouped items in a ListView? (SOLVED)

[EKY32]

Is it available to sort items in a GuiCtrlCreateListView which have been added to a group using _GUICtrlListView_SetItemGroupID ?

Edited August 20, 2012 by EKY32

[BrewManNH]

What have you tried? Have you tried sorting a listview with groups in them?

[EKY32]

I created a ListView and added items to it, then i created a group and set the items' groupID to that group, so the commands:

_GUICtrlListView_RegisterSortCallBack($ListView)

_GUICtrlListView_SortItems($ListView, 8)

Case $ListView

_GUICtrlListView_SortItems($ListView, GUICtrlGetState($ListView))

this works if no group is created, but when i create a group and add items to it, this command never works

[BrewManNH]

Well, without your script to see how you're attempting to do this, I will have to assume that you can't sort a listview with items in a group.

Of course, I could be wrong because I have never used a group in a listview and I've only ever sorted listview items with no grouping.

[EKY32]

This is an example:

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>


$Debug_LV = False ; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work


Local $hImage, $hListView

GUICreate("ListView Set Item Group ID", 400, 300)
$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
_GUICtrlListView_RegisterSortCallBack($hListView)
_GUICtrlListView_SortItems($hListView, 8)
GUISetState()

; Load images
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($hListView, $hImage, 1)

; Add columns
_GUICtrlListView_AddColumn($hListView, "Column 1", 100)
_GUICtrlListView_AddColumn($hListView, "Column 2", 100)
_GUICtrlListView_AddColumn($hListView, "Column 3", 100)

; Add items
_GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
_GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 2", 1)
_GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 3", 2)
_GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1)
_GUICtrlListView_AddSubItem($hListView, 1, "Row 2: Col 2", 1)
_GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)

; Build groups
_GUICtrlListView_EnableGroupView($hListView)
_GUICtrlListView_InsertGroup($hListView, -1, 1, "Group 1")
_GUICtrlListView_InsertGroup($hListView, -1, 2, "Group 2")
_GUICtrlListView_SetItemGroupID($hListView, 0, 1)
_GUICtrlListView_SetItemGroupID($hListView, 1, 2)
_GUICtrlListView_SetItemGroupID($hListView, 2, 2)

; Display Item 3 group ID
MsgBox(4160, "Information", "Item 3 Group ID: " & _GUICtrlListView_GetItemGroupID($hListView, 2))

; Loop until user exits
Do
If GUIGetMsg() = $hListView Then _GUICtrlListView_SortItems($hListView, GUICtrlGetState($hListView))

Until GUIGetMsg() = $GUI_EVENT_CLOSE
Exit

I should be able to sort the items in every group it self. is that possible?

Edited August 19, 2012 by EKY32

[BrewManNH]

What have YOU tried for sorting? Because that's just the example script from the help file for the function, not something you wrote, and there's no sort routine in there.

[EKY32]

Yes I just gave you the helpfile example but i edit it!!

Look, aren't these sort routines??

_GUICtrlListView_RegisterSortCallBack($hListView)
_GUICtrlListView_SortItems($hListView, 8)

If GUIGetMsg() = $hListView Then _GUICtrlListView_SortItems($hListView, GUICtrlGetState($hListView))

[BrewManNH]

Try this.

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>


$Debug_LV = False ; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work


Local $hImage, $hListView

GUICreate("ListView Set Item Group ID", 400, 300)
$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
_GUICtrlListView_RegisterSortCallBack($hListView)
;~ _GUICtrlListView_SortItems($hListView, 8)
GUISetState()

; Load images
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($hListView, $hImage, 1)

; Add columns
_GUICtrlListView_AddColumn($hListView, "Column 1", 100)
_GUICtrlListView_AddColumn($hListView, "Column 2", 100)
_GUICtrlListView_AddColumn($hListView, "Column 3", 100)

; Add items
_GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0, 1000) ; $iParam needs to be >= 1000
_GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 2", 1)
_GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 3", 2)
_GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1, 1001) ; next row, add 1 to $iParam used previously
_GUICtrlListView_AddSubItem($hListView, 1, "Row 2: Col 2", 1)
_GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2, 1002) ; ditto

; Build groups
_GUICtrlListView_EnableGroupView($hListView)
_GUICtrlListView_InsertGroup($hListView, -1, 1, "Group 1")
_GUICtrlListView_InsertGroup($hListView, -1, 2, "Group 2")
_GUICtrlListView_SetItemGroupID($hListView, 0, 1)
_GUICtrlListView_SetItemGroupID($hListView, 1, 2)
_GUICtrlListView_SetItemGroupID($hListView, 2, 2)

; Display Item 3 group ID

; Loop until user exits
While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $hListView
            _GUICtrlListView_SortItems($hListView, GUICtrlGetState($hListView))
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd
Exit

When you create listview items with the UDF functions, you have to create them using the $iParam parameter, usually any number 1000 or greater is sufficient, as long as each item is created with an $iParam value that is 1 more than the last used item. Otherwise you can't sort the listview items.

[EKY32]

Well, Thank you very much Mr.BrewManNH.