Delayed function

[Amaruq]

Hello all,

I'm using a script that consist of several functions, so far so good.

Now I have received a request to delay the execution of one function by 5 minutes, once it is called, without delaying the rest of the script. If the same function should be called again within these 5 minutes it should 'ignore' this most recent call and continue with the previous one.

The function uses an array as parameter and gets called upon when the modified date of a file changes.

Can anyone point me in the right direction on how to properly handle this please?

Thanks in advance.

[SadBunny]

Something like this perhaps?

HotKeySet("x", "doSomethingSpecialTrigger")

; we will wait for 5000 milliseconds after the hotkey is pressed
Global $timeOutInMs = 5000
Global $specialTimer = 0

Global $loopTimer = TimerInit()

$count = 0

While 1
Sleep(10)
If (TimerDiff($loopTimer) > 1000) Then
$count += 1
ConsoleWrite("Script has been running for " & $count & " seconds." & @CRLF)
$loopTimer = TimerInit()
EndIf

If ($specialTimer <> 0) Then
If TimerDiff($specialTimer) > $timeOutInMs Then
doSomethingSpecial()
$specialTimer = 0
EndIf
EndIf
WEnd

Func doSomethingSpecial()
ConsoleWrite("*** HUGS AND KISSES TO YOU *** because you hit 'x' five seconds ago! I love x..." & @CRLF)
EndFunc

Func doSomethingSpecialTrigger()
If $specialTimer == 0 Then
$specialTimer = TimerInit()
EndIf
EndFunc

Edited January 26, 2013 by SadBunny

[stormbreaker]

Just another proof of concept (10 seconds):

Global $hTimer

HotKeySet('1', '_MyFunction')

Func _MyFunction()
If NOT $hTimer then $hTimer = TimerInit()
$TIMER = TimerDiff($hTimer)
If $TIMER > 10*1000 then 
msgbox(64, '', '10 seconds exceeded.')
EndIf
EndFunc

While 1
Sleep(100)
WEnd

I assume u have some basic knowledge of functions.

[BrewManNH]

Another idea, using MKISH's script used as a base and using the Static function.

HotKeySet('1', '_Exit')
Global $Stop = 0 ; only needed for the exit function


Func _MyFunction()
     Local Static $hTimer = TimerInit()
     $Time = 10
     If TimerDiff($hTimer) > $Time * 1000 Then
          MsgBox(64, '', '10 seconds exceeded.')
          $hTimer = TimerInit()
     EndIf
EndFunc   ;==>_MyFunction

While 1
     _MyFunction()
     Sleep(1000)
     If $Stop Then ExitLoop
WEnd
Func _Exit()
     $Stop = 1
EndFunc   ;==>_Exit

Press 1 to exit the script.

Edited January 26, 2013 by BrewManNH

[KaFu]

Here's my version

Global $b_Delayed_Func_Running = False, $a_Delayed_Func_Array

Func _Call_Delayed_Function($array)
    If $b_Delayed_Func_Running Then Return
    $b_Delayed_Func_Running = True
    $a_Delayed_Func_Array = $array
    AdlibRegister("_Delayed_Function", 5 * 60 * 1000)
EndFunc   ;==>_Call_Delayed_Function

Func _Delayed_Function()
    ; do something with $a_Delayed_Func_Array
    AdlibUnRegister("_Delayed_Function")
    $b_Delayed_Func_Running = False
EndFunc   ;==>_Delayed_Function

Are you delaying the function call because the file is locked? better test for a lock after filetime has changed, and proceed when lock is lifted instead of just guessing that 5 minutes will be enough.

[guinness]

Another idea, using MKISH's script used as a base and using the Static function.

HotKeySet('1', '_Exit')
Global $Stop = 0 ; only needed for the exit function


Func _MyFunction()
     Local Static $hTimer = TimerInit()
     $Time = 10
     If TimerDiff($hTimer) > $Time * 1000 Then
          MsgBox(64, '', '10 seconds exceeded.')
          $hTimer = TimerInit()
     EndIf
EndFunc   ;==>_MyFunction

While 1
     _MyFunction()
     Sleep(1000)
     If $Stop Then ExitLoop
WEnd
Func _Exit()
     $Stop = 1
EndFunc   ;==>_Exit

Press 1 to exit the script.

Nice to see Static variables being used. The Global variable can be destroyed as I would have used Exit in the _Exit function.

[Amaruq]

First of all my thanks to all who contributed!

