StringRegExp General Help

[AZJIO]

guinness

expandcollapse popup

#include <Array.au3>
Local $sText = 'Local $GUI_CHECKED, $GUI_NOTDECLARED, $GUI_UNCHECKED, $sSomeVar, $sSomeVars' & @CRLF & _
        'Local $sData = "", $iExample = 0' & @CRLF & _
        '    Local $toto = ''toto'', $tata = ''ta,$xaxa'', _ ; ,$comments' & @CRLF & _
        '   $msg,  $aState[2] = [$GUI_CHECKED, $GUI_UNCHECKED], $tutu' & @CRLF & _
        @CRLF & _
        'Local Const $iLConst = 1000' & @CRLF & _
        'Const $iConst = 1000' & @CRLF & _
        'Local Enum Step *2 $eLEnum_1, $eLEnum_2' & @CRLF & _
        'Enum Step *2 $eEnum_1, $eEnum_2' & @CRLF & _
        'Local Static $sStatic = "Local Static"' & @CRLF & _
        'Static $sStatic = "Static"' & @CRLF & _
        'Local $aArray[10][2] = [[$GUI_CHECKED, 100], [$sSomeVar, $GUI_NOTDECLARED]], $aSRE[2] = [$GUI_UNCHECKED, $sSomeVars]' & @CRLF & _
        'Local $aSRE_2[2] = [$GUI_UNCHECKED, $sSomeVars]' & @CRLF & _
        'Local Const $iStringLeft = StringLeft($sData, StringInStr("", "")), $iStringRight = StringRight("", 100)' & @CRLF
; $sText = StringRegExpReplace($sText, '(?m)^((?:[^''";]*([''"]).*?\2)*[^;]*);.*$', '\1') ; remove one-line comments
_stripComments($sText)
$sText = StringRegExpReplace($sText, '\h+(?=[\r\n\z])', '') ; remove space
$sText = StringRegExpReplace($sText, ' _(\r\n|\n|\r)', ' ')
$aText = StringRegExp($sText, '(?mi)^\h*(?:(?:Local|Global|Static|Enum|Const)\h+(?:(?:Local|Global|Static|Enum|Const)\h+)?(?:Step(?:\h+\*\d+)?\h+)?)(.+?)\s+$', 3)
If Not @error Then
    $sRes = ''
    For $i = 0 To UBound($aText) - 1
        $aText[$i] = StringStripWS($aText[$i], 8)
        $aText[$i] = StringRegExpReplace($aText[$i], '([''"]).*?\1', '')
        Do
            $aText[$i] = StringRegExpReplace($aText[$i], '\([^()]*?\)', '')
        Until Not @extended
        Do
            $aText[$i] = StringRegExpReplace($aText[$i], '\[[^\[\]]*?\]', '')
        Until Not @extended
        $aVar = StringRegExp(',' & $aText[$i], '(?<=,)\$\w+', 3)
        If Not @error Then
            For $j = 0 To UBound($aVar) - 1
                $sRes &= $aVar[$j] & @CRLF
            Next
        EndIf
        ; $sRes &= @CRLF
    Next
EndIf
MsgBox(0, "Yes?", $sRes)

; "Organize Includes"
Func _stripComments(ByRef $string)
    $string = StringRegExpReplace($string, "(?s)\r(?!\n)", '\r\n') ; Adds @LF in string, AZJIO
    ;Author: Prog@ndy
    $string = StringReplace(StringReplace($string, "#comments-start", "#cs", 0, 2), "#comments-end", "#ce", 0, 2)
    $string = StringRegExpReplace($string, "(?si)(\v|\A)\h*#cs\b.*?\v\h*#ce\b", '') ; remove simple block comments (Modified AZJIO)
    #Region remove nested block-comments
    Local $match, $depth, $offset, $start, $CommentsAfterce
    While 1
        $depth = 0
        $match = StringRegExp($string, "(?im)^\h*#cs\b", 1)
        $start = @extended
        If @error Then ExitLoop
        Do
            $match = StringRegExp($string, "(?im)^\h*#c([se])\b", 1, $offset)
            $offset = @extended
            Select
                Case @error
                    Return False
                Case $match[0] = "e"
                    $depth -= 1
                Case Else
                    $depth += 1
            EndSelect
        Until $depth < 1

        $string = StringLeft($string, $start - 4) & StringRegExpReplace(StringMid($string, $offset), ".*", '', 1)
