_IsGUID() - Check a GUID string with or without brackets is valid.

[guinness 1,517]

Check whether a GUID is valid. You may only need to copy one function only.

Source: https://en.wikipedia.org/wiki/Guid

Function:

; #FUNCTION# ====================================================================================================================
; Name ..........: _IsGUID
; Description ...: Check whether a GUID string is valid.
; Syntax ........: _IsGUID($sString)
; Parameters ....: $sString             - Check a GUID string with or without brackets is valid.
; Return values .: Success: True
;                  Failure: False
; Author ........: guinness
; Remarks .......: SRE: http://mitchelsellers.com/blogs/2007/04/22/validating-a-guid-value-with-regular-expressions.aspx
; Example .......: Yes
; ===============================================================================================================================
Func _IsGUID($sString)
    Return StringRegExp($sString, '^(?:(?<curly>\{)?[0-9A-Fa-f]{8}-(?:[0-9A-Fa-f]{4}-){3}[0-9A-Fa-f]{12}(?(curly)\}))$') > 0
EndFunc   ;==>_IsGUID

Function: (Different approach)

; #FUNCTION# ====================================================================================================================
; Name ..........: _IsGUID
; Description ...: Check whether a GUID string is valid.
; Syntax ........: _IsGUID($sString)
; Parameters ....: $sString             - Check a GUID string with or without brackets is valid.
; Return values .: Success: True
;                  Failure: False
; Author ........: guinness
; Remarks .......: SRE: http://mitchelsellers.com/blogs/2007/04/22/validating-a-guid-value-with-regular-expressions.aspx
; Example .......: Yes
; ===============================================================================================================================
Func _IsGUID($sString)
    Return StringRegExp($sString, '^(?:(?<curly>\{)?[[:xdigit:]]{8}-(?:[[:xdigit:]]{4}-){3}[[:xdigit:]]{12}(?(curly)\}))$') > 0
EndFunc   ;==>_IsGUID

Example use of Function:

Example()

Func Example()
    Local $sGUID = CreateGUID() ; Or _WinAPI_CreateGUID() from WinAPIEx.au3.
    ConsoleWrite($sGUID & ': ' & _IsGUID($sGUID) & @CRLF)

    $sGUID = '{EBEB-642D-11E2-B009-B121}'
    ConsoleWrite($sGUID & ': ' & _IsGUID($sGUID) & @CRLF)

    $sGUID = '{E25F2E50-6497-11E2-BE9E-182679957A39}'
    ConsoleWrite($sGUID & ': ' & _IsGUID($sGUID) & @CRLF)

    $sGUID = 'EF3391DE-6497-11E2-B99A-182679957A39'
    ConsoleWrite($sGUID & ': ' & _IsGUID($sGUID) & @CRLF)
EndFunc   ;==>Example

; #FUNCTION# ====================================================================================================================
; Name ..........: CreateGUID
; Description ...: Create a valid GUID.
; Syntax ........: CreateGUID()
; Parameters ....: None
; Return values .: Success: GUID string
;                  Failure: Empty string and sets @error to non-zero
; Author ........: guinness
; Example .......: Yes
; ===============================================================================================================================
Func CreateGUID() ; Converted from a VBScript I had.
    Local $oTypeLib = ObjCreate('Scriptlet.TypeLib')
    If IsObj($oTypeLib) = 0 Then
        Return SetError(1, 0, '')
    EndIf
    Return StringLeft($oTypeLib.Guid, 38)
EndFunc   ;==>CreateGUID

Edited January 9, 2015 by guinness

[JohnOne 1,603]

Did you intend to leave bracets out of one of those examples?

[guinness 1,517]

Ah, was meant to post another GUID, whoops. Will fix later on.

[guinness 1,517]

Done, fixed the example.

[guinness 1,517]

Added a different approach to this function by using the xdigit character class instead. See the original post which includes the function and example.

Edited January 29, 2013 by guinness

[Myicq 20]

is it on purpose that your two different methods have exact same function name ? I guess AutoIT will complain about duplicate function names and script won't run.

Yes, simple to fix, but perhaps confusing for noobs.

[guinness 1,517]

Yes it was and it did cross my mind, but I thought that if a user knows what a GUID then surely they would know to only copy one function. Seems I was wrong.

Amended the first post.

[guinness 1,517]

Fixed unnecessarily escaping the - character and several optimisations in the regular expression.

[RTFC 353]

Hi guinness,

Just for info, and this is nitpicking, of course, but a valid GUID will have a type ID in the third group that determines the version and generating algorithm (e.g, using the MAC address, timestamp, (weak) randomiser, and so forth). So that part cannot be just any hex digit, and what it contains can have ramifications for other parts of the GUID.

For GUID algorithm specs, see: http://tools.ietf.org/html/rfc4122

The issue has come up before on the AutoIt forums too:

'?do=embed' frameborder='0' data-embedContent>>

Just thought I'd mention it, in case it's of interest to anyone; not meant to annoy you.

[guinness 1,517]

I was only going by the return value of _WinAPI_CreateGUID().

[RTFC 353]

That's fine.  

I was just thinking along the lines of a scenario where somebody generates a random GUID that happens to have "1" in the third group, for example, which would indicate that the GUID tail should contain the MAC address of the generating machine, which of course does not match the random string  (unless you're extreeeemely lucky), so when somebody later relies on that incorporated MAC address to trace the owner, it won't work because the GUID is technically invalid.   Not that I'd advocate using that particular algorithm, which can be a gaping security hole, anyway.

I guess it's just me,   I sometimes get into these morbid speculations how simple, obviously useful things could turn evil and destroy the universe (I've got this old rusty can-opener at the back of my kitchen drawer, for example, which I'm certain is planning for world domination... )

[guinness 1,517]

But 1 is classed as a hex value

ConsoleWrite(StringIsXDigit('1') & @CRLF)

.

[RTFC 353]

Yes, but the point I was trying to make was that that particular "1" would place constraints on the GUID tail, i.e., being the MAC address of the generating machine. So simply checking for valid hex groups is insufficient to determine whether a GUID is valid in this case, since you can have countless valid random hex strings that would look like GUIDs but that would not follow the GUID spec. So if anyone sees that "1" in group 3, they would expect to find a MAC address in a valid GUID.

I perfectly understand that this falls outside the scope of your function, I just wanted to mention that there's more to a GUID validity check than the proper grouping of hexidecimal digits your function evaluates. I'll stop nagging now...

[guinness 1,517]

OK, I understand now. Thanks for pointing that out, but it does go beyond the scope of this function.

[guinness 1,517]

Updated first function that was missing quotes around the string.

[guinness 1,517]

The regular expression should be this... 

^(?:(?<curly>\{)?[0-9A-Fa-f]{8}-(?:[0-9A-Fa-f]{4}-){3}[0-9A-Fa-f]{12}(?(curly)\}))$

I will update the code in the first post eventually. [Done] Edited January 9, 2015 by guinness