By the looks of it I was searching in a too difficult direction.

I've tested with all supplied scripts and it looks like only SadBunny's versions does everything that I need.

So I'll be going with that one.

Once again, thanks to all who took the time to have a go at this!

[SadBunny]

First of all my thanks to all who contributed!

By the looks of it I was searching in a too difficult direction.

I've tested with all supplied scripts and it looks like only SadBunny's versions does everything that I need.

So I'll be going with that one.

Once again, thanks to all who took the time to have a go at this!

It was the hugs&kisses, wasn't it? Anyway, good luck and I'm happy I was able to help.

[kylomas]

Amaruk,

As far as I can tell only Kafu's script meets this requirement

without delaying the rest of the script.

And just for grins, a gui version using Kafu's technique.

expandcollapse popup

; *** Start added by AutoIt3Wrapper ***
#include <WindowsConstants.au3>
; *** End added by AutoIt3Wrapper ***
; *** Start added by AutoIt3Wrapper ***
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
; *** End added by AutoIt3Wrapper ***

#include <date.au3>

#AutoIt3Wrapper_Add_Constants=n

local $delay_time = 10, $sec = @sec, $func_timer

local $gui010 = guicreate('Main Gui',300,500)
local $edt010 = guictrlcreateedit('',0,0,300,450,bitor($es_readonly,$ws_vscroll))
guictrlsetfont(-1,8,800,-1,'Lucinda Console')
local $btn010 = guictrlcreatebutton('Start Delayed Function',10,470,270,20)
guisetstate()

while 1
switch guigetmsg()
case $gui_event_close
Exit
case $btn010
if guictrlread($btn010) = 'Start Delayed Function' Then
guictrlsetdata($btn010,'Stop Delayed Function')
guictrlsetdata($edt010,_nowtime() & ' Begin Wait for Delayed Function' & @crlf,1)
adlibregister('_delayed_function',1000)
$func_timer = timerinit()
Else
guictrlsetdata($btn010,'Start Delayed Function')
adlibunregister('_delayed_function')
EndIf
EndSwitch

if $sec <> @sec then
if mod( @sec, 3) = 0 then _issue_goofy_message()
$sec = @SEC
endif

WEnd

func _delayed_function()

ConsoleWrite(_nowtime() & ' ' & (timerdiff($func_timer)/1000) & @LF)

if (timerdiff($func_timer)/1000) >= $delay_time then
guictrlsetdata($edt010,_nowtime() & ' Delayed Function Running' & @crlf,1)
adlibunregister('_delayed_function')
guictrlsetdata($btn010,'Start Delayed Function')
$func_timer = 0
endif

if mod( int(timerdiff($func_timer)/1000), 5) = 0 then
guictrlsetdata($edt010,_nowtime() & ' Delayed Function Still waiting' & @crlf,1)
return
EndIf

endfunc

func _issue_goofy_message()

guictrlsetdata($edt010,_nowtime() & ' Main Func is running' & @crlf,1)

endfunc

Good Luck,

kylomas

edit: wrong name

edit2: My earlier stmt is full of shit, apologies...

Edited January 27, 2013 by kylomas

[BrewManNH]

How does my entry delay the script, other than the 1 second pause which is only there for demonstration purposes?

[kylomas]

BrewmanNH,

How does my entry delay the script, other than the 1 second pause which is only there for demonstration purposes?

Does it not stay in "myfunction"for 10 seconds? Perhaps I am misreading the script.

kylomas

edit: Your right! apologies...

Edited January 27, 2013 by kylomas

[Amaruq]

Hello BrewManNH,

How does my entry delay the script, other than the 1 second pause which is only there for demonstration purposes?

It doesn't. I wrote that SadBunny's version does everything I need and that is because he did another, for me, more correct interpretation of what I needed.

More specifically about how the function is being called without the need to loop _MyFunction.

[Amaruq]

It was the hugs&kisses, wasn't it? Anyway, good luck and I'm happy I was able to help.

Well, it helped . Thanks again!

[KaFu]

Well, my example does neither require looping.

[Amaruq]

Hello KaFu,

Well, my example does neither require looping.

You are right it doesn't. But the help file states that an adlid function needs to be kept 'simple'.

I'm not an experienced scripter and it's been awhile since I had the need to use AutoIT so as I can't tell what 'simple' is for AutoIT.

The triggered function has several things to do, including connecting to and altering databases, so I choose the safe way.

Anyway, I hope this helps clear things up.