_StringReverse - improved approach?

[guinness]

I'm wondering is there a better approach to the currently implemented version of this function. Suggestions are welcome below on how it can/could be improved.

Edited February 2, 2013 by guinness

[BrewManNH]

_strrev doesn't support Unicode or multi-byte characters, there are other functions in msvcrt.dll that can handle them, _mbsrev for multibyte and _wcsrev for Unicode, although I think the _mbsrev might handle both but I don't know for sure.

[guinness]

I saw this comment from back in December and literally have been thinking I should get around to fixing this function.

[guinness]

Of course the simple way is this.

#include <Constants.au3>

MsgBox($MB_SYSTEMMODAL, '', StringReverse('StringReversed, see how it'' backwards now.'))

Func StringReverse($sString)
    Local $sReturn = ''
    For $i = StringLen($sString) To 1 Step -1
        $sReturn &= StringMid($sString, $i, 1)
    Next
    Return $sReturn
EndFunc   ;==>StringReverse

[czardas]

Of course the simple way is this.

#include <Constants.au3>

MsgBox($MB_SYSTEMMODAL, '', StringReverse('StringReversed, see how it'' backwards now.'))

Func StringReverse($sString)
    Local $sReturn = ''
    For $i = StringLen($sString) To 1 Step -1
        $sReturn &= StringMid($sString, $i, 1)
    Next
    Return $sReturn
EndFunc ;==>StringReverse

This is faster until your string gets beyond about 15 19 characters, Then it becomes far too slow. Edited February 2, 2013 by czardas

[guinness]

This is faster until your string gets beyond about 15 characters, Then it becomes far too slow.

That's the primary reason I haven't committed to the UDFs yet. A user came up with a nice approach to _StringRepeat (search Trac) so I thought there must be something I'm missing. Some shifting or something along those lines.

[BrewManNH]

Without an explanation of WHY she thinks that, it doesn't really affect the fact that _StringReverse doesn't work with Unicode characters. Do we have any links that tell something similar to what she says?

[czardas]

I wouldn't commit the above solution to the UDF. Instead I would create a separate function, or at least a unicode flag, but I would personally prefer a separate function. Something like:

_UnicodeReverse($sUnicodeStr)

Edited February 2, 2013 by czardas

[BrewManNH]

You just recreated the StringReverse function that was in the String UDF before it was changed to make it faster.

; #FUNCTION# ====================================================================================================================
; Name...........: _StringReverse
; Description ...: Reverses the contents of the specified string.
; Syntax.........: _StringReverse($sString)
; Parameters ....: $sString - String to reverse
; Return values .: Success - Returns reversed string
;                  Failure - Returns an empty string and sets @error = 1
;                  |@Error  - 0 = No error.
;                  |@Error  - 1 = One of the parameters is invalid
; Author ........: Jonathan Bennett <jon at hiddensoft com>
; Modified.......:
; Remarks .......:
; Related .......:
; Link ..........;
; Example .......; Yes
; ===============================================================================================================================
Func _StringReverse($sString)
    ;==============================================
    ; Local Constant/Variable Declaration Section
    ;==============================================
    Local $sReverse
    Local $iCount

    If StringLen($sString) >= 1 Then
        For $iCount = 1 To StringLen($sString)
            $sReverse = StringMid($sString, $iCount, 1) & $sReverse
        Next

        Return $sReverse
    Else
        SetError(1)
        Return ""
    EndIf
EndFunc   ;==>_StringReverse

[czardas]

You just recreated the StringReverse function that was in the String UDF before it was changed to make it faster.

I tried the same thing too!

Edited February 2, 2013 by czardas

[kylomas]

@BrewmanNH

Without an explanation of WHY she thinks that, it doesn't really affect the fact that _StringReverse doesn't work with Unicode characters. Do we have any links that tell something similar to what she says?

Just did some searching for this and the only hit I could find that seemed bad was for exe's (games mostly) that had an out of date copy imbedded and it would get called before the correct copy.

kylomas

[guinness]

czardas,

I came across this post when doing some research about _strrev >> http://stackoverflow.com/questions/52002/how-to-check-if-the-given-string-is-palindrome (funny!)

#include <Array.au3>

Local $aString = StringSplit('StringReversed, see how it'' backwards now.', '', 2) ; I don't know the Constant.au3 value for this.
StringReverseChrArray($aString)
_ArrayDisplay($aString)

Func StringReverseChrArray(ByRef $aString) ; Converted from this: http://marc.info/?l=php-general&m=120422082915762
    Local $sChr = '', $i = 0, $j = UBound($aString) - 1

    While ($i < $j)
        $sChr = $aString[$i]
        $aString[$i] = $aString[$j]
        $aString[$j] = $sChr
        $i += 1
        $j -= 1
    WEnd
