Problem when trying to accessing a array

[boelensman1]

Hi everybody,I have the following code:

Local $ini = IniReadSectionNames("settings.ini")
Global $program[$ini[0]+1][10]
If @error Then
MsgBox(4096, "", "Error occurred, while reading settings.ini")
Else
For $i = 1 To $ini[0]
if IniRead ( "settings.ini", $ini[$i], "main", "false" )=='true' Then
$main_program=$i
EndIf
Local $var=IniReadSection("settings.ini",$ini[$i])
For $a = 1 To $var[0][0]
$program[$i][$var[$a][0]]=$var[$a][1]
Next
Next
EndIf

MsgBox(4096, "", "Key: " & "path" & @CRLF & "Value: " & $program[$main_program]["path"])
MsgBox(4096, "", "Key: " & "asdf" & @CRLF & "Value: " & $program[$main_program]["asdf"])

Wich reads the following ini:

[NOTEPAD]
path=C:\Windows\system32\notepad.exe
ontop=true
exit=false
main=true
restart=true
[NOTEPAD++]
path=C:\Program Files (x86)\Notepad++
ontop=true
exit=true
restart=true

The problem is that both messageboxes return "true" while the first should return "C:\Windows\system32\notepad.exe" and the second key (asdf) doesn't even exist in the ini.

I have been trying to find out why it doesn't work for the past half an hour. It's probably something real simple. Thanks in advance

[guinness]

I think you need to read the Array wiki, because this $program[$main_program]["asdf"] is wrong since the second index should be an integer and not a string.

#include <Array.au3>

Local $aINISections = IniReadSectionNames(@ScriptDir & 'Example.ini')
Local $aPrograms[$aINISections[0] + 1][10], $iMainProgram = 0, $vVar = 0 ; Don't declare variables in loops.
If @error Then
    MsgBox(4096, '', 'Error occurred, while reading Example.ini')
Else
    For $i = 1 To $aINISections[0]
        $aPrograms[0][0] += 1
        $aPrograms[$i][0] = $aINISections[$i]

        If IniRead(@ScriptDir & 'Example.ini', $aINISections[$i], 'main', 'False') = 'True' Then
            $iMainProgram = $i
        EndIf

        $vVar = IniReadSection(@ScriptDir & 'Example.ini', $aINISections[$i])
        For $j = 1 To $vVar[0][0]
            $aPrograms[$i][$j] = $vVar[$j][1]
        Next

    Next
EndIf
_ArrayDisplay($aPrograms)
;~ MsgBox(4096, '', 'Key: ' & 'Path' & @CRLF & 'Value: ' & $aPrograms[$iMainProgram]['path'])
;~ MsgBox(4096, '', 'Key: ' & 'ASDF' & @CRLF & 'Value: ' & $aPrograms[$iMainProgram]['asdf'])

[MilesAhead]

It looks to me in the MsgBox calls as if you are trying to index the arrays using strings. If you want to use an associative array, use Scripting.Dictionary.

[guinness]

If they do decide to use an associative array, may I recommend at least looking at the Array Wiki.

[MilesAhead]

For a Dictionary with case insensitive keys my wrapper functions simplify construction and destruction. If construction fails @error is set to 1.

;use Scripting.Dictionary object for simple associative arrays
Func _AssocArray()
Local $aArray = ObjCreate("Scripting.Dictionary")
If @error Then
Return SetError(1, 0, 0)
EndIf
$aArray.CompareMode = 1
Return $aArray
EndFunc ;==>_AssocArray

Func _AssocArrayDestroy(ByRef $aArray)
If Not IsObj($aArray) Then
Return False
EndIf
$aArray.RemoveAll()
$aArray = 0
Return True
EndFunc ;==>_AssocArrayDestroy

For methods such as Exists("key"), see the docs here:

http://msdn.microsoft.com/en-us/library/x4k5wbx4(v=vs.84).aspx

It's pretty vanilla

Edited September 17, 2012 by MilesAhead