MsgBox Retry Cancel bug?

[YoshiKlarenbeek]

Once the user presses retry the MsgBox should close and you should be able to change stuff, but as of yet the whole program closes?

Ps. Here a part of the code.

Func _GUI()
GUISetState(@SW_SHOW, $main)
While 1 ;~ = true
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE
Exit
Case $msg = $btnManual
$varElectosVersion = GUICtrlRead($hCombo)
$varElectosVersionDash = StringReplace($varElectosVersion,".","-") ;Replaces the . for a - for use in the .sws and .ws.
MsgBox(0,"varElectosVersion",$varElectosVersion)
If $varElectosVersion = "" Then
$RetryCancel = MsgBox(48 + 5, "Electos Version", "Error, please select an Electos version.")
Switch $RetryCancel
Case 4 ;Retry
Return
Case 2 ;Cancel
Exit
EndSwitch
EndIf

Tell me if you need more info.

[YoshiKlarenbeek]

Fixed by replacing

Case 4 ;Retry

Return

for

Case 4 ;Retry

_GUI()

[Melba23]

YoshiKlarenbeek,

That is most certainly NOT the answer as you start an infinite recursive loop by recalling the function inside itself. Read the Recursion tutorial in the Wiki to understand why this is a bad thing.

All you need to do is to simply ignore that return value - then you return to the main loop and wait for another button press:

#include <GUIConstantsEx.au3>

_GUI()

Func _GUI()
    $main = GUICreate("Test", 500, 500)
    $hCombo = GUICtrlCreateCombo("", 10, 10, 200, 20)
    GUICtrlSetData(-1, "1.1|1.2|1.3")
    $btnManual = GUICtrlCreateButton("Go", 10, 200, 80, 30)
    GUISetState(@SW_SHOW, $main)
    While 1 ;~ = true
        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                Exit
            Case $msg = $btnManual
                $varElectosVersion = GUICtrlRead($hCombo)
                $varElectosVersionDash = StringReplace($varElectosVersion, ".", "-") ;Replaces the . for a - for use in the .sws and .ws.
                MsgBox(0, "varElectosVersion", $varElectosVersion)
                If $varElectosVersion = "" Then
                    $RetryCancel = MsgBox(48 + 5, "Electos Version", "Error, please select an Electos version.")
                    Switch $RetryCancel
                        Case 2 ;Cancel
                            Exit
                    EndSwitch
                EndIf
        EndSelect
    WEnd
EndFunc   ;==>_GUI

All clear?

M23