Detecting hanging app?

[iXX]

Hi!

Is there any way to detect if a specific application is hanging or not responding or crashing...?

Cant use of "ProcesExists()" function, because such app is "still there" - in the task manager list.

Thanks for any advance.

[water]

What do you mean by "specific application"? An application you've written yourself?

What do you mean by "hang"? Running in a loop and eating up all CPU cycles or doing nothing? Waiting for an event to occur (I/O or whatever ...)?

[FireFox]

@iXX

Maybe

Br, FireFox.

[guinness]

@iXX

Maybe

Br, FireFox.

That can be found in WinAPIEx.au3, the function is called _WinAPI_IsHungAppwindow.

[FireFox]

That can be found in WinAPIEx.au3, the function is called _WinAPI_IsHungAppwindow.

Let's say I'm oldschool. But thanks for having pointed out the right solution for now.

oh yes, I remember now this function but It's not the first thing that came up to my mind...

Edited October 3, 2012 by FireFox

[Skitty]

Now that I remember, I've seen that function in there.

But using the code FF linked, it'll keep your script much smaller and will launch much faster when debugging, except if you turn off Au3Check for it.

Anyway, here's an example for detecting a hung app, can be changed to work with other things.

expandcollapse popup

#include <Array.au3>

Global Const $hNTDLL = DllOpen("ntdll.dll")
Global Const $hUSER32 = DllOpen("user32.dll")
Global Const $hKERNEL32 = DllOpen("kernel32.dll")

Global $ChildPID
Global $aWinHwnds[1]
Global $GlobalWinCount

If StringInStr($CmdLineRaw, "WatchMe=", 2) Then
    $temporariis = StringSplit($CmdLineRaw, "WatchMe=")
    Monitor($temporariis[$temporariis[0]])
    Exit
EndIf

Switch @Compiled
    Case True
        $ChildPID = Run(FileGetShortName(@ScriptFullPath) & " WatchMe=" & @AutoItPID)
        Sleep(3000)
    Case False
        $ChildPID = Run(FileGetShortName(@AutoItExe) & ' /AutoIt3ExecuteScript "' & @ScriptFullPath & '" WatchMe=' & @AutoItPID)
        Sleep(3000)
EndSwitch

MsgBox(64, "Information!", "Process ("&@AutoItPID&") is about to be suspended, after this happens, our "&@CR&"child monitoring script should respond to the event. This may take a few seconds.")
_ProcessSuspend(@AutoItPID); simulate a non responsive GUI
MsgBox(16, "Information!", "Something happened D:"&@CR&"Obviously we don't have enough rights to suspend a process on this machine :("&@CR&"Too bad lol, try something else :P")
Exit

; #INTERNAL FUNCTION# ===========================================================================================================
; Name ..........: Monitor
; Description ...: Monitors the main instance of this script to prevent any unwanted system lockups.
; Syntax ........: Monitor($PID)
; Parameters ....: $PID                 - PID of our initiating instance.
; Return values .: None
; Example .......: No
; ===============================================================================================================================
Func Monitor($PID)
    Local $aReturn
    Local $Win = _EnumProcessWindows($PID,0)
    $Win = $Win[0]
    While ProcessExists($PID)
        Sleep(1000)
        $aReturn = DllCall($hUSER32, "Int", "IsHungAppWindow", "Hwnd", $Win)
        If @error Or $aReturn[0] Then ExitLoop
        ;If WinGetState($Win) = 16 Then WinSetState($Win,"",@SW_RESTORE)
    WEnd
    ProcessClose($PID)
    MsgBox(64, "Whoa!", "Seems like something went wrong with our script!" & @CR & @CR & _
    "A well trained team of monkeys were dispatched to take care of the problem...")
    Exit
EndFunc   ;==>Monitor

; #INTERNAL FUNCTION# ===========================================================================================================
; Name...........: _EnumProcessWindows
; Description....: Enumerates a windows that belong to the specified process.
; Syntax.........: _EnumProcessWindows ( [$PID [, $fVisible]] )
; Parameters.....: $PID      - The PID of the process.
;                  $fVisible - Specifies whether enumerates the invisible window, valid values:
;                  |TRUE     - Enumerate only visible windows. (Default)
;                  |FALSE    - Enumerate all windows.
; Return values..: Success   - The 1D array of window handles.
;                  Failure   - 0 and sets the @error flag to non-zero.
; Author.........: Yashied
; Modified.......: CaptainClucks
; Remarks........: I've slightly modified this for use in this script, only necesary stuff is keept here.
; Related........: __EnumWindowsProc
; Link...........: None
; Example........: No
; ===============================================================================================================================

Func _EnumProcessWindows($PID = 0, $fVisible = 1)
    $GlobalWinCount = 0
    Local $Threads = _GetAllProcessThreads($PID)

    If @error Then
        Return SetError(1, 0, 0)
    EndIf

    Local $hEnumProc = DllCallbackRegister('__EnumWindowsProc', 'int', 'hwnd;lparam')

    For $I = 0 To UBound($Threads) - 1
        DllCall($hUSER32, 'int', 'EnumThreadWindows', 'dword', $Threads[$I][0], 'ptr', DllCallbackGetPtr($hEnumProc), 'lparam', $fVisible)
        If @error Then
            ExitLoop
        EndIf
    Next
    DllCallbackFree($hEnumProc)
    If Not $aWinHwnds[0] Then
        Return SetError(1, 0, 0)
    EndIf
    Return $aWinHwnds
