Is using Ubound in For To Next declarations loops bad practice

[BitByteBit 1]

In the first example below Ubound($Array) - 1 is evaluated every cycle for no reason.

Is there any significant benefit to doing the calculation before such as in the 2nd example?

Global $Array[100]
For $i = 0 to Ubound($Array) - 1
;Do something
Next

Global $Array[100], $a = Ubound($Array) - 1
For $i = 0 to $a
;Do something
Next

[guinness 1,482]

In the first example below Ubound($Array) - 1 is evaluated every cycle

I don't think it is. Anyway, the first one is a better choice.

[Melba23 2,926]

BitByteBit,

guinness is correct - in your first example, the loop bound is only evaluated once: as you enter the loop. You can modify the loop counter programatically by changing the value of $i inside the loop, but changing the size of the array within the loop will not affect the intially set limit. That is why when you are changing the size of the array (deleting unnecessary elements for example) you must always start at the bottom of the array and work up using Step -1.

M23

[BrewManNH 1,159]

There's no noticeable speed difference in doing it either way, so I'm not sure of any gains/losses you'd have using one over the other.

[guinness 1,482]

Also for the sake of learning (I presume this is what you want?) your example is declaring the variable in Global scope when it should be Local.

Local $aProblems[99] ; Jay-Z Array
For $i = 0 To UBound($aProblems) - 1
    ; Enumerate through the array.
Next

This is valid use, as the variable is use other than its current scope.

Global $aProblems[99] ; Jay-Z Array
For $i = 0 To UBound($aProblems) - 1
    ; Enumerate through the array.
Next

Func SomeFunc()
    For $i = 0 To UBound($aProblems) - 1
        ; Enumerate through the array.
    Next
EndFunc   ;==>SomeFunc

Func AnotherFunc()
    $aProblems = 0
EndFunc   ;==>AnotherFunc

Local $aProblems[99] = [98] ; Jay-Z Array
For $i = 1 To $aProblems[0] ; If I know the size of the array beforehand, I like to use the 0th index as the count.
                            ; This theory can also be applied to arrays which are dynamic too.
    ; Enumerate through the array.
Next

Edited January 2, 2013 by guinness

[BrewManNH 1,159]

Wouldn't the third example above be practically the same as the example above using $a = UBound($array) - 1? Again, in testing I don't see any speed difference in doing it in any of the 3 methods, they're all statistically the same in repeated tests.

[guinness 1,482]

Wouldn't the third example above be practically the same as the example above using $a = UBound($array) - 1? Again, in testing I don't see any speed difference in doing it in any of the 3 methods, they're all statistically the same in repeated tests.

It's nothing to do with speed, just ease of readability and the unnecessary use of calling a secondary function for information you already know.

[czardas 1,200]

In the case where you need to use the same Ubound value later on in the script, it's just as well to create the variable to avoid keep repeating the same line of code. That's a common thing I do in that circumstance.

Edited January 2, 2013 by czardas

[guinness 1,482]

I have no idea if this is true, but I read somewhere that using UBound on a large array can slow down the script. I can't see how it could be true though, but it has always stuck with me.

[trancexx 948]

^^I never heard of that.

[czardas 1,200]

I think it's probably not going to make too much difference in terms of speed. I just do it to streamline things if I think it makes sense. Perhaps it's a personal thing. I've seen it used a few times. Monkey see etc...

Edited January 2, 2013 by czardas

[guinness 1,482]

^^I never heard of that.

OK, seems who ever said that must have seen at some point but missed the part about it being fixed.

[trancexx 948]

OK, seems who ever said that must have seen at some point but missed the part about it being fixed.

That's cool, I didn't know AutoIt is that old. You learn something new every day.

[kylomas 414]

@guinness,

This is valid use, as the variable is use other than its current scope.

Consider the following code modified from your original example regarding scope.

local $aProblems[5]                 ; $aProblems is "script" in scope
For $i = 0 To UBound($aProblems) - 1        ; $i is "script" in scope
    AnotherFunc()
    SomeFunc()
Next

Func SomeFunc()
    For $i = 0 To UBound($aProblems) - 1    ; This $i is "SomeFunc" in scope.
        ConsoleWrite('Somefunc iteration # ' & $i & @LF)
    Next
EndFunc

Func AnotherFunc()
    ConsoleWrite('vartype of $aProblems = ' & VarGetType($aProblems) & @lf & 'ubound of $aProblems  = ' & ubound($aProblems) & @LF)

    ; Setting $aProblems to "0" demonstrates the following from the Help File
    ;   "If stepVal or stop is a variable, its value is only read the first time the loop executes."
    ; Therefore the initial loop continues to iterate, however, SomeFunc will not run as the ubound evaluates to "0"

    if $i > 1 then $aProblems = 0       ; This $i and "$aProblems are "script" in scope
EndFunc

Please comment if this does not represent what you are saying.

@BitByteBit - "If stepVal or stop is a variable, its value is only read the first time the loop executes." from the

help file answers your original question. Since the "stop" value cannot be altered if it is a

variable, it is reasonable to surmise that less processing is more efficient so don't use

an intermediate variable ($a in your case). However, as BrewmanNH pointed out, while it is logical that

there is a difference in performance, it may not be measurable or significant, depending on scale.

kylomas

[guinness 1,482]

Here, my take on it.

Local $aProblems[5] ; $aProblems is in 'File Scope'
For $i = 0 To UBound($aProblems) - 1 ; $i is in 'Loop Scope' but it seems it's in 'File 'Loop' Scope'
    AnotherFunc()
    SomeFunc()
Next

Func SomeFunc()
    For $i = 0 To UBound($aProblems) - 1 ; This $i is in 'Local 'Loop' Scope'
        ConsoleWrite('SomeFunc Iteration # ' & $i & @CRLF)
    Next
    ConsoleWrite(@CRLF)
EndFunc   ;==>SomeFunc

Func AnotherFunc()
    ConsoleWrite('VarType of $aProblems = ' & VarGetType($aProblems) & @CRLF & _
            'UBound of $aProblems  = ' & UBound($aProblems) & @CRLF)

    ; Setting $aProblems to "0" demonstrates the following from the Help File
    ; "If StepVal or stop is a variable, its value is only read the first time the loop executes."
    ; Therefore the initial loop continues to iterate, however, SomeFunc will not run as the UBound evaluates to "0"
    If $i > 1 Then $aProblems = 0 ; This $i is in 'File Scope'
EndFunc   ;==>AnotherFunc

[kylomas 414]

guinness - yes, I believe we are saying the same thing

kylomas

Edited January 2, 2013 by kylomas

[guinness 1,482]

Yeh we are, but you said 'Script' and I said 'File.' Though I did learn something, as I thought the $i in 'File Scope' was in 'Local Scope' or 'Loop Scope' therefore not having to declare it e.g.

Local $i ; Wrong!
For $i = 1 To $aArray[0]
    
Next

[czardas 1,200]

I don't follow this. The code in the first post seems correct to me.

Edited January 2, 2013 by czardas

[guinness 1,482]

I don't follow this. The code in the first post seems correct to me.

It's all correct, but BitByteBit asked what would be the best of the two. The first as it's unnecessary in the example above to store the UBound value in a separate variable.

[czardas 1,200]

I'm referring to the following sytax being correct.

Global $Array[100]

This is what I'm not understanding.

your example is declaring the variable in Global scope when it should be Local.

Edited January 2, 2013 by czardas