Eval control ID variable

[Rhyono]

I have a couple dozen checkboxes and their states are saved in a binary string.

It looks like eval and execute are only for transferring/computing values, rather than creating a variable name.

The checkboxes are numbered, following the format of $chkBox1, $chkBox2, etc.

I was hoping to be able to do loop through and be able to take the string "$chkBox" and append the current value the loop is on in, then set if it is checked with GUICtrlSetState.

The way I tried it was: GUICtrlSetState(Eval("$chkBox" & $currentID),$GUI_UNCHECKED)

Is there a way to do that with Eval/Execute and I'm just doing it incorrectly or is it not possible by that method or any other?

[kylomas]

Ryhono,

If you want to use "dynamic" variable names it could be done like this.

#include <GUIConstantsEx.au3>

#AutoIt3Wrapper_Add_Constants=n

local $msg

local $gui010 = guicreate('Checkbox Controls Using an Array for the Control ID')

for $1 = 1 to 15
    guictrlcreatelabel('CheckBox #' & stringformat('%02i',$1),10, $1 * 25,90,20)
    assign('checkbox' & $1,GUICtrlCreateCheckbox('',95, $1 * 25,20,15))
Next

guisetstate()

while 1

    $msg = guigetmsg()

    switch $msg
        case $gui_event_close
            Exit
        case eval('checkbox' & 1) to eval('checkbox' & 15)
            for $1 = 1 to 15
                if guictrlread(eval('checkbox' & $1)) = $gui_checked then
                    ConsoleWrite('Checkbox #' & stringformat('%02i',$1) & ' checked' & @LF)
                else
                    ConsoleWrite('Checkbox #' & stringformat('%02i',$1) & ' unchecked' & @LF)
                endif
            next
    EndSwitch

wend

However, this makes reading and debugging the code more difficult than it need be. You will generally find multiple checkboxes implemented using an array like this.

#include <GUIConstantsEx.au3>

#AutoIt3Wrapper_Add_Constants=n

local $ckb_cntrls[16], $msg

ConsoleWrite(ubound($ckb_cntrls) - 1 & @LF)

local $gui010 = guicreate('Checkbox Controls Using an Array for the Control ID')

for $1 = 1 to 15
    guictrlcreatelabel('CheckBox #' & stringformat('%02i',$1),10, $1 * 25,90,20)
    $ckb_cntrls[$1] = GUICtrlCreateCheckbox('',95, $1 * 25,20,15)
Next

guisetstate()

while 1

    $msg = guigetmsg()

    switch $msg
        case $gui_event_close
            Exit
        case $ckb_cntrls[1] to $ckb_cntrls[ubound($ckb_cntrls) - 1]
            for $1 = 1 to ubound($ckb_cntrls) - 1
                if guictrlread($ckb_cntrls[$1]) = $gui_checked then
                    ConsoleWrite('Checkbox #' & stringformat('%02i',$1) & ' checked' & @LF)
                else
                    ConsoleWrite('Checkbox #' & stringformat('%02i',$1) & ' unchecked' & @LF)
                endif
            next
    EndSwitch

wend

Both of these examples list the state of all checkboxes when any checkbox is actioned.

kylomas

[Rhyono]

Looking at your example I realized the only mistake I made was including the $

So doing GUICtrlSetState(Eval("chkBox" & $currentID),$GUI_UNCHECKED) works perfectly.

Thanks for indirectly solving my problem.

[kylomas]

Merry Christmas!

[guinness]

I would still use the advice of kylomas and use an array, there are only a handful of occasions when you should use Eval/Assign, this isn't one of them.