EndFunc   ;==>StringReverseChrArray

I believe what she says is true, she's a very smart lady indeed.

Edited February 3, 2013 by guinness

[guinness]

You just recreated the StringReverse function that was in the String UDF before it was changed to make it faster.

; #FUNCTION# ====================================================================================================================
; Name...........: _StringReverse
; Description ...: Reverses the contents of the specified string.
; Syntax.........: _StringReverse($sString)
; Parameters ....: $sString - String to reverse
; Return values .: Success - Returns reversed string
;                  Failure - Returns an empty string and sets @error = 1
;                  |@Error  - 0 = No error.
;                  |@Error  - 1 = One of the parameters is invalid
; Author ........: Jonathan Bennett <jon at hiddensoft com>
; Modified.......:
; Remarks .......:
; Related .......:
; Link ..........;
; Example .......; Yes
; ===============================================================================================================================
Func _StringReverse($sString)
    ;==============================================
    ; Local Constant/Variable Declaration Section
    ;==============================================
    Local $sReverse
    Local $iCount

    If StringLen($sString) >= 1 Then
        For $iCount = 1 To StringLen($sString)
            $sReverse = StringMid($sString, $iCount, 1) & $sReverse
        Next

        Return $sReverse
    Else
        SetError(1)
        Return ""
    EndIf
EndFunc   ;==>_StringReverse

This could be improved upon. Edited February 3, 2013 by guinness

[czardas]

Here's a possible unicode check I wrote recently. It would be nice if someone can improve it. Using a check like this might be a plausible option, but I think _StringReverse is okay as it is.

#include <WinAPI.au3>

Func _IsUnicode($sString)
    Local $bRet = False
    If StringIsASCII($sString) = 0 Then
        $sString = StringReplace($sString, "?", "")
        $sString = _WinAPI_WideCharToMultiByte($sString)
        If StringInStr($sString, "?") Then $bRet = True
    EndIf
    Return $bRet
EndFunc

Edited February 3, 2013 by czardas

[kylomas]

Plain English

"Just reverse the string and if it is the same as before, it's a palindrome"

Yes, this was hilarious!

@guinness - There are a bunch of examples of reversing a string on the link you posted. Is it possible to create an module and call it similar to the _winapi_* functions?

Edited February 3, 2013 by kylomas

[guinness]

Well being honesty of course I don't use this function in everyday use, but sometimes it's nice to create topics that can invoke creativity.

[guinness]

Plain English

"Just reverse the string and if it is the same as before, it's a palindrome"

Yes, this was hilarious!

No, I meant that czardas & myself had a discussion about _IsPalindrome (see signature) a week or so ago and what was the correct definition of a palindrome. It was funny that it came up in the search results and so close to the top as well.

[kylomas]

@guinness - Yes, I understand. What makes this so funny is that it is preceeded by numerous programatic solutions and this was presented aa the last solution.

[guinness]

Just has a quick play around with using timers.

expandcollapse popup

#include <String.au3>

Local $aString = StringSplit('StringReversed, see how it'' backwards now.', '', 2) ; I don't know the Constant.au3 value for this.
Local $hTimer = 0

$hTimer = TimerInit()
For $i = 1 To 100000
    StringReverseChrArray($aString) ; Average: 0.108710496513316
Next
ConsoleWrite((TimerDiff($hTimer) / 100000) & @CRLF)

$hTimer = TimerInit()
For $i = 1 To 100000
    StringReverse('StringReversed, see how it'' backwards now.') ; Average: 0.102159167946852
Next
ConsoleWrite((TimerDiff($hTimer) / 100000) & @CRLF)

$hTimer = TimerInit()
For $i = 1 To 100000
    _StringReverse('StringReversed, see how it'' backwards now.') ; Average: 0.0436380721306283 (though uses the wrong approach.)
Next
ConsoleWrite((TimerDiff($hTimer) / 100000) & @CRLF)

Func StringReverseChrArray(ByRef $aString) ; Converted from this: http://marc.info/?l=php-general&m=120422082915762
    Local $sChr = '', $sReturn = ''
    Local $i = 0, $j = UBound($aString) - 1

    While ($i < $j)
        $sChr = $aString[$i]
        $aString[$i] = $aString[$j]
        $aString[$j] = $sChr
        $i += 1
        $j -= 1
    WEnd
EndFunc   ;==>StringReverseChrArray

Func StringReverse($sString)
    Local $sReturn = ''
    For $i = StringLen($sString) To 1 Step -1
        $sReturn &= StringMid($sString, $i, 1)
    Next
    Return $sReturn
EndFunc   ;==>StringReverse

[jchd]

Why not using a plain wstrrev blindly instead?

It has the exact same drawback that every solution shown here so far and will work much faster in probably almost all cases (maybe empty and 1-codepoint strings).