Set a file's size?

[typhoon]

Does AutoIt have a mechanism for setting a file's size without having to actually write out the data? Assume that I want to generate a dummy file of large size, and do not want to wait to write zeroes.

[ZacUSNYR]

You can use fsutil in windows to do it. Just toss together a function wrapper

_TestFileCreate("C:\test.txt", 2048)

Func _TestFileCreate($sFile, $iSize = 1024)
Run ( @ComSpec & ' /c fsutil file createnew "' & $sFile & '" ' & $iSize, @SystemDir, @SW_HIDE)
EndFunc

You can do error correction using FileExists and FileGetSize. Remember if you do the check immediately it may fail if fsutil takes a little bit of time to complete. Simple solution is the toss in RunWait instead.

Edited January 18, 2013 by ZacUSNYR

[kylomas]

typhoon,

The following will create a 20 MB file. You will need Yashied WINAPIex.au3 udf, just search for it.

#include <winapiex.au3>
#include <winapi.au3>

local $sFile = @scriptdir & '\test2.txt'

$hFile = _WinAPI_CreateFile($sFile, 1, 4)
if $hFile = 0 then ConsoleWrite(_winapi_getlasterrormessage() & @LF)

_WinAPI_SetFilePointer($hFile, 1024*1024*20)
if @error <> 0 then ConsoleWrite(_winapi_getlasterrormessage() & @LF)

if not _WinAPI_SetEndOfFile($hFile) then ConsoleWrite(_winapi_getlasterrormessage() & @LF)

ConsoleWrite(_winapi_getfilesizeEX($hFile)/(1024*1024) & ' MB' & @LF)
;if @error then ConsoleWrite(@error & @LF) 

_WinAPI_CloseHandle($hFile)

kylomas

edit: amended script to show size of file in MB's

edit2: commented last consolewrite - makes no sense in this context

Edited January 18, 2013 by kylomas

[guinness]

Why go WinAPI when you can go native.

#include <FileConstants.au3>

_DummyFile(@ScriptDir & '\Test.txt', 30) ; 30MB

Func _DummyFile($sFilePath, $iSizeMB) ; Initial idea by trancexx.
    Local $hFileOpen = FileOpen($sFilePath, $FO_OVERWRITE + $FO_BINARY)
    If $hFileOpen = -1 Then
        Return SetError(1, 0, 0)
    EndIf
    FileSetPos($hFileOpen, $iSizeMB * 1048576 - 4, 0)
    FileWrite($hFileOpen, 0)
    Return FileClose($hFileOpen)
EndFunc   ;==>_DummyFile

[kylomas]

Why go WinAPI when you can go native.

No real reason, just something that worked...now the OP has three choices...

kylomas

[guinness]

No real reason, just something that worked...now the OP has three choices...

kylomas

They do indeed.

Pick me, pick me!!!

[kylomas]

@guinness - Your spoiler gave me much needed laugh, thanks!!!

[typhoon]

Ah, probably should have mentioned this earlier but I was using fsutil. We were just migrated from XP to 7 and it seems to cause headaches with privilege levels (the command has to be run as administrator even if you're already an admin). The functions that kylomas (or guinness!) provided do the job nicely. Thanks guys.

Edited January 18, 2013 by typhoon

[guinness]

@guinness - Your spoiler gave me much needed laugh, thanks!!!

Ah, you won.

[kylomas]

typhoon,

This is what it might look like as a function (inspired by guinness's example)

#include <winapiex.au3>
#include <winapi.au3>

local $sFile = @scriptdir & '\test2.txt'
local $ret   = _alloc_file_space($sFile,1024*1024*1024)

if $ret = 0 then ConsoleWrite(filegetsize($sFile) & @LF)

func _alloc_file_space($sFile,$size)

    $hFile = _WinAPI_CreateFile($sFile, 1, 4)
    if $hFile = 0 then return seterror(1,0,_winapi_getlasterrormessage())

    _WinAPI_SetFilePointer($hFile, 1024*1024*20)
    if @error <> 0 then return seterror(2,0,_winapi_getlasterrormessage())

    if not _WinAPI_SetEndOfFile($hFile) then return seterror(3,0,_winapi_getlasterrormessage())

    _WinAPI_CloseHandle($hFile)

    return 0

endfunc

kylomas