Selecting nearest keyvalue in an ini if given value doesn't exist

[CptSpike 0]

Title may not be particularly clear, sorry I'm struggling to put my problem in to words. But here goes.

I'm writing a program that takes pixel colour info from the mouse pointer, and looks it up in an INI file to see the corresponding Pantone colour. Snippet of the INI looks like this:

16702208=108C

16765184=109C

14396928=110C

(Pantone colour on the right)

This is great if the pixel colour matches exactly, but if not, the user gets nothing. I want them to get the nearest match. Is it possible for AutoIt to select the nearest listed decimal number? I tried adding 1 to the pixel decimal number until it hits a matching a Pantone colour but this is far too slow.

Sorry if I'm not articulating this very well. Many thanks.

-CptSpike

[water 2,359]

How many entries do you have in your INI file?

[FireFox 260]

Hi,

I think you will need to get the section keys with IniReadSection and then comparing the data to get the nearest pantone color.

Br, FireFox.

[CptSpike 0]

Exactly 907 entries, only one section name Firefox.

[FireFox 260]

Exactly 907 entries, only one section name Firefox.

I haven't asked how many section do you have

[CptSpike 0]

No I mean there are no section names to compare - only one section name. [Decimal] to be precise.

[FireFox 260]

No I mean there are no section names to compare - only one section name. [Decimal] to be precise.

oh, I meant compare pantone colors in the array (which contains all pantone colors).

[water 2,359]

The solution Firefox suggests should do what you need. InIReadSections returns a 2D array. If the entries are already sorted then search until you find a value which is higher than the value you want to comapre. Then take this or the previous value.

You need to handle the situation where the first or last entry of the array is returned so you don't get out of bounds.

[CptSpike 0]

Oh I see. Hadn't thought about that. Still not sure where to go from there - most of the decimal values the program looks up won't be listed in the ini file, how would I get it to pick the closest match instead?

[water 2,359]

This example will return the next highest value if the search value is not found in the ini file. It returns -1 if the search value is higher then the highest value in the ini file.

Example works for this ini file:

[section1]

16702208=108C

16765184=109C

14396928=110C

#include <array.au3>
Global $aValues = IniReadSection("C:temppantone.ini", "Section1")
_Arraysort($aValues, 0, 1, 0, 0)
_ArrayDisplay($aValues)
Global $iReturn, $iSearchFor = 1670000
$iReturn = Search($iSearchFor)
MsgBox(0, "", "Value searched: " & $iSearchFor & @CRLF & "Value returned: " & $iReturn)

Func Search($iSearch)

    For $i = 1 To $aValues[0][0]
        If $aValues[$i][0] > $iSearch Then Return $aValues[$i][1]
        ConsoleWrite($i & @LF)
    Next
    Return -1 ; Value not found in table

Endfunc

[Melba23 3,398]

CptSpike,

Ii fear there is a fundamental flaw in your +1 theory. The colour is made up of 3 elements (RGB) and each of them can vary slightly. So you need to add to each element of the colour and not just the final total.

This code gives you the idea:

expandcollapse popup

$iPantone = "FEDB00" ; Hex of 16702208

; Simulate PixelGetColor converted to Hex
$iColor = "FDDA00"

$iRed = StringMid($iColor, 1, 2)
$iGrn = StringMid($iColor, 3, 2)
$iBlu = StringMid($iColor, 5, 2)

; Start by adding to R
$iTest_Color = Hex(Dec($iRed) + 1, 2) & $iGrn & $iBlu
If $iTest_Color = $iPantone Then
    ConsoleWrite("Found!" & @CRLF)
EndIf

; Now G
$iTest_Color = $iRed & Hex(Dec($iGrn) + 1, 2) & $iBlu
If $iTest_Color = $iPantone Then
    ConsoleWrite("Found!" & @CRLF)
Else
    ConsoleWrite($iTest_Color & " - " & $iPantone & @CRLF)
EndIf