;~         $string = StringLeft($string, $start-4) & StringMid($string, $offset)
    WEnd
    #EndRegion remove nested block-comments
    $string = StringRegExpReplace($string, '(?m)^((?:[^''";]*([''"]).*?\2)*[^;]*);.*$', '\1') ; remove one-line comments (недостаток - не работает если @CR без @LF)
    Return True
EndFunc   ;==>_stripComments

[czardas]

Azijo I think this can be simplified ==> "[rnz]" ==> "[vz]" Maybe I'm wrong.

Edited March 21, 2013 by czardas

[AZJIO]

czardas

v = [rnf]

Do not know

guinness

I often use these groups, they are popular. I think it makes sense to add them to the help file

(?=...)

(?!...)

(?<=...)

(?<!...)

Edited March 21, 2013 by AZJIO

[czardas]

czardas

v = [rnf]

Do not know

I'm not sure why any vertical white space character other than CR and LF would appear in a script. I doubt using 'v' would break the script, but I do see the logic of your choice.

[PhoenixXL]

I'm not sure why any vertical white space character other than CR and LF would appear in a script.

Most probably it won't but even if it comes it would serve the same purpose and should be treated equally.

[guinness]

Thanks AZJIO. I will ponder over your implementation today. I tried yesterday to do the replacing before looping, but to no avail.

I've started to just use lookarounds, how awesome are they?!

[guinness]

Thanks once again AZJIO. I had the same SRE in my script for removing brackets and content in between parenthesis, but the clue was just do it in a Do...Until loop until no more replacements. I'm sure there is a regular expression that can be created which does away with the Do...Until loop, but for now this works well.

[guinness]

To those that understand SREs, improve this!

It works well and I'm really starting to get the feel for conditional statements and lookarounds. But as ever I want to know the best practices. Thanks.

#include <Array.au3>
#include <Constants.au3>

Local $sData = 'AdlibRegister("_Function_1", 1000)' & @CRLF
$sData &= 'AdlibUnRegister("_Function_2", 1000)' & @CRLF
$sData &= 'Call("_Function_3")' & @CRLF
$sData &= 'DllCall("_Function_ShouldNOTDisplay")' & @CRLF
$sData &= 'GUICtrlRegisterListViewSort($iControl, "_Function_4")' & @CRLF
$sData &= 'TrayItemSetOnEvent("1000", "_Function_5")' & @CRLF
$sData &= 'HotKeySet("^,", "_Function_6")' & @CRLF
$sData &= "TrayItemSetOnEvent(1000, '_Function_7')" & @CRLF
Local $sReturn = ''

$sData = StringStripWS($sData, $STR_STRIPALL) ; Not really required!
Local $aArray = StringRegExp($sData, '(?i:Adlib(?:Un)?Register|(?<!\w)Call|DllCallbackRegister|OnAutoItExit(?:Un)?Register)\(["''](\w+)["'']', 3)
For $i = 0 To UBound($aArray) - 1
    $sReturn &= $aArray[$i] & @CRLF
Next
$aArray = StringRegExp($sData, '(?i:GUICtrlRegisterListViewSort|GUICtrlSetOnEvent|GUIRegisterMsg|HotKeySet|TraySetOnEvent|TrayItemSetOnEvent)' & _
        '\((?(?="|'').+?["''])[^,]*?,\h*["''](\w+)["'']', 3)
For $i = 0 To UBound($aArray) - 1
    $sReturn &= $aArray[$i] & @CRLF
Next

$aArray = StringSplit(StringTrimRight($sReturn, 2), @CRLF, 1) ; 2 is StringLen(@CRLF)
_ArrayDisplay($aArray)

Edited March 25, 2013 by guinness

[czardas]

I find reading SRE's I haven't written myself very confusing. I wasn't aware you could do this (Interesting):

ConsoleWrite('["'']')

I normally would use the hex for characters that might cause problems, or that can't be escaped normally.

Can't you just write 2 instead of this?

StringLen(@CRLF)

Edited March 25, 2013 by czardas

[Mechaflash]

'"' = """

"'" = '''

"can't" = 'can''t'

'"can''t"' = ""can't""

XD

[guinness]

Can't you just write 2 instead of this?

StringLen(@CRLF)

I could, but then I do this for readability.

I find reading SRE's I haven't written myself very confusing. Interesting - I wasn't aware you could do this:

I believe it's better than (?:''|"") (which I would use in this case, as I don't need to capture ' or ".

[guinness]

'"' = """

