DirCopy w/progress alternate

[NewPlaza]

Hello,

I've seen dozens of examples on how to copy folders with a progress bar. But find that I don't want to incorporate the code in my very simple/tiny scripts.

Anyhow, I have come up with this bit of code.

$sSourceFolder = "D:\!Drivers"
$iSourceSize = DirGetSize($sSourceFolder)
$sDestFolder = @DesktopDir & "\" & "TestDownloadFolder"
Run(@AutoItExe & ' /AutoIt3ExecuteLine "DirCopy(''' & $sSourceFolder & ''', ''' & $sDestFolder & ''')"')
ProgressOn("Progress Meter", "Increments every second", "0 percent")
Do
$iDestSize = DirGetSize($sDestFolder)
$iPercent = Int($iDestSize / ($iSourceSize / 100))
ProgressSet($iPercent, $iPercent & " percent")
Until $iPercent = 100
ProgressSet(100 , "Done", "Complete")
Sleep(500)
ProgressOff()

I would like to know what the risks/danger of using such code. I can only come up with is there is no error checking if the folder copied or not.

But I would image there or more risks I can't possible come up with.

I welcome any advice/help.

Thanks.

[GordonFreeman]

I like this code but need a sleep to not to stress the processor and not blink percentage

$sSourceFolder = "D:\!Drivers"
$iSourceSize = DirGetSize($sSourceFolder)
$sDestFolder = @DesktopDir & "\" & "TestDownloadFolder"
Run(@AutoItExe & ' /AutoIt3ExecuteLine "DirCopy(''' & $sSourceFolder & ''', ''' & $sDestFolder & ''')"')
ProgressOn("Progress Meter", "Increments every second", "0 percent")
Do
$iDestSize = DirGetSize($sDestFolder)
$iPercent = Int($iDestSize / ($iSourceSize / 100))
ProgressSet($iPercent, $iPercent & " percent")
Sleep(200)
Until $iPercent = 100
ProgressSet(100 , "Done", "Complete")
Sleep(500)
ProgressOff()

Not to understand the part of the risks. Im a brazilian (PT-BR) xD

Edited January 1, 2013 by GordonFreeman

[MilesAhead]

Or you can use _WinAPI_ShellFileOperation() from the WinAPIEx UDF. You may even get the Taskbar Progress in W7. The Shell does it all for you. Albeit it may be a bit slow doiing it.

Edited January 1, 2013 by MilesAhead

[NewPlaza]

@GordonFreeman

Thanks for that. I does make it much smoother.

@MilesAhead

Yeah, I though & tried the WinAPI but I don't want anyway a user can cancel the copy. Thanks

[KaFu]

In SMF I switched to Yashied's excellent " which utilizes a copy.dll file to perform the operations. The script stays responsive, the copy process can be interrupted and you can measure the progress too.

[guinness]

In SMF I switched to Yashied's excellent " which utilizes a copy.dll file to perform the operations. The script stays responsive, the copy process can be interrupted and you can measure the progress too.

I second that suggestion too.

[kylomas]

Not to mention that you can interrogate the return from the copy process in Yashied's code whereas in the technique that you use has no visibility to the spawned process, as you metioned in the OP.

However, if you elect to stay with your code the following may help:

- changed the code to a function to make it easier to add to code/maintain

- added delete for target dir as code will not work if target is not empty

- changed % calculation - I believe the general formula is int((part/whole)*100)

- changed to loop on the pid of the spawned process

;
; copy folder and subfolders with progress
;

_CopyFolder(@scriptdir, @scriptdir & '\Temp out folder')

func _CopyFolder($sSourceFolder,$sDestFolder)

    dirremove($sDestFolder,1)
    local $iSourceSize = DirGetSize($sSourceFolder), $iDestSize
    local $pid = Run(@AutoItExe & ' /AutoIt3ExecuteLine "DirCopy(''' & $sSourceFolder & ''', ''' & $sDestFolder & ''')"')
    ProgressOn("Copy Progress", "Please Wait...")
    Do
        $iDestSize = dirgetsize($sDestFolder)
        local $ipct = int(($iDestSize/$iSourceSize)*100)
        ProgressSet($ipct,$ipct & ' percent complete')
        sleep(20)
    Until not ProcessExists($pid)
    ProgressOff()

endfunc

Incidentally, your code shows that you are thinking and grasping the language, Good Job!

kylomas

[guinness]

For efficency you should declare $ipct outside the loop.

[kylomas]

noted - Thank You Guinness

[TalivanIBM]

Thanks a lot man, i was looking for this, and now i have found it!!!

[boniakowski]

Hi, everyone.

First thanks for the script. but i have a problem when i compile the script. if i run the script pressing f5 it´s all right but when i compile the script the line:

Run(@AutoItExe & ' /AutoIt3ExecuteLine "DirCopy(''' & $sSourceFolder & ''', ''' & $sDestFolder & ''')"')

don´t do the spected, the progress bar stay freezed and don´t continue, in any line with the run command i need to say it the WorkingDir, and in this example i dónt see it, maybe i was wrong but i don´t understand my mistake in this line, i only copy and paste and later i modify the source and destination, nothing more.

why when i press f5 all it´s fine but when i compile all it´s wrong?

thanks.

Christian

[Jos]

Do you mean that the line isn't executed so no files are copied?

What version are you running?

Have you added this at the top in case you run the latest version of AutoIt3?:

#pragma compile(AutoItExecuteAllowed, true)

Jos

[boniakowski]

Do you mean that the line isn't executed so no files are copied?

What version are you running?

Have you added this at the top in case you run the latest version of AutoIt3?:

#pragma compile(AutoItExecuteAllowed, true)

Jos

Exactly, the script pause the execution in the window of progress and don´t continue, it´s not copying anything.

but you are the men.

this line was the solution of my problems:

#pragma compile(AutoItExecuteAllowed, true)

now it´s working perfect.

my autoit version is

SciTE

Version 3.4.1

 

I don´t know how this line work, i need to read about it.

Thanks a Lot Jos for your contribution to my work.

Christian

[Aler]

Hi

I found the code from kylomas for DirCopy with progress (above) works great for me. Many thanks ! ! !

However, I have one small problem . . .

I'm using the code to copy Audacity recording files from C:\...\My Documents\Audacity\ to a USB (E:\ drive).

When I use the command: DirCopy($FilePath, $USBdrive, 1) normally (without progress), I can set $USBdrive to "E:\" and it all works fine.

HOWEVER, when I call the _CopyFolder fuction above from within my script, I have found the destination drive MUST have a drive letter AND a folder name specified.  Otherwise the script continues without copying anything!

ie  $sDestFolder MUST be set to something like: "E:\Audacity" - not just "E:\".

Any ideas ? ? ?

I can work around it but it would be nice to just use "E:\".

[benched42]

I agree that it would be nice to use just "E:\" but you can't rely on the USB flash drive always being E:  To get around this, use the "DriveGetDrive" function and check to see if it is of type "REMOVEABLE"; flash drives (as well as SD cards) show up as REMOVEABLE.