Updating GUI

[Zer0Velocity]

Hello, I have a basic GUI I'm trying to update with a time stamp every sec. However, on the GUI I have a button with FileSelectFolder and when I use this button the time stamp stops on the GUI which I don't want to happen. Any suggestions on how I can make this work as I need?

[BrewManNH]

Post your code, or at least a script that reproduces what you're doing and demonstrates what happens.

[Zer0Velocity]

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 117, 84, 192, 124)
$Button1 = GUICtrlCreateButton("Browse", 24, 48, 75, 25)
$Label1 = GUICtrlCreateLabel("", 20, 16, 76, 20)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
While 1
$nMsg = GUIGetMsg()
Select
  Case $nMsg = $GUI_EVENT_CLOSE
   Exit
  Case $nMsg = $Button1
  Local $var = FileOpenDialog("Choose a folder.", "", "EXE (*.exe)", 1 + 4 )
  GUICtrlSetData($Label1, $var)
EndSelect
$time = "TIME: " & @HOUR & ":" & @MIN & ":" & @SEC
GUICtrlSetData($Label1, $time)
Sleep(60)
WEnd

[BrewManNH]

I belive it's because the FileOpenDialog is a blocking function, which means nothing runs while it's displayed. Here's a way to make the GUI's label update even though the FileOpenDialog is blocking the rest of the script.

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Include <Timers.au3> ; New include file <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
#region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 117, 84, 192, 124)
$Button1 = GUICtrlCreateButton("Browse", 24, 48, 75, 25)
$Label1 = GUICtrlCreateLabel("", 20, 16, 76, 20)
GUISetState(@SW_SHOW)
$iTimer = _Timer_SetTimer($Form1, 250, "timer") ; Start a timer <<<<<<<<<<<<<<<<
#endregion ### END Koda GUI section ###
While 1
     $nMsg = GUIGetMsg()
     Select
          Case $nMsg = $GUI_EVENT_CLOSE
               _Timer_KillAllTimers($Form1) 
               Exit
          Case $nMsg = $Button1
               Local $var = FileOpenDialog("Choose a folder.", "", "EXE (*.exe)", 1 + 4)
               GUICtrlSetData($Label1, $var)
     EndSelect
     Sleep(60)
WEnd
Func Timer($hWnd, $Msg, $iIDTimer, $dwTime)
    #forceref $hWnd, $Msg, $iIDTimer, $dwTime
     $time = "TIME: " & @HOUR & ":" & @MIN & ":" & @SEC
     GUICtrlSetData($Label1, $time)
EndFunc   ;==>Timer

EDIT: I forgot a line in the script before the Exit, need to kill the timer before you exit the script.

Edited September 6, 2012 by BrewManNH

[Zer0Velocity]

That works as I need now, thank you BrewManNH for the help. Much appreciated.