Emailing with AutoIT3

[ryandao]

Hi,

I'm trying to AutoIT with JMail to email my co-workers and I after a particular task has been completed. I was able to get JMail to work with Kixtart but wasn't able to get it to work with AutoIT, I'm sure it's my fault since I'm not familiar with AutoIT. Any sample codes for this or another other free email program would be greatly appreciated.

http://www.dimac.net/Products/w3JMail/start.htm

Thx

Ryan

[DaleHohm]

There have been a couple of discussion of this recently with working code posted. I'd suggest you search the forums while you wait for someone else to respond who may have specific pointers.

Dale

[ryandao]

Got AutoIt to work with bmail.

Thx

[MSLx Fanboy]

Here's an example that uses COM functionality (requires autoit beta)

expandcollapse popup

;=============================================================
; Global Settings
$smtpserver = "";smtp server address (i.e. mail.server.com)
$smtpuser = "";smtp username (i.e. john_doe)
$smtppass = "";smtp password (i.e. my_s3cret_P@$$)
;
;=============================================================

Func SendEmail($e_Sender, $e_Recipient, $e_Subject, $e_Text)
    $objMessage = ObjCreate ("CDO.Message")
    With $objMessage
        .Subject = $e_Subject
        .Sender = $e_Sender
        .From = $e_Sender
        .To = $e_Recipient
        .TextBody = $e_text
    ;.AddAttachment ("") ;Needs FULL path!!!
    EndWith
    With $objMessage.Configuration.Fields
        .Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
        .Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $smtpserver
        .Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        .Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $smtpuser
        .Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $smtppass
        .Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
        .Item ("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
        .Update
    EndWith
    $objMessage.Send
    Return
EndFunc  ;==>SendEmail


;;Error handler functions in case there was an error with email
Dim $oMyError = ObjEvent ("AutoIt.Error", "ErrorHandler")
Func ErrorHandler()
    
    $HexNumber = Hex($oMyError.number, 8)
    
    MsgBox(0, "", "We intercepted a COM Error !" & @CRLF & @CRLF & _
            "err.description is: " & @TAB & $oMyError.description & @CRLF & _
            "err.windescription:" & @TAB & $oMyError.windescription & @CRLF & _
            "err.number is: " & @TAB & $HexNumber & @CRLF & _
            "err.lastdllerror is: " & @TAB & $oMyError.lastdllerror & @CRLF & _
            "err.scriptline is: " & @TAB & $oMyError.scriptline & @CRLF & _
            "err.source is: " & @TAB & $oMyError.source & @CRLF & _
            "err.helpfile is: " & @TAB & $oMyError.helpfile & @CRLF & _
            "err.helpcontext is: " & @TAB & $oMyError.helpcontext _
            )
    
    SetError(1); to check for after this function returns
    Exit
EndFunc  ;==>ErrorHandler