[SOLVED] TCP Chat Problem

[PhoenixXL]

Hello Every One

I tried many of the TCP Chat programs

which worked flawlessly between my computer and my moms computer in the same WiFi Network

Then I decided to give the program to my friends and do chat with them

But, that didnt work

After a lot of searching I found that PORT FORWARDING would be required for Private networks

My friends were not aware of any of this, therefore i chose to make a program that could do the

PORT FORWARDING by itself.

I finally chose the NAT-PMP for this,

But I'm not able to find anything to do it.

Please Guide my in the Right Direction

Thanks for your Time

Edited September 9, 2012 by PhoenixXL

[stormbreaker]

I always prefer UPnP. See http://www.codeproject.com/Articles/27237/Easy-Port-Forwarding-and-Managing-Router-with-UPnP. A good place where I got started...

[PhoenixXL]

Thanks.

Topic Solved

[nullschritt]

Could you please share you solution on how to automatically portforward with UPnP? Thanks.

[guinness]

Why not use the UDP protocol? Since from your initial post both your Mum and you are on the same local area network.

[PhoenixXL]

nullschritt,

this code worked for me

I got it from the Forum and modified it as per my needs

expandcollapse popup

;Port Forwarding
Global $g_eventerror = 0 ; to be checked to know if com error occurs. Must be reset after handling.
$oMyError = ObjEvent("AutoIt.Error", "MyErrFunc") ; Install a custom error handler
Global $debuglog = "Chat Debug.log"
Global $debug = 0 ; 1 = Log , 0 = no log
Global $console = 0 ;1=ConsoleWrite , 0= No ConsoleWrite

If is_privateIP(@IPAddress1) Then PortForward('TCP')
If @error Then Exit -1

Func PortForward($nProtocol='UDP',$nInternalPort=6800,$nExternalPort=$nInternalPort,$nIPAddress=@IPAddress1,$nDescription='PortForward')
If FindDevice() Then
Return SetError(0,0,UpnpPortMap($nIPAddress, $nInternalPort, $nExternalPort, $nProtocol, $nDescription))
EndIf
Return SetError(1,0,0)
EndFunc

Func UpnpPortMap($InternalIP, $InternalPort, $ExternalPort, $Protocol, $Description)
Local $theNatter = ObjCreate("HNetCfg.NATUPnP")
If IsObj($theNatter) Then
DebugMsg("HNetCfg.NATUPnP.StaticPortMappingCollection now")
Local $mappingPorts = $theNatter.StaticPortMappingCollection
DebugMsg("HNetCfg.NATUPnP.StaticPortMappingCollection.Add now")
$mappingPorts.Add($InternalPort, $Protocol, $ExternalPort, @IPAddress1, 1, $Description)
; at this point we know that we have IGD device and we was unable to open port via HNetCfg.NATUPnP StaticPortMappingCollection.Add
; so lets try with MiniUPnP Project link to site http://miniupnp.free.fr/
; many distribution use this project
If $g_eventerror = 1 Then
If miniupnpcaddstatic($InternalIP, $InternalPort, $ExternalPort, $Protocol) Then
DebugMsg("ok port is open on router")
Return 1
EndIf
Else
DebugMsg("ok port is open on router")
Return 1
EndIf
EndIf
DebugMsg("fail to open on router")
Return 0
EndFunc ;==>UpnpPortMap


; this is taken from forum :)
Func FindDevice()
Dim $deviceFinder
Dim $DeviceType
Dim $Devices
Dim $Device
Dim $strDescDocURL
$deviceFinder = ObjCreate("UPnP.UPnPDeviceFinder")
$DeviceServices = ObjCreate("UPnP.UPnPServices")
$DeviceService = ObjCreate("UPnP.UPnPService")
$Device = ObjCreate("UPnP.UPnPDevice")
; we need any version of IGD device curently there only 1 and 2 :)
$DeviceType = "upnp:rootdevice"
$Devices = $deviceFinder.FindByType($DeviceType, 0)

DebugMsg('strDescDocURL:' & $strDescDocURL)
DebugMsg("Found # :" & $Devices.Count & " Devices")
If $Devices.Count = 0 Then
DebugMsg("Unable to find Device.")
EndIf
For $DeviceObj In $Devices
$deiceDescription = "Children " & $DeviceObj.Children & @CRLF & "Description " & $DeviceObj.Description & @CRLF & "FriendlyName " & $DeviceObj.FriendlyName & @CRLF & "HasChildren " & $DeviceObj.HasChildren & @CRLF & "IsRootDevice " & $DeviceObj.IsRootDevice & @CRLF & "ManufacturerName " & $DeviceObj.ManufacturerName & @CRLF & "ManufacturerURL " & $DeviceObj.ManufacturerURL & @CRLF & "ModelName " & $DeviceObj.ModelName & @CRLF & "ModelNumber " & $DeviceObj.ModelNumber & @CRLF & "ModelURL " & $DeviceObj.ModelURL & @CRLF & "ParentDevice " & $DeviceObj.ParentDevice & @CRLF & "PresentationURL " & $DeviceObj.PresentationURL & @CRLF & "RootDevice " & $DeviceObj.RootDevice & @CRLF & "SerialNumber " & $DeviceObj.SerialNumber & @CRLF & "Services " & $DeviceObj.Services & @CRLF & "Device URN Type " & $DeviceObj.Type & @CRLF & "UniqueDeviceName " & $DeviceObj.UniqueDeviceName & @CRLF & "Product Code - UPC " & $DeviceObj.UPC & @CRLF
DebugMsg("Found The Following Device(s)" & @CRLF & $deiceDescription)
Next
If $Devices.Count > 0 Then Return 1
Return 0
EndFunc ;==>FindDevice

