Getting pixel color set with GUICtrlSetGraphic($graph,$GUI_GR_PIXEL, $X, $Y)

[phedlund]

Greetings,

I am trying to find the complimentary function of GuiCtrlSetGraphic($GR, $GUI_GR_PIXEL, $x $y)

I have tried to use PixelGetColor without success.$GR is created with GUICtrlCreateGraphic and I can

write to it ok, but its the reading back I am looking for.

Any help would be appreciated.

[Melba23]

phedlund,

You will need to convert the coordinates to screen values like this:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

$hGUI = GUICreate("Test", 500, 500, 100, 100)

$cGraphic = GUICtrlCreateGraphic(10, 10, 200, 200)
$hGraphic = GUICtrlGetHandle($cGraphic)

GUICtrlSetGraphic($cGraphic, $GUI_GR_COLOR, 0xFF0000, 0x00FF00)
GUICtrlSetGraphic(-$cGraphic, $GUI_GR_RECT, 10, 10, 100, 100)

$cButton_1 = GUICtrlCreateButton("Read 10, 10", 10, 200, 80, 30) ; Should be the red border
$cButton_2 = GUICtrlCreateButton("Read 11, 11", 10, 250, 80, 30) ; Should be the green interior

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton_1
            _GUICtrlGetGraphic(10, 10) ; Pass the coords used to draw the graphic
        Case $cButton_2
            _GUICtrlGetGraphic(11, 11)
    EndSwitch
WEnd

Func _GUICtrlGetGraphic($iX, $iY)
    ; Create a point structure
    Local $tPoint = DllStructCreate("int X;int Y")
    ; Insert the client coords
    DllStructSetData($tPoint, "X", $iX)
    DllStructSetData($tPoint, "Y", $iY)
    ; Convert the client coords to screen coords
    _WinAPI_ClientToScreen($hGraphic, $tPoint)
    ; Get the colour of the pixel using the screen coords
    $iColour = Hex(PixelGetColor(DllStructGetData($tPoint, "X"), DllStructGetData($tPoint, "Y")), 6)
    ; And announce the result
    MsgBox(0, "Pixel Colour", "The Pixel at " & $iX & ", " & $iY & " has colour: 0x" & $iColour)
EndFunc

Al clear? Please ask if not.

M23

[phedlund]

Yes thank you, Much clearer now. I was hoping I just missed something and there was a sub function in the GUICtrlSetGraphic that i had missed.

Your solution does make sense.

Thanks again.