removing dashes in keys

[xilace]

Hi,

I'm looking to consolidate product keys. I had my script working and removing dashes properly using stringinstr to get the position and then a series of stringmid's to format the key from something like "CD Key: aaaaa-bbbbb-ccccc-ddddd" to just "aaaaabbbbbcccccddddd"

Problem came when the string I was initially searching with stringinstr changed its positioning such as instead of the above it may be like "CD key for windows -".

So now what i was thinking of doing was have it find the "-" symbol, then if its found again 5 more characters to the right as you would see in a serial code Then grab that positioning. Anybody have an idea how to do that though? Below is what I was initially using.

;Parse results looking for CD Key:"
Local $result = StringInStr($strReturn, "CD Key:")

;take the character postion of where "CD Key:" was found and copy the next 29 characters after that
Local $PCcode = StringMid($strReturn, $result + 49, 29)

;remove dashes from the code and put back together
Local $PCcodePart1 = StringLeft($PCcode, 5)
Local $PCcodePart2 = StringMid($PCcode, 7, 5)
Local $PCcodePart3 = StringMid($PCcode, 13, 5)
Local $PCcodePart4 = StringMid($PCcode, 19, 5)
Local $PCcodePart5 = Stringmid($PCcode, 25, 5)
Local $PCcode= ($PCcodePart1 & $PCcodePart2 & $PCcodePart3 & $PCcodePart4 & $PCcodePart5)

Edited November 1, 2012 by xilace

[guinness]

Why not use a regular expression instead? Look at StringRegExpReplace in the help file.

Edited November 1, 2012 by guinness

[caleb41610]

I think StringReplace() would be the easiest method

[guinness]

I think StringReplace() would be the easiest method

To remove, yes, but what about to put back?

[guinness]

Like this >>

Local Const $sString = 'aaaaabbbbbcccccddddd'
MsgBox(4096, '', StringRegExpReplace($sString, '(w{5})(w{5})(w{5})(w{5})', '1-2-3-4'))

[jchd]

I think the OP needs the exact opposite

Local Const $sString = 'ACME CD key is there: aaaaa-bbbbb-ccccc-ddddd'
MsgBox(4096, '', StringRegExpReplace($sString, '(w{5})-(w{5})-(w{5})-(w{5})', '1234'))

[guinness]

Well at least they now know how to remove and get them back.

[xilace]

I'm sure i made this far more complicated than needed, but I was able to understand it where as i couldnt with the regex examples.

;Parse the results looking for a key
local $i = 0
Do
Local $findPCkey = StringInStr($strPCReturn, "-", $i)
If StringMid($strPCReturn, $findPCkey + 6, 1) = "-" Then
$i = $i + 1
If StringMid($strPCReturn, $findPCkey + 6, 1) = "-" Then
$i = $i + 1
If StringMid($strPCReturn, $findPCkey + 6, 1) = "-" Then
Local $PCkey = StringMid($strPCReturn, $findPCkey - 5, 30)
$i = 20
EndIf
EndIf
EndIf
Until $i = 20



;remove dashes from the code and put back together
  Local $PCkeyPart1 = StringLeft($PCkey, 5)
  Local $PCkeyPart2 = StringMid($PCkey, 7, 5)
  Local $PCkeyPart3 = StringMid($PCkey, 13, 5)
  Local $PCkeyPart4 = StringMid($PCkey, 19, 5)
  Local $PCkeyPart5 = Stringmid($PCkey, 25, 5)
  Local $PCkey= ($PCkeyPart1 & $PCkeyPart2 & $PCkeyPart3 & $PCkeyPart4 & $PCkeyPart5)

Edited November 2, 2012 by xilace

[jchd]

Didn't my example work for you or do you mean you'd like to have its working dissected before your very eyes?

[SmOke_N]

You could have fun with it:

expandcollapse popup

#include <Array.au3>; just for _ArrayDisplay

#region cdkey with 4 groups of 5 chars
Global $gs_cdKeyStr = "CD Key: aaaaa-bbbbb-ccccc-ddddd"
Global $ga_cdKeyArg = _cdkey_toArray($gs_cdKeyStr, 4)
_ArrayDisplay($ga_cdKeyArg)

; convert to regular string
Global $gs_cdKeyToStr = _cdkey_arrayToStr($ga_cdKeyArg)
MsgBox(64 + 262144, "_cdkey_arrayToStr", $gs_cdKeyToStr)

; convert string back
Global $gs_cdKeyProper = _cdkey_arrayToProperStr($ga_cdKeyArg)
MsgBox(64 + 262144, "_cdkey_arrayToProperStr", $gs_cdKeyProper)
#endregion cdkey with 4 groups of 5 chars

#region cdkey with 5 groups of 5 chars
Global $gs_cdKeyStr = "CD Key: aaaaa-bbbbb-ccccc-ddddd-eeeee"
Global $ga_cdKeyArg = _cdkey_toArray($gs_cdKeyStr)
_ArrayDisplay($ga_cdKeyArg)

; convert to regular string
Global $gs_cdKeyToStr = _cdkey_arrayToStr($ga_cdKeyArg)
MsgBox(64 + 262144, "_cdkey_arrayToStr", $gs_cdKeyToStr)

; convert string back
Global $gs_cdKeyProper = _cdkey_arrayToProperStr($ga_cdKeyArg)
MsgBox(64 + 262144, "_cdkey_arrayToProperStr", $gs_cdKeyProper)
#endregion cdkey with 5 groups of 5 chars



Func _cdkey_toArray($s_key, $i_repeat = 5, $i_charlen = 5, $s_delim = "-")

    If Int($i_repeat) < 1 Then $i_repeat = 1

    Local $s_pattern = "(?i)"
    For $i = 1 To $i_repeat - 1
        $s_pattern &= "([a-z0-9]{" & $i_charlen & "})" & $s_delim
    Next

    $s_pattern &= "([a-z0-9]{" & $i_charlen & "})(?:z|W)"

    Return StringRegExp($s_key, $s_pattern, 1)
EndFunc

Func _cdkey_arrayToStr(ByRef $a_args)

    If Not IsArray($a_args) Then Return SetError(1, 0, "")

    Local $s_ret = ""
    For $i = 0 To UBound($a_args) - 1
        $s_ret &= $a_args[$i]
    Next

    Return $s_ret
EndFunc

Func _cdkey_arrayToProperStr(ByRef $a_args, $s_delim = "-")

    If Not IsArray($a_args) Then Return SetError(1, 0, "")

    Local $s_ret = ""
    For $i = 0 To UBound($a_args) - 2
        $s_ret &= $a_args[$i] & $s_delim
    Next
    $s_ret &= $a_args[UBound($a_args) - 1]

    Return $s_ret
EndFunc