Func miniupnpcaddstatic($InternalIP, $InternalPort, $ExternalPort, $Protocol)
Local $ResultMiniUpnp = Run(@ComSpec & " /c " & ' upnpc-static.exe -a ' & $InternalIP & " " & $InternalPort & " " & $ExternalPort & " " & $Protocol, @ScriptDir, @SW_HIDE, 0x2 + 0x4)
Local $upnpc_static_output
While 1
; read output from cmd command
$upnpc_static_output = StdoutRead($ResultMiniUpnp)
;exit on error
If @error Then ExitLoop
; send output to window
If $upnpc_static_output Then DebugMsg($upnpc_static_output)
WEnd
EndFunc ;==>miniupnpcaddstatic

; This is my custom error handler
; we don't want script to fail if HNetCfg.NATUPnP fails
Func MyErrFunc()
$HexNumber = Hex($oMyError.number, 8)
If @error Then Return
Local $msg = "!> COM Error with HNetCfg.NATUPnP!" & @CRLF & @CRLF & _
"err.description is: " & @TAB & $oMyError.description & @CRLF & _
"err.windescription:" & @TAB & $oMyError.windescription & @CRLF & _
"err.number is: " & @TAB & $HexNumber & @CRLF & _
"err.lastdllerror is: " & @TAB & $oMyError.lastdllerror & @CRLF & _
"err.scriptline is: " & @TAB & $oMyError.scriptline & @CRLF & _
"err.source is: " & @TAB & $oMyError.source & @CRLF & _
"err.helpfile is: " & @TAB & $oMyError.helpfile & @CRLF & _
"err.helpcontext is: " & @TAB & $oMyError.helpcontext
DebugMsg($msg)
$g_eventerror = 1 ; something to check for when this function returns
Return
EndFunc ;==>MyErrFunc

Func DebugMsg($debugtext)
If $debug Then
Local $file = FileOpen(@ScriptDir & "" & $debuglog, 1)
If $file = -1 Then
MsgBox(0, "Error", "Unable to open file." & $debuglog)
Return 0
EndIf
FileWriteLine($file, @HOUR & ":" & @MIN & ":" & @SEC & ":" & @MSEC & "->" & $debugtext)
FileClose($file)
If $console Then ConsoleWrite($debugtext & @CR)
EndIf
Return 1
EndFunc ;==>DebugMsg


; #FUNCTION# ====================================================================================================================
; Name ..........: is_privateIP
; Description ...: Get if the IP is Private
; Syntax ........: is_privateIP($nIp)
; Parameters ....: $nIp - The IP to be checked
; Return values .: 1 - IP is Private
; 2 - IP is Public
; Author ........: Phoenix XL
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func is_privateIP($nIp)
Local $pri_addrs[5] = [ _
'10.0.0.0|10.255.255.255', _
'172.16.0.0|172.31.255.255', _
'192.168.0.0|192.168.255.255', _
'169.254.0.0|169.254.255.255', _
'127.0.0.0|127.255.255.255' _
];
Local $aAssign, $start, $end
Local $long_ip = ip2long($nIp)
If $long_ip = -1 Then Return SetError(1, 0, -1)
For $pri_addr In $pri_addrs
$aAssign = StringSplit($pri_addr, '|', 2);
$start = ip2long($aAssign[0])
$end = ip2long($aAssign[1])
; IF IS PRIVATE
If $long_ip >= $start And $long_ip <= $end Then Return True
Next

Return False;
EndFunc ;==>is_privateIP

; #FUNCTION# ====================================================================================================================
; Name ..........: ip2long
; Description ...: Convert the IPv4 into Long
; Syntax ........: is_privateIP($nIp)
; Parameters ....: $nIp - The IP to be checked
; Return values .:
; Author ........: Ptrex
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func ip2long($nIp)
$split = StringSplit($nIp, '.')
If $split < 4 Then Return -1
$long = ($split[1] * 16777216) + ($split[2] * 65536) + ($split[3] * 256) + ($split[4] * 1)
Return $long
EndFunc ;==>ip2long

Tell me if the code works for you too

Guinness,

Then I decided to give the program to my friends and do chat with them

But, that didnt work

This is the reason for port forwarding Edited September 11, 2012 by PhoenixXL

[guinness]

Ah, sorry PhoenixXL missed that point.