~ Hide ListView Scrollbar disabels the ability to scroll? (SOLVED)

[EKY32]

I need to hide the ListView Scroll bars but still can use _GUICtrlListView_Scroll, this is my example:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <ListViewConstants.au3>
#include <GuiListView.au3>

$Form1 = GUICreate("Form1", 600, 300)
$ListView1 = GUICtrlCreateListView("|",380, 10, 150, 217, $LVS_NOCOLUMNHEADER + $LVS_NOSCROLL + $LVS_EX_FLATSB + $LVS_REPORT, 0)
GUICtrlSetCursor(-1, 0)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 150)
$ListView1_0 = GUICtrlCreateListViewItem("1", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("2", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("3", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("4", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("5", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("6", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("7", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("8", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("9", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("10", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("11", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("12", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("13", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("14", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("15", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("16", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("17", $ListView1)
$sup = GUICtrlCreateButton("up", 544, 16, 43, 25)
$sdown = GUICtrlCreateButton("down", 544, 56, 43, 25)

GUISetState(@SW_SHOW)


While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit


Case $sup
_GUICtrlListView_Scroll($ListView1, 0, - 10)

Case $sdown
_GUICtrlListView_Scroll($ListView1, 0, 10)


EndSwitch
WEnd

Using $LVS_NOSCROLL disables scrolling, not just hiding the bars, any help please?

Thank you.

Edited October 4, 2012 by EKY32

[BrewManNH]

There's a search function on the server for a reason, you should probably familiarize yourself with it and its operation.

[Melba23]

EKY32,

Why not hide the scrollbars rather then remove them:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <ListViewConstants.au3>
#include <GuiListView.au3>
#include <GuiScrollBars.au3>
#include <ScrollBarConstants.au3>

$Form1 = GUICreate("Form1", 600, 300)
$ListView1 = GUICtrlCreateListView("|", 380, 10, 150, 217, BitOr($LVS_NOCOLUMNHEADER, $LVS_EX_FLATSB, $LVS_REPORT), 0)
GUICtrlSetCursor(-1, 0)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 150)
$ListView1_0 = GUICtrlCreateListViewItem("1", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("2", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("3", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("4", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("5", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("6", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("7", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("8", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("9", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("10", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("11", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("12", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("13", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("14", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("15", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("16", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("17", $ListView1)

_GUIScrollBars_ShowScrollBar(GUICtrlGetHandle($ListView1), $SB_BOTH, False)

$sup = GUICtrlCreateButton("up", 544, 16, 43, 25)
$sdown = GUICtrlCreateButton("down", 544, 56, 43, 25)

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $sup
            _GUICtrlListView_Scroll($ListView1, 0, -10)
            _GUIScrollBars_ShowScrollBar(GUICtrlGetHandle($ListView1), $SB_BOTH, False)
        Case $sdown
            _GUICtrlListView_Scroll($ListView1, 0, 10)
            _GUIScrollBars_ShowScrollBar(GUICtrlGetHandle($ListView1), $SB_BOTH, False)
    EndSwitch
WEnd

And note how I combined the styles for the ListView - the Setting Styles tutorial in the Wiki explains why you should use BitOr rather than a simple addition.

M23

[EKY32]

There's a search function on the server for a reason, you should probably familiarize yourself with it and its operation.

I'm sorry, next time I will.

Thank you.

[EKY32]

Mr.Melba23 thank you very much, I understood.