How to generate combinations of 0 and 1?

[E1M1]

Hello

Could anyone tell me by what logic is it possible to generate combinations of 1s and 0s for given length?

examples:

1:

1

0

2:

11

10

01

00

3:

111

110

100

101

011

010

001

000

It looks like n bit binary number.

[guinness]

Random perhaps? Though surprised as this should be simple for you, unless I misunderstood?

ConsoleWrite(_RandomBinaryString() & @CRLF)
ConsoleWrite(_RandomBinaryString(2) & @CRLF)
ConsoleWrite(_RandomBinaryString(3) & @CRLF)

Func _RandomBinaryString($iLength = Default) ; Returns a string.
    If StringIsInt($iLength) Then $iLength = Int($iLength)
    If $iLength <= 0 Or $iLength = Default Then $iLength = 1
    Local $sReturn = ''
    For $i = 1 To $iLength
        $sReturn &= String(Random(0, 1, 1))
    Next
    Return $sReturn
EndFunc   ;==>_RandomBinaryString

[FireFox]

Random perhaps?

Lucky me. I got this :

1
11
111

I think he wants to generate all possibilities, which makes the script more complex, I'm working on it.

Br, FireFox.

[E1M1]

I invented this but I somehow have to return it instead of writing to console. This seems to be little more tricky

func MakeTable($iLen,$Combinations = "")
For $i = 0 to 1
     If $iLen = 0 Then
         ConsoleWrite($Combinations&@CRLF)
         Return
     else
         MakeTable($iLen-1,$Combinations&$i)
     EndIf
Next
EndFunc

Edited September 22, 2012 by E1M1

[FireFox]

AND... Here you go ! :

#include <Array.au3>
#include <String.au3>

Global $iLength = 10, $aBytes[2 ^ $iLength]

For $iIndex = 0 To 2 ^ $iLength -1
    $aBytes[$iIndex] = Integer2Binary($iIndex, $iLength)
Next

_ArrayDisplay($aBytes) ;sorted

; scramble it
For $i = 2 ^ $iLength - 1 To 1 Step -1
    $new = Random(0, $i, 1)
    $tmp = $aBytes[$i]
    $aBytes[$i] = $aBytes[$new]
    $aBytes[$new] = $tmp
Next

_ArrayDisplay($aBytes) ;what you want

Func Integer2Binary($in, $len) ;coded by UEZ, edited by FireFox
    If $in = 0 Then Return StringFormat("%0" & $len & "s", 0)
    Local $bin
    While $in > 0
        $bin &= Mod($in, 2)
        $in = Floor($in / 2)
    WEnd
    $bin = _StringReverse($bin)
    $bin = StringFormat("%0" & $len & "s", $bin)
    Return ($bin)
EndFunc   ;==>Integer2Binary

Br, FireFox.

[E1M1]

Huge thanks to you.

[guinness]

Ah, now I get it FireFox. I read it too quickly and just thought they were wanting to create a random 'binary string.' Cheers.

[FireFox]

Huge thanks to you.

You're welcome

Ah, now I get it FireFox. I read it too quickly and just thought they were wanting to create a random 'binary string.' Cheers.

I got it, cheers too

Br, FireFox.