CmdLine[x] possibility

[RedneckTech]

Im working with the $CmdLine[x] variables and i must say bravo to whoever got them working. Was just wondering if there was a feature in there that would detect if any of the command switches passed to the exe would pass.

basically:

myscript.exe /par1 /par2 /par3

and

myscript.exe /par3 /par2 /par1

would both do the same thing. Just wondering if there is a If $CmdLine[any] = /par2 Then

That way no matter which position par2 is in the exe will stil perform the same. sorry if this is confusing. i can try to reword if necessary

[Melba23]

RedneckTech,

I think you are going to have to loop through the array yourself:

For $i = 1 To $cmdline[0]
    ConsoleWrite($cmdline[$i] & @CRLF)
    If $cmdline[$i] = "par2" Then
        MsgBox(0, "Found", "Par2")
        ExitLoop
    EndIf
Next
If $i > $cmdline[0] Then
    MsgBox(0, "Error", "Not found")
EndIf

M23

[RedneckTech]

yuck. thanks though. Not a dire feature, i guess the users will just have to learn to do something the right way for once

That and its probably just a sign for me to make things simple for once. Thanks!

[BrewManNH]

You could do something like this:

If $cmdline[0] > 0 Then
     For $I = 1 To $cmdline[0]
          Switch $cmdline[$I]
               Case "/par1"
                    $Par1 = 1
               Case "/par2"
                    $Par2 = 1
               Case "/par3"
                    $Par3 = 1
          EndSwitch
     Next
EndIf
If $Par1 Then MsgBox(64, "", "/par1 found")
If $Par2 Then MsgBox(64, "", "/par2 found")
If $Par1 Then MsgBox(64, "", "/par3 found")

This way, you're setting a flag when it sees one of the parameters, and it won't matter in what order they're in on the command line.

[jdelaney]

Don't forget to declare the $Par# variables outside the loop, or it will error out on If ^ (when not defined inside the loop)

$Par1 = 0

$Par2 = 0

$Par3 = 0

[RedneckTech]

i like what you guys have up. currently have this going (not finished) its basically just a comprehensive AV control script for update/scan just to make my life easier

expandcollapse popup

If $CmdLine[0] <> 0 Then
   If $CmdLine[2] = "/full" Then
      $Full = 1
      If $CmdLine[3] = "-scan" Then
         $update = 0
      Else
         MsgBox(0,"","ERROR: Incorrect Parameter Syntax" & @CRLF & "Please consult the readme for more information")
      EndIf
   ElseIf $CmdLine[2] = "-scan" Then
      $update = 0
   Else
      MsgBox(0,"","ERROR: Incorrect Parameter Syntax" & @CRLF & "Please consult the readme for more information")
   EndIf
   If $CmdLine[1] = "ALL" Then
         _SEP()
         _MSSE()
         _AVAST()
         _MBAM()
         _Counter()
   ElseIf $CmdLine[1] = "SEP" Then
      _SEP()
   ElseIf $CmdLine[1] = "MSSE" Then
      _MSSE()
   ElseIf $CmdLine[1] = "AVAST" Then
      _AVAST()
   ElseIf $CmdLine[1] = "MBAM" Then
      _MBAM()
   Else
      MsgBox(0,"","ERROR: Incorrect Parameter Syntax" & @CRLF & "Please consult the readme for more information")
   EndIf
ElseIf $CmdLine[0] > 3 Then
   MsgBox(0,"","ERROR: Incorrect Parameter Syntax" & @CRLF & "Please consult the readme for more information")
Else
   _SEP()
   _MSSE()
   _AVAST()
   _MBAM()
   _Counter()
EndIf

any others you think i should add (norton is being added right now) and what the lines (either silent or over cmd with autoexit) for update/scan(quick and full) would be greatly appreciated!

[BrewManNH]

Don't forget to declare the $Par# variables outside the loop, or it will error out on If ^ (when not defined inside the loop)

It was an example of how to do something with the command line, but you're right I should have declared them before using them just in case someone wasn't aware of that.

EDIT: RedneckTech, I wouldn't parse the command line the way you're doing it unless you're sure that there's going to BE a $cmdline[2] or [3], otherwise you're going to crash the script with an array subscript error. The way I showed makes it a LOT easier to parse the command line, and a lot safer because you don't have to hope that every parameter is going to be used.

Edited August 30, 2012 by BrewManNH

[RedneckTech]

PS. Trend Micro has already told me that "there are no supported command lines for controlling our titanium product" and i havent been able to find any, so if you know them it would be GREATLY appreciated, especially because there are like 6 different versions of trend AV and they all function differently apparently. Makin my life a nightmare

Edited August 30, 2012 by RedneckTech

[ajag]

[...] Just wondering if there is a If $CmdLine[any] = /par2 Then

That way no matter which position par2 is in the exe will stil perform the same. sorry if this is confusing. i can try to reword if necessary

Maybe this could be what you want

#include <Array.au3>
Dim $params = _ArrayToString($CmdLine, @TAB, 1)

If StringInStr($params,"/par2") Then
MsgBox(0, "BINGO", "Found '/par2'")
EndIf

If StringInStr($params,"/par1") Then
MsgBox(0, "BINGO", "Found '/par1'")
EndIf

If StringInStr($params,"/par3") Then
MsgBox(0, "BINGO", "Found '/par3'")
EndIf

A-Jay