Read input text as you type problem.

[DicatoroftheUSA]

I am having trouble with setting up a "read as you type" function.

I want to have an input box that will run a function every time its value changes.

I do not want to launch the function under the WM_command function. Because I would have to almost rewrite the entire script it is going to be used in, and introduce a billion global variables.

Ideally I would like zero globals, but at most one for WM_command.

As it is in the example below, the function will run only when some event is returned from _guigetmsg(), which is logical, but is not the behavior I want.

also, I do not want the function to run every time any key is pressed, only when the value of the input box changes.

TIA, for any input.

expandcollapse popup

#region- Gui includes
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#endregion - includes


Global $gsWM_returnit, $Input1
GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

_testgui()
Func _testgui()
Local $nMsg
#region ### START Koda GUI section ### Form=
Local $Form1 = GUICreate("Form1", 412, 382, 192, 124)
$Input1 = GUICtrlCreateInput("Input1", 40, 48, 265, 21)
Local $List1 = GUICtrlCreateList("", 40, 72, 265, 175)
GUISetState(@SW_SHOW)
#endregion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()

Switch $nMsg
Case 0
ContinueLoop
Case -11
ContinueLoop
Case $GUI_EVENT_CLOSE
Exit
Case $Form1
Case $List1
Case $Input1
Case Else





EndSwitch
If $gsWM_returnit<>"" Then _DoSomething($gsWM_returnit)

WEnd


EndFunc ;==>_testgui

Func _DoSomething($sStuff)
ConsoleWrite("Return:"&$sStuff& @LF)
endfunc

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)


Switch _WinAPI_HiWord($wParam)
Case $EN_CHANGE

$gsWM_returnit = GUICtrlRead($Input1)
;~ ConsoleWrite($gsWM_returnit & @LF)
Case $hWnd
Case $iMsg
Case $lParam
Case Else
$gsWM_returnit = ""
EndSwitch

EndFunc ;==>WM_COMMAND

Edited September 24, 2012 by DicatoroftheUSA

[guinness]

It's quite difficult to use WM_COMMAND without using a Global variable, AutoIt kind of forces you too.

Anyway, here is a clean and working example.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $__Label = -9999

Example()

Func Example()
    Local $hGUI = GUICreate('Input Filter', 300, 30)
    $__Label = GUICtrlCreateInput('', 5, 5, 290)
    GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')
    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd
    GUIDelete($hGUI)
EndFunc   ;==>Example

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam, $ilParam
    GUICtrlSetData($__Label, StringRegExpReplace(GUICtrlRead($__Label), '[/:*?"<>|]', ''))
EndFunc   ;==>WM_COMMAND

Edit: It removes the following characters (/:*?"<>|) from a string.

Edited September 24, 2012 by guinness

[guinness]

Or using a 'flag' to detect a change in the input and run the function.

expandcollapse popup

#include <Date.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $__iLabel = -9999, $__iFlag = 0

Example()

Func Example()
    Local $hGUI = GUICreate('Input Filter', 300, 30)
    $__iLabel = GUICtrlCreateInput('', 5, 5, 290)
    GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')
    GUISetState(@SW_SHOW)

    While 1
        If $__iFlag Then
            $__iFlag = 0
            _Change()
        EndIf
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd
    GUIDelete($hGUI)
EndFunc   ;==>Example

Func _Change()
    ConsoleWrite('Change: ' & _Now() & @CRLF)
EndFunc   ;==>_Change

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam, $ilParam

    Local $iLoWord = _WinAPI_LoWord($iwParam)
    Local $iHiWord = _WinAPI_HiWord($iwParam)
    Switch $iLoWord
        Case $__iLabel
            Switch $iHiWord
                Case $EN_CHANGE
                    $__iFlag = 1
            EndSwitch
    EndSwitch
EndFunc   ;==>WM_COMMAND

[DicatoroftheUSA]

Or using a 'flag' to detect a change in the input and run the function.

Great, I think that will do the trick. I am having trouble seeing why your example works but mine didn't. Specifically why guigetmsg() isn't slowing down the return.

[guinness]

Great, I think that will do the trick. I am having trouble seeing why your example works but mine didn't. Specifically why guigetmsg() isn't slowing down the return.

Simple. because you have Case 0 with a continue loop, so it moves to the top again when GUIGetMsg is 0. Your function will never be called regardless of if the input has data in it. So either remove that or place the function part at the top of the While loop. Edited September 24, 2012 by guinness

[kylomas]

Dictator,

You are not testing for which control fired en_change. See the following:

#Include <GUIConstants.au3>
#Include <EditConstants.au3>
#Include <WindowsConstants.au3>
GUICreate('MyGUI', 300, 200)
$Input = GUICtrlCreateInput('', 10, 10, 280, 19)
$edit  = guictrlcreateedit("",10,40,100,20)
GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')
GUISetState()
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    Switch BitAND($wParam, 0xFFFF)
        Case $Input
            Switch BitShift($wParam, 16)
                Case $EN_CHANGE
                    ConsoleWrite(GUICtrlRead($Input) & @CR)
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

kylomas

[DicatoroftheUSA]

Simple. because you have Case 0 with a continue loop, so it moves to the top again when GUIGetMsg is 0. Your function will never be called regardless of if the input has data in it. So either remove that or place the function part at the top of the While loop.

[guinness]

Just a word of advice, try to stray away from using 'magic numbers' e.g. -11 or -3 and opt for using the variable instead. So $GUI_EVENT_MOUSEMOVE & $GUI_EVENT_CLOSE as I had no idea what -11 was.

[kylomas]

Dictator,

if by this

also, I do not want the function to run every time any key is pressed, only when the value of the input box changes.

you mean "when the user presses enter after typing" then this example from M23 will help.

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
Opt('GUIOnEventMode', 1)
$hGUI = GUICreate("Test", 200, 200)
GUISetOnEvent($GUI_EVENT_CLOSE, "On_Exit")
$hInput = GUICtrlCreateInput("", 10, 10, 100, 20)
$hButton = GUICtrlCreateButton("clear text", 120, 10)
GUICtrlSetState(-1, $GUI_HIDE)
GUICtrlSetOnEvent(-1, "On_Clear")
$hDummy = GUICtrlCreateDummy()
GUICtrlSetOnEvent(-1, "On_Dummy")
GUISetState(@SW_SHOW)
; Set accelerator for Enter to action the Dummy code
Dim $aAccelKeys[1][2] = [["{ENTER}", $hDummy]]
GUISetAccelerators($aAccelKeys)
While 1
    Sleep(10)
WEnd
Func On_Exit()
    Exit
EndFunc   ;==>On_Exit
Func On_Clear()
    GUICtrlSetData($hInput, "")
    GUICtrlSetState($hButton, $GUI_HIDE)
EndFunc   ;==>On_Clear
Func On_Dummy()
    ; Check input has focus
    If _WinAPI_GetFocus() = GUICtrlGetHandle($hInput) Then
        $sText = GUICtrlRead($hInput)
        MsgBox(0, "test", "You typed in " & $sText)
        GUICtrlSetState($hButton, $GUI_SHOW)
    EndIf
EndFunc   ;==>On_Dummy

The code I posted above isolates the en_change notification to the input control. Your code does not test for which control issued the notification.

kylomas

[DicatoroftheUSA]

@kylomas

Thanks guinness saw where I goofed up.

I just said that, because the default answer is "use hotkeys" or "capture keystrokes" which both methods are generally terrible in my opinion.

[guinness]

I wouldn't call it a 'goof up,' but at least you won't forget next time.