"'" = '''

"can't" = 'can''t'

'"can''t"' = ""can't""

XD

Would you care to explain further please?

[czardas]

I could, but then I do this for readability.

Okay, it's a personal choice. I would personally prefer to add comments (if they are needed) instead. You are calling a function where it isn't needed.

I believe it's better than (?:''|"") (which I would use in this case, as I don't need to capture ' or ".

I was refering to the nested single quote syntax, not to the the type of group. Edited March 25, 2013 by czardas

[guinness]

Oh OK, it's how you escape it. I think the help file explains this.

You're right about usage, but if in the future @CRLF changes to 4, then I have nothing to worry about.

[czardas]

You're right about usage, but if in the future @CRLF changes to 4, then I have nothing to worry about.

Lol. Did you read my edit?

[guinness]

About comments? Yes. But if I have a compiled executable out in the big Internet wide world, then comments are of no use then. I don't think it increases execution time that much or does it?

Edit: See code above. Happy?

Edited March 25, 2013 by guinness

[Kyan]

To those that understand SREs, improve this!

It works well and I'm really starting to get the feel for conditional statements and lookarounds. But as ever I want to know the best practices. Thanks.

#include <Array.au3>
#include <Constants.au3>

Local $sData = 'AdlibRegister("_Function_1", 1000)' & @CRLF
$sData &= 'AdlibUnRegister("_Function_2", 1000)' & @CRLF
$sData &= 'Call("_Function_3")' & @CRLF
$sData &= 'DllCall("_Function_ShouldNOTDisplay")' & @CRLF
$sData &= 'GUICtrlRegisterListViewSort($iControl, "_Function_4")' & @CRLF
$sData &= 'TrayItemSetOnEvent("1000", "_Function_5")' & @CRLF
$sData &= 'HotKeySet("^,", "_Function_6")' & @CRLF
$sData &= "TrayItemSetOnEvent(1000, '_Function_7')" & @CRLF
Local $sReturn = ''

$sData = StringStripWS($sData, $STR_STRIPALL) ; Not really required!
Local $aArray = StringRegExp($sData, '(?i:Adlib(?:Un)?Register|(?<!\w)Call|DllCallbackRegister|OnAutoItExit(?:Un)?Register)\(["''](\w+)["'']', 3)
For $i = 0 To UBound($aArray) - 1
    $sReturn &= $aArray[$i] & @CRLF
Next

$aArray = StringRegExp($sData, '(?i:GUICtrlRegisterListViewSort|GUICtrlSetOnEvent|GUIRegisterMsg|HotKeySet|TraySetOnEvent|TrayItemSetOnEvent)' & _
        '\((?(?="|'').+?["''])[^,]*?,\h*["''](\w+)["'']', 3)
For $i = 0 To UBound($aArray) - 1
    $sReturn &= $aArray[$i] & @CRLF
Next

$aArray = StringSplit(StringTrimRight($sReturn, StringLen(@CRLF)), @CRLF, 1)
_ArrayDisplay($aArray)

Hi!

I learning SRE, could you explain the use of "(?:Un)" and "?<!"

'=!' = '<>'

'<!' = '<=' ?

[czardas]

About comments? Yes. But if I have a compiled executable out in the big Internet wide world, then comments are of no use then. I don't think it increases execution time that much or does it?

It won't make so much different to speed, but I think it's not typical.

Edit: See code above. Happy?

Yes thanks!

I think it's very good.

Edited March 25, 2013 by czardas

[guinness]

"(?:Un)?"

Create a non-capture group of "Un" and check for AdlibRegister or AdLibUnRegister. Notice the placement of Un. The ? at the end means it might not exist, which is when it would find AdlibRegister.

"?<!"

Negative lookbehind. If behind Call is a word character e.g. l, then fail because it's not Call, but instead something like DllCall.

It won't make so much different to speed, but I think it's not typical.

I'm not typical nor conventional. You should know this by now. Edited March 25, 2013 by guinness

[PhoenixXL]

@guinness,

You are trying to find the string nested inside function ?

Am I getting it right ?

Edit :

Negative lookbehind. If behind Call is a word character e.g. l, then fail because it's not Call, but instead something like DllCall.

a W character would even match(not assertion) instead, there is no requirement for a negative assertion here. Edited March 26, 2013 by PhoenixXL