Using a progress in a gui

[Chimaera]

Hey, ive been messing around with a bit of code that was posted for a simple backup script(creds to the author)

and whilst it works fine i wanted to make it work in a gui rather than the popup progress bar, but the problem is i cant seem to get them working together.

This is the original

Func _CopyFolder($sSourceFolder, $sDestFolder)
Local $ipct
DirRemove($sDestFolder, 1)
Local $iSourceSize = DirGetSize($sSourceFolder), $iDestSize
Local $pid = Run(@AutoItExe & ' /AutoIt3ExecuteLine "DirCopy(''' & $sSourceFolder & ''', ''' & $sDestFolder & ''')"')
ProgressOn("Copy Progress For " & $sSourceFolder, "Please Wait...")
Do
$iDestSize = DirGetSize($sDestFolder)
$ipct = Int(($iDestSize / $iSourceSize) * 100)
ProgressSet($ipct, $ipct & ' Percent Complete')
Sleep(20)
Until Not ProcessExists($pid)
ProgressOff()
EndFunc ;==>_CopyFolder

and the line from the gui is

$hProgress = GUICtrlCreateProgress(30, 440, 270, 23)

and its called from a button press like this.

_CopyFolder(@UserProfileDir & "\Desktop", $sDestination & '\Desktop')

i tried changing the copy folder to progressSET instead of ON but it wont have it

i tried adding $hProgress = to the progressON to reuse the variable

Do i need to also create text boxes for the percentage done stuff as well to get it to work or am i missing something stupid?

[BrewManNH]

You'd need to update the progress bar by using GUICtrlSetData with a percentage from 1 to 100.

[Chimaera]

aah so run it as normal but then as it cycle use a GUICtrlSetData tied to the original progress in the gui?

[BrewManNH]

Yes, but in a normal filecopy, your script halts until the file copy has completed if I remember right. So if you're copying only one file the progress bar would go from 1 to 100 with no updates in between. You'd need to copy the file in chunks, using something like the LargeFileCopy UDF, so you can update the progress.

[Chimaera]

Got it working now thx

Im mainly doing folders so not to bad but yes its 0-100 for every folder.

Is there a way to make it work across the copy rather than the folders without major surgery?

What i mean if this is the commands

_CopyFolder(@UserProfileDir & "\Folder1", $sDestination & '\Folder1')
_CopyFolder(@UserProfileDir & "\Folder2", $sDestination & '\Folder2')
_CopyFolder(@UserProfileDir & "\Folder3", $sDestination & '\Folder3')
_CopyFolder(@UserProfileDir & "\Folder4", $sDestination & '\Folder4')

Could i put these together in a function maybe and monitor the function process instead?

Then its just 0 - 100 once not for every file

If that makes any sense

[guinness]

FileCopy/FileMove are blocking functions and thus nothing will happen until the function has completed its request. Look at the Copy UDF if you want to update a progress bar in real time.

[kylomas]

Chimaera,

The technique used in this script might be useful. It does not use a gui progress bar but can be easily adapted.

;
; copy folder and subfolders with progress
;

_CopyFolder(@scriptdir, @scriptdir & '\Temp out folder')

func _CopyFolder($sSourceFolder,$sDestFolder)

    dirremove($sDestFolder,1)
    local $iSourceSize = DirGetSize($sSourceFolder), $iDestSize
    local $pid = Run(@AutoItExe & ' /AutoIt3ExecuteLine "DirCopy(''' & $sSourceFolder & ''', ''' & $sDestFolder & ''')"')
    ProgressOn("Copy Progress", "Please Wait...")
    Do
        $iDestSize = dirgetsize($sDestFolder)
        local $ipct = int(($iDestSize/$iSourceSize)*100)
        ProgressSet($ipct,$ipct & ' percent complete')
        sleep(20)
    Until not ProcessExists($pid)
    ProgressOff()

endfunc

kylomas

[Chimaera]

Thats the same one im using m8 see post one

[kylomas]

chimaera,

Sorry, fingers getting ahead of brain! Posted the wrong code. This might help.

expandcollapse popup

; *** Start added by AutoIt3Wrapper ***
#include <GUIConstantsEx.au3>
; *** End added by AutoIt3Wrapper ***
;
; copy folder and subfolders with progress
;

#AutoIt3Wrapper_Add_Constants=n

local $gui010 = guicreate('My Copy With Progresss')
local $prg010 = guictrlcreateprogress(10,10,380,20)
local $btn010 = guictrlcreatebutton('Start Copy',10,300,380,20)
                guisetstate()

while 1

    switch guigetmsg()
        case $gui_event_close
            Exit
        case $btn010
            _CopyFolder(@scriptdir, @scriptdir & '\Temp out folder')
    EndSwitch

wend

func _CopyFolder($sSourceFolder,$sDestFolder)

    dirremove($sDestFolder,1)
    local $iSourceSize = DirGetSize($sSourceFolder), $iDestSize
    local $pid = Run(@AutoItExe & ' /AutoIt3ExecuteLine "DirCopy(''' & $sSourceFolder & ''', ''' & $sDestFolder & ''')"')
    Do
        $iDestSize = dirgetsize($sDestFolder)
        local $ipct = int(($iDestSize/$iSourceSize)*100)
        guictrlsetdata($prg010,$ipct)
        sleep(20)
    Until not ProcessExists($pid)
    guictrlsetdata($prg010,' ')

endfunc

kylomas