GUICtrlCreateInput Help

[tylerh27]

I have a username, and a password field. The thing is, i want the text there to disapear onfocus, and for the password field to show *** when the user types in their password, can someone tell me how to do this?

[Melba23]

tylerh27,

Add the $ES_PASSWORD style to your input when you create it to get the "****" appearing. And to get the disappearing hint text on focus, you need to send a SETCUEBANNER message to the input.

Here is an example of both of these in action:

#include <GUIConstantsEX.au3>
#include <EditConstants.au3>

$hGui = GUICreate("", 500, 300)
GUICtrlCreateLabel("Info", 10, 5)
Local $aInput[6][2] = [[0, "Name"],[0, "Address"],[0, "Home Phone"],[0, "Mobile Phone"],[0, "Town"],[0, "Password"]]
For $i = 0 To UBound($aInput) - 2
    $aInput[$i][0] = GUICtrlCreateInput("", 10, (20 * ($i + 1)), 140, 20)
    GUICtrlSendMsg(-1, $EM_SETCUEBANNER, False, $aInput[$i][1])
Next
$aInput[$i][0] = GUICtrlCreateInput("", 10, (20 * ($i + 1)), 140, 20, $ES_PASSWORD)
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, False, $aInput[$i][1])
GUISetState()
While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then Exit
WEnd

;SETCUEBANNER does not work for edit controls with $ES_MULTILINE style.
;In XP, the banner disappears when the edit has focus (cursor in edit)
;In Vista/7 the banner can optionally still appear when the edit has focus (cursor in edit)
;(third parameter = True/False)

All clear?

M23

P.S. Have you read the Forum Rules with reference to log-in scripts? I would do so before you ask for any more help about this script.

[tylerh27]

It said wrong amount of paramaters? :/

$inputpass = GUICtrlCreateInput("**********",70,140,150,20,-1,512, $ES_PASSWORD)

Edited August 24, 2012 by tylerh27

[skin27]

If such an error occurs its best to check the help file:

GUICtrlCreateInput ( "text", left, top [, width [, height [, style [, exStyle]]]] )

Here you see that you need at least 3 parameters and that there are maximum of 7 parameters can be used. So you are using 8 parameters and the $ES_PASSWORD is not on the right place (should be 6th parameter). Compare your example with that of Melba23 than you see the difference.

What are you trying to accomplish with these extra parameters?