EndFunc   ;==>_EnumProcessWindows

Func __EnumWindowsProc($hWnd, $fVisible)
    If $fVisible Then
        Local $aResult = DllCall($hUSER32, "bool", "IsWindowVisible", "hwnd", $hWnd)
        If @error Then Return 1
        If Not $aResult[0] Then Return 1
    EndIf
    $GlobalWinCount += 1
    ReDim $aWinHwnds[$GlobalWinCount]
    $aWinHwnds[$GlobalWinCount - 1] = $hWnd
    Return 1
EndFunc   ;==>__EnumWindowsProc

; #FUNCTION# ====================================================================================================================
; Name ..........: _GetAllProcessThreads
; Description ...: Gets threads in a process
; Syntax ........: _GetAllProcessThreads($iPID)
; Parameters ....: $iPID                - Process ID.
; Return values .: Array with thread info
; Author ........: monoceres
; Remarks .......:
; Related .......: _GetAllThreads_ArrHelper, _ThreadSuspend, _ThreadResume
; Link ..........: http://www.autoitscript.com/forum/topic/85728-thread-enumeration-with-createtoolhelp32snapshot/
; Example .......: No
; ===============================================================================================================================

Func _GetAllProcessThreads($iPID)
    Local $call = DllCall($hKERNEL32, "ptr", "CreateToolhelp32Snapshot", "dword", 0x00000004, "dword", 0)
    Local $handle = $call[0]
    Local $RetArr[1][3]
    Local $te32 = DllStructCreate("dword dwSize;dword cntUsage;dword th32ThreadId;dword th32OwnerProcessID;long tpBasePri;long tpDeltaPri;dword dwFlags;")
    DllStructSetData($te32, "dwSize", DllStructGetSize($te32))
    $call = DllCall($hKERNEL32, "int", "Thread32First", "ptr", $handle, "ptr", DllStructGetPtr($te32))
    If DllStructGetData($te32, "th32OwnerProcessID") = $iPID Then _GetAllThreads_ArrHelper($RetArr, $te32)
    Do
        $call = DllCall($hKERNEL32, "int", "Thread32Next", "ptr", $handle, "ptr", DllStructGetPtr($te32))
        If Not $call[0] Then ExitLoop
        If DllStructGetData($te32, "th32OwnerProcessID") = $iPID Then _GetAllThreads_ArrHelper($RetArr, $te32)
    Until True And False
    _ArrayDelete($RetArr, 0)
    DllCall($hKERNEL32, "bool", "CloseHandle", "handle", $handle)
    Return $RetArr
EndFunc   ;==>_GetAllProcessThreads

Func _GetAllThreads_ArrHelper(ByRef $arr, $TE32_Struct)
    Local $ub = UBound($arr)
    ReDim $arr[$ub + 1][3]
    $arr[$ub][0] = DllStructGetData($TE32_Struct, "th32ThreadId")
    $arr[$ub][1] = DllStructGetData($TE32_Struct, "th32OwnerProcessID")
    $arr[$ub][2] = DllStructGetData($TE32_Struct, "tpBasePri")
EndFunc   ;==>_GetAllThreads_ArrHelper

; #FUNCTION# ====================================================================================================================
; Name ..........: _ProcessSuspend
; Description ...: suspends a process
; Syntax ........: _ProcessSuspend($Process)
; Parameters ....: $Process             - An unknown value.
; Return values .: None
; Author ........: The Kandie Man
; Modified ......: CaptainClucks
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _ProcessSuspend($Process)
    Local $processid = ProcessExists($Process)
    If $processid Then
        Local $ai_Handle = DllCall($hKERNEL32, 'int', 'OpenProcess', 'int', 0x1F0FFF, 'int', False, 'int', $processid)
        Local $i_sucess = DllCall($hNTDLL, "int", "NtSuspendProcess", "int", $ai_Handle[0])
        DllCall($hKERNEL32, 'ptr', 'CloseHandle', 'ptr', $ai_Handle[0])
        If IsArray($i_sucess) Then
            Return SetError(0, 0, True)
        Else
            Return SetError(1, 0, False)
        EndIf
    Else
        Return SetError(2, 0, False)
    EndIf
EndFunc   ;==>_ProcessSuspend

[iXX]

Very thak You!, especialy FF ang guiness! Thats what I am finding.

One more thing, after killing an process, is possible to remove its "dead icon" from system tray? (On Win7/x64).

[guinness]

Yes, use this function.

#include <WinAPI.au3>

_Taskbar_Refresh()

Func _Taskbar_Refresh() ; By rasim - http://www.autoitscript.com/forum/topic/66629-systemtray-refresh/
    Local $hTaskBar = _WinAPI_FindWindow("Shell_TrayWnd", "")
    Local $hParent = ControlGetHandle($hTaskBar, "", "TrayNotifyWnd1")
    Local $hHandle = ControlGetHandle($hParent, "", "ToolbarWindow321")
    Local $tWinRect = _WinAPI_GetWindowRect($hHandle)
    Local $aMouseGetPos = MouseGetPos()
    Local $iLeft = DllStructGetData($tWinRect, "Left")
    Local $iRight = DllStructGetData($tWinRect, "Right")
    Local $iTop = DllStructGetData($tWinRect, "Top")
    For $i = $iLeft To $iRight
        MouseMove($i, $iTop, 0)
    Next
    MouseMove($aMouseGetPos[0], $aMouseGetPos[1], 0)
EndFunc   ;==>_Taskbar_Refresh

Edited October 4, 2012 by guinness