Trying to compare two arrays and find matches from one in the other.

[PowerCat]

I'm trying to make a script, however having difficulty.

I have two arrays, one of the terms that I'd like to match, and the other one an array of sentences.

I've made this so far, however it keeps finding only position 0, 6 and 2...

I don't get why, and I would welcome any better way to do this, as I can't seem to wrap my head around doing this properly...

expandcollapse popup

#include <Array.au3>

Dim $SearchTerms[3]

$SearchTerms[0] = "Term1"
$SearchTerms[1] = "Term2"
$SearchTerms[2] = "Term3"

Dim $SearchList[10]

$SearchList[0] = "This sentence may contain term1"
$SearchList[1] = "This one doesn't match anything"
$SearchList[2] = "This one may match term1 and term3"
$SearchList[3] = "This one matches term3"
$SearchList[4] = "No match here"
$SearchList[5] = "I'm running out of things to write"
$SearchList[6] = "Term2 comes up here"
$SearchList[7] = "I can't see what's going on"
$SearchList[8] = "Blah blah blah term3"
$SearchList[9] = "no"

$MatchedPosition = ""

For $i = 0 to ubound($SearchList)-1

;enter FOR loop. it will loop 10 times for $searchlist

ConsoleWrite("-- Processing array SearchList, at position " & $i & ". Val = " & $SearchList[$i] & @CRLF)

For $j = 0 to ubound($searchterms)-1
ConsoleWrite('Looking for "' & $searchterms[$j] & '" in "' & $SearchList[$i] & '"' & @CRLF)

; enter sub FOR loop, it will compare the current search item to the terms

$isMatch = _ArraySearch($SearchList, $SearchTerms[$j], 0, ubound($SearchList)-1, 0, 1)

ConsoleWrite("> found at " & $isMatch & @CRLF)

Next

Next

Edited December 10, 2012 by PowerCat

[PowerCat]

I was able to get this to work the way I'd like, but I'm still wondering if there's any better way:

expandcollapse popup

#include <Array.au3>
Dim $SearchTerms[3]
$SearchTerms[0] = "Term1"
$SearchTerms[1] = "Term2"
$SearchTerms[2] = "Term3"
Dim $SearchList[10]
$SearchList[0] = "This sentence may contain term1"
$SearchList[1] = "This one doesn't match anything"
$SearchList[2] = "This one may match term1 and term3"
$SearchList[3] = "This one matches term3"
$SearchList[4] = "No match here"
$SearchList[5] = "I'm running out of things to write"
$SearchList[6] = "Term2 comes up here"
$SearchList[7] = "I can't see what's going on"
$SearchList[8] = "Blah blah blah term3"
$SearchList[9] = "no"
$MatchedPosition = ""
For $i = 0 to ubound($SearchList)-1
;enter FOR loop. it will loop 10 times for $searchlist
ConsoleWrite("-- Processing array SearchList, at position " & $i & ". Val = " & $SearchList[$i] & @CRLF)
For $j = 0 to ubound($searchterms)-1
 ConsoleWrite('Looking for "' & $searchterms[$j] & '" in "' & $SearchList[$i] & '"' & @CRLF)
 ; enter sub FOR loop, it will compare the current search item to the terms
 $isMatch = _ArraySearch($SearchList, $SearchTerms[$j], 0,  ubound($SearchList)-1, 0, 1)
 $isMatch = _ArrayFindAll($SearchList, $SearchTerms[$j], "", "", "", 1)
 if IsArray($ismatch) then
  $Positions = _ArrayToString($ismatch)
  $MatchedPosition = $MatchedPosition & $Positions & "|"
 Else
 EndIf
 ConsoleWrite("> found at " & $isMatch & @CRLF)
Next
Next
$MatchedPosition = StringTrimRight($MatchedPosition, 1)
$Matches = StringSplit($MatchedPosition, "|", 2)
$matches = _ArrayUnique($Matches)
_ArrayDelete($Matches, 0)
_ArrayDisplay($matches)

[Melba23]

PowerCat,

I would use an SRE like this:

expandcollapse popup

#include <Array.au3>

Global $SearchTerms[3]
$SearchTerms[0] = "Term1"
$SearchTerms[1] = "Term2"
$SearchTerms[2] = "Term3"

Global $SearchList[10]
$SearchList[0] = "This sentence may contain term1"
$SearchList[1] = "This one doesn't match anything"
$SearchList[2] = "This one may match term1 and term3"
$SearchList[3] = "This one matches term3"
$SearchList[4] = "No match here"
$SearchList[5] = "I'm running out of things to write"
$SearchList[6] = "Term2 comes up here"
$SearchList[7] = "I can't see what's going on"
$SearchList[8] = "Blah blah blah term3"
$SearchList[9] = "no"

; Get the search terms into a SRE pattern
$sPattern = "("
For $i = 0 To UBound($SearchTerms) - 1
    $sPattern &= $SearchTerms[$i] & "|"
Next
$sPattern = StringTrimRight($sPattern, 1) & ")"

; Now compare the pattern to each element
$MatchedPosition = ""
For $i = 0 To UBound($SearchList) - 1
    ConsoleWrite("-- Processing array SearchList, at position " & $i & ". Val = " & $SearchList[$i] & @CRLF)
    If StringRegExp($SearchList[$i], "(?i)" & $sPattern) Then
        $MatchedPosition &= $i & "|"
        ConsoleWrite("> found at " & $i & @CRLF)
    EndIf
Next

; Convert to an array
$MatchedPosition = StringTrimRight($MatchedPosition, 1)
$Matches = StringSplit($MatchedPosition, "|", 2)
_ArrayDisplay($Matches)

M23

[BrewManNH]

Here's my version.

#include <Array.au3>
Dim $SearchTerms[3]
$SearchTerms[0] = "Term1"
$SearchTerms[1] = "Term2"
$SearchTerms[2] = "Term3"
Dim $SearchList[10]
$SearchList[0] = "This sentence may contain term1"
$SearchList[1] = "This one doesn't match anything"
$SearchList[2] = "This one may match term1 and term3"
$SearchList[3] = "This one matches term3"
$SearchList[4] = "No match here"
$SearchList[5] = "I'm running out of things to write"
$SearchList[6] = "Term2 comes up here"
$SearchList[7] = "I can't see what's going on"
$SearchList[8] = "Blah blah blah term3"
$SearchList[9] = "no"
$MatchedPosition = ""
For $i = 0 To UBound($SearchList) - 1
    ;enter FOR loop. it will loop 10 times for $searchlist
    ConsoleWrite("-- Processing array SearchList, at position " & $i & ". Val = " & $SearchList[$i] & @CRLF)
    For $j = 0 To UBound($SearchTerms) - 1
        ConsoleWrite('Looking for "' & $SearchTerms[$j] & '" in "' & $SearchList[$i] & '"' & @CRLF)
        If StringInStr($searchlist[$i], $SearchTerms[$j]) Then
            $MatchedPosition &= $i & "|"
        EndIf
        ConsoleWrite("> found at " & $i & @CRLF)
    Next
Next
$MatchedPosition = StringTrimRight($MatchedPosition, 1)
$Matches = StringSplit($MatchedPosition, "|", 2)
$Matches = _ArrayUnique($Matches)
_ArrayDelete($Matches, 0)
_ArrayDisplay($Matches)

No SRE, but it works.

[PowerCat]

Ahh, the stringregex method is so classy, but a bit complex. I'll be able to adapt it, thanks for that.

Thank you two for the suggestions, that ArrayFind was definitely not a good way to go about it!