; Now B
$iTest_Color = $iRed & $iGrn & Hex(Dec($iBlu) + 1, 2)
If $iTest_Color = $iPantone Then
    ConsoleWrite("Found!" & @CRLF)
Else
    ConsoleWrite($iTest_Color & " - " & $iPantone & @CRLF)
EndIf

; Now RG
$iTest_Color = Hex(Dec($iRed) + 1, 2) & Hex(Dec($iGrn) + 1, 2) & $iBlu
If $iTest_Color = $iPantone Then
    ConsoleWrite("Found!" & @CRLF)
Else
    ConsoleWrite($iTest_Color & " - " & $iPantone & @CRLF)
EndIf

; Now RB
$iTest_Color = Hex(Dec($iRed) + 1, 2) & $iGrn & Hex(Dec($iBlu) + 1, 2)
If $iTest_Color = $iPantone Then
    ConsoleWrite("Found!" & @CRLF)
Else
    ConsoleWrite($iTest_Color & " - " & $iPantone & @CRLF)
EndIf

; Now GB
$iTest_Color = $iRed & Hex(Dec($iGrn) + 1, 2) & Hex(Dec($iBlu) + 1, 2)
If $iTest_Color = $iPantone Then
    ConsoleWrite("Found!" & @CRLF)
Else
    ConsoleWrite($iTest_Color & " - " & $iPantone & @CRLF)
EndIf

; Now RGB
$iTest_Color = Hex(Dec($iRed) + 1, 2) & Hex(Dec($iGrn) + 1, 2) & Hex(Dec($iBlu) + 1, 2)
If $iTest_Color = $iPantone Then
    ConsoleWrite("Found!" & @CRLF)
Else
    ConsoleWrite($iTest_Color & " - " & $iPantone & @CRLF)
EndIf

You can see that you need to vary the colour elements separately to match the Pantone value. Of course in the real case you would need to subtract as well as add and the number of combinations you need to test becomes quite large. There should be a way of doing it faster using the Bit* functions rather then the cumbersome proof-of-concept code I used above - I will have a think about it.

M23

[jdelaney 313]

Using Water's array

#include <array.au3>
#include <Color.au3>
Global $aValues = IniReadSection("C:temppantone.ini", "Section1")
_Arraysort($aValues, 0, 1, 0, 0)
;_ArrayDisplay($aValues)
$iColor = 16702209
$iGreen = _ColorGetGreen ( $iColor )
$iRed = _ColorGetRed ( $iColor )
$iBlue = _ColorGetBlue ( $iColor )
ConsoleWrite ( $iGreen & " " & $iRed & " " & $iBlue & @CRLF )
Dim $aDiff[1][2]
$iCounter = 0
For $i = 1 To UBound ( $aValues ) - 1
 $iCurrentDiff = Abs ( _ColorGetGreen ( $aValues[$i][0] ) - $iGreen ) + Abs ( _ColorGetRed ( $aValues[$i][0] ) - $iRed ) + Abs ( _ColorGetBlue ( $aValues[$i][0] ) - $iBlue )
 ReDim $aDiff[$iCounter+1][2]
 $aDiff[$iCounter][0] = $iCurrentDiff
 $aDiff[$iCounter][1] = $i
 $iCounter += 1
Next
_ArraySort ( $aDiff, 0,0,0,0 )
$iLowestDiff = $aDiff[0][1]
ConsoleWrite ( "Value searched: " & $iColor & @CRLF & "Value returned: " & $aValues[$iLowestDiff][0] & @CRLF )

[CptSpike 0]

(OffTopic) I love this forum. So helpful.

(OnTopic) Will play around with my code more tomorrow, looks like the array method is the way to go. Thanks for pointing out the mathemathical flaw Melba - I assumed the colours would follow a linear decimal pattern. But life is never simple jdelaney, may I shamelessly steal your code?

[kylomas 415]

CptSpike,

Posted code is posted code...do yourself a favor and take time to understand the code.

Good Luck,

kylomas

[CptSpike 0]

Thought it would be nice to ask anyways thanks everyone for the help.

-CptSpike