I am having trouble understanding GUIRegisterMsg()

[jrumbaug]

I am working on a popup picklist based on code samples from HELP. I am having trouble understanding GUIRegisterMsg(). The code posted works OK. I am concerned because I am getting my return value from the function named by GUIRegisterMsg() by setting a value to a GLOBAL variable. Is there a better way to do this, a way that does not use a GLOBAL variable?

Thanks in advance

Jim Rumbaugh

expandcollapse popup

;;; _PickList
;;; send an array of items to choose
;;; one item returned via DOUBLE CLICK with mouse or pressing ENTER key
;;; size of window automatically adjusts HEIGHT and WIDTH 
;;; to number of items in list and width of text used in list or title
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <ListBoxConstants.au3>
#include <Array.au3>
#include <Math.au3>
#Include <Misc.au3>

Global $glExitMyList = 0
Local $aList[5] = [ 'Test1','Test2','Test3','Test4','Test123456789123456789' ]

MsgBox(1,"selected", _PickList( $aList,"My Pick List",'Test3',100 , 100  ))

Func _PickList($aList = "",$cTitle="My List",$cDefault="",$nLeft=100,$nTop=100 )

 Local $nTitleWidth, $nListWidth, $i
 Local $Form1, $mylist
;;;;;;;; determine window height per number of elements in list
 $nHeight = (UBound($aList) * 12) + 30
;;;;;;; determine window width per maximum width of elements in LIST or TITLE
 $nTitleWidth = StringLen($cTitle )*6 + 100
 For $i = 0 To UBound($aList)-1
   $nListWidth  = _Max( $nListWidth , StringLen( $aList[$i])*7 )
 Next
 $nWidth = _Max( $nTitleWidth , $nListWidth )


 $Form1  = GUICreate(  $cTitle , $nWidth , $nHeight , $nLeft , $nTop )
 $mylist = GUICtrlCreateList( "" ,10,10,$nWidth - 20,$nHeight - 20, $cDefault )
 GUICtrlSetData( $mylist , _ArrayToString( $aList,"|") ,  $cDefault )
 GUISetState(@SW_SHOW)
 ;;; command to start DBL CLICK detection function
 GUIRegisterMsg($WM_COMMAND, "_IF_LIST_DBLCLICK")

  While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
    ;;;; if ENTER KEY or LEFT ARROW  or RIGHT ARROW pressed, Exit
    If _IsPressed( "0D" ) Or _IsPressed( "25" ) Or _IsPressed( "27" ) Then
        ExitLoop
    EndIf
    ;; See if  _IF_LIST_DBLCLICK() detected a DBLCLICK from the list
    If $glExitMyList = $mylist    Then
        ExitLoop
    EndIf

 WEnd
 Return GUICtrlRead($mylist)
EndFunc

Func _IF_LIST_DBLCLICK($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $lParam

    $iIDFrom = BitAND($wParam, 0xFFFF) ; Low Word
    $iCode   = BitShift($wParam, 16) ; Hi Word

    Switch $iCode
        Case $LBN_DBLCLK
            ;; set global variable to ID of form 
            $glExitMyList = $iIDFrom
     EndSwitch
EndFunc

[guinness]

No, unfortunately with certain AutoIt functions you're forced to a use a Global variable. GUIRegisterMsg is one of those functions.

Some advice, I would use this instead in GUIRegisterMsg for readability.

$iIDFrom = _WinAPI_LoWord($wParam) ; Low Word
$iCode   = _WinAPI_HiWord($wParam) ; Hi Word

Edited November 9, 2012 by guinness

[Melba23]

jrumbaug,

Just to offer a contrary opinion, I would keep the Bit* operations - then you do not need to #include <WinAPI.au3>. But do also keep the Lo/Hi comments so that you know what the operations are doing!

M23

[jrumbaug]

Thank you both.

I consider my question solved.

Jim Rumbaugh