Sort files in dir by date and time in its names

[tibcho]

Hello scripters! I need to write a simple app which sort files in a directory by its names and keep only last 50. Auto delete the oldest files when more than 50 copies. Here are some filenames:

...

works12-30-12_10-55-30.tar.gz

sales12-21-12_14-03-49.tar.gz

names12-30-12_05-45-00.tar.gz

homes12-31-12_14-59-50.tar.gz

data01-01-13_21-05-30.tar.gz

cust01-01-13_21-55-18.tar.gz

...

and here are my function for split names:

Func SplitNames($s)
$sStrip = StringRegExpReplace($s,"[a-zA-Z.]","") ;remove all letters and "."
Local $x = StringSplit($sStrip, "_") ;split date and time from "_"
Global $fDate = StringRegExpReplace($x[1], '(\d{2})-(\d{2})-(\d{2})', '$2.$1.$3') ;transfer MM-DD-YY to DD.MM.YYYY
Global $fTime = StringRegExpReplace($x[2], '-', ':') ;transfer 00-00-00 to 00:00:00
EndFunc

SplitNames("data12-30-11_10-50-30.tar.gz")
ConsoleWrite($fDate & @CR) ;Result: 30.12.11
ConsoleWrite($fTime & @CR) ;Result: 10:50:30

I need sort the names like this (desync date+time) and keep only 50 (newest) of it, others delete:

cust01-01-13_21-55-18.tar.gz

data01-01-13_21-05-30.tar.gz

homes12-31-12_14-59-50.tar.gz

works12-30-12_10-55-30.tar.gz

names12-30-12_05-45-00.tar.gz

sales12-21-12_14-03-49.tar.gz

...

Please help me and thanks for any ideas or snippets!

Edited December 30, 2012 by tibcho

[guinness]

Look at _RecFileListToArray by Melba23.

[Melba23]

tibcho,

I would do something like this:

#include <Array.au3>

; Simulate reading the filenames into an array - we would use _FileListToArray($sPath, "*.gz", 1)
Global $aList[7] = [6, "works12-30-12_10-55-30.tar.gz", "sales12-21-12_14-03-49.tar.gz", "names12-30-12_05-45-00.tar.gz", _
            "homes12-31-12_14-59-50.tar.gz", "data01-01-13_21-05-30.tar.gz", "cust01-01-13_21-55-18.tar.gz"]

; Create a 2D array of the correct size
Global $aList_2D[UBound($aList)][2]

; Now loop through the list and add tha full filenames and the extracted DTG to the new array
For $i = 1 To $aList[0]
    ; First the filename
    $aList_2D[$i][0] = $aList[$i]
    ; Now the DTG - I assume the dates are currently in the abominable MM-DD-YY_HH-mm-SS format so we reorder them into YYMMDDHHmmSS
    $aList_2D[$i][1] = StringRegExpReplace($aList[$i], ".*(\d\d).(\d\d).(\d\d).(\d\d).(\d\d).(\d\d).*", "$3$1$2$4$5$6")
Next

; Now sort the second column to get the latest files to the top
_ArraySort($aList_2D, 1, 1, 0, 1)

; And here we have the result - just for interest
_ArrayDisplay($aList_2D)

; Now you just need to loop through the sorted array and delete all the files from 51 down
For $i = 51 To $aList[0]
    FileDelete($sPath & $aList_2D[$i][0]
Next

Please ask if you have any questions.

M23

Edit: Welcome to the AutoIt forum, by the way.

Edited December 30, 2012 by Melba23

[tibcho]

Work great and very fast and simple Thank you a lot Melba23 you are the best =)

[Melba23]

tibcho,

Glad I could help.

M23