How can I make a entire tab of my GUI accept a drag and drop?

[rmshro0]

I thought I was being clever by trying a hidden input field, but that isn't working. I also tried to set the GUI_DOPACCEPTED on the tab, but that isn't working either.

Thanks for any help!

[PlayHD]

How about this:

#include 
$gHwnd = GuiCreate("Test",600,600,-1,-1,-1,$WS_EX_ACCEPTFILES)
$Tab = GuiCtrlCreateTab(10,10,500,500)
$TabItem1 = GUiCtrlCreateTabItem("Tab1")
$Button1 = GuiCtrlcreateButton("Button",50,50,150,20)
$TabItem2 = GUiCtrlCreateTabItem("Tab2")
$Button2 = GuiCtrlcreateButton("Button",60,50,150,20)
GUiCtrlCreateTabItem("")

GUiSetstate()
local $msg, $cur
While 1
$msg = GUiGetMsg()
Switch $msg
Case $GUI_EVENT_CLOSE
exit
case $GUI_EVENT_DROPPED
$cur = GuiGetCursorInfo()
if isArray($cur) then
if $cur[4] = $Tab then
;Accept file
endif
endif
endswitch
wend

p.s. i not tested, i will tested at home...

[guinness]

PlayHD,

I don't need to test as I can see it won't work. Please study this example carefully on how to structure clean AutoIt GUI code.

expandcollapse popup

#include <Constants.au3>
#include <GUIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate('', Default, Default, Default, Default, Default, $WS_EX_ACCEPTFILES)
    Local $iTab = GUICtrlCreateTab(10, 10, 380, 380)
    GUICtrlSetState($iTab, $GUI_DROPACCEPTED)

    ; Tab 1
    Local $iTabItem_1 = GUICtrlCreateTabItem('Tab1')
    Local $iButton_1 = GUICtrlCreateButton('Close (OnTab_1)', 30, 50, 150, 25)

    ; Tab 2
    GUICtrlCreateTabItem('Tab2')
    Local $iButton_2 = GUICtrlCreateButton('Close (OnTab_2)', 30, 50, 150, 25)

    ; Close the Tab control.
    GUICtrlCreateTabItem('')

    ; Display the GUI.
    GUISetState(@SW_SHOW, $hGUI)

    Local $aGetCursor = 0
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $iButton_1, $iButton_2
                ExitLoop

            Case $GUI_EVENT_DROPPED
                MsgBox($MB_SYSTEMMODAL, '', @GUI_DragFile)

        EndSwitch
    WEnd

    ; Delete the GUI.
    GUIDelete($hGUI)
EndFunc   ;==>Example

Edited February 8, 2013 by guinness

[PhoenixXL]

Something like this - purposely for multiple files

expandcollapse popup

#include <WindowsConstants.au3>
#include <GUIConstants.au3>

If Not IsDeclared( "WM_DROPFILES" ) Then Assign( "WM_DROPFILES", 0x0233, 2 )
Global $CurTabItem = 1, $gaDropFiles

$hGui = WinSetOnTop(GUICreate('WM_DROPFILES', 600, 360, -1, -1, -1, $WS_EX_ACCEPTFILES), '', 1)


Global $iTab = GUICtrlCreateTab(10, 10, 500, 200)
GUICtrlSetState($iTab, $GUI_DROPACCEPTED)

GUICtrlCreateTabItem("Tab1")
GUICtrlCreateTabItem("Tab2")
GUICtrlCreateTabItem(""); end tabitem definition
GUISetState()

GUIRegisterMsg(Eval("WM_DROPFILES"), "WM_DROPFILES")

While GUIGetMsg() <> -3
Sleep(10)
WEnd


Func WM_DROPFILES($hWnd, $msgID, $wParam, $lParam)
Local $nSize, $pFileName
Local $nAmt = DllCall('shell32.dll', 'int', 'DragQueryFileW', 'hwnd', $wParam, 'int', 0xFFFFFFFF, 'ptr', 0, 'int', 0)
For $i = 0 To $nAmt[0] - 1
$nSize = DllCall('shell32.dll', 'int', 'DragQueryFileW', 'hwnd', $wParam, 'int', $i, 'ptr', 0, 'int', 0)
$nSize = $nSize[0] + 1
$pFileName = DllStructCreate('wchar[' & $nSize & ']')
DllCall('shell32.dll', 'int', 'DragQueryFileW', 'hwnd', $wParam, 'int', $i, 'ptr', DllStructGetPtr($pFileName), 'int', $nSize)
$gaDropFiles &= DllStructGetData($pFileName, 1) & @CRLF
$pFileName = 0
Next
$CurTabItem = GUICtrlRead($iTab) + 1
$gaDropFiles = StringTrimRight($gaDropFiles, 2)
ConsoleWrite(StringFormat("+...Dropped On Tab: %s\nFiles- %s\n+....End--\n", $CurTabItem, $gaDropFiles))
$gaDropFiles = ''
EndFunc ;==>WM_DROPFILES

Thumbs up if it helped Edited February 8, 2013 by PhoenixXL

[guinness]

This will cause errors in V3.3.8.1+

[PhoenixXL]

Its working on the latest stable version i.e. 3.3.8.1

need to check with the BETA !

Edited February 8, 2013 by PhoenixXL

[PhoenixXL]

Working with the beta even i.e. 3.3.9.4

Edit : Environment(Language:0409 Keyboard:00000409 OS:WIN_7/ CPU:X64 OS:X86)

Edited February 8, 2013 by PhoenixXL

[guinness]

Strange because in my version $WM_DROPFILES is defined in WindowsConstants, see #2049 I should know as I added it there.

[PhoenixXL]

My fault I felt you are talking about the utility error if its just for declaration my apolozies

I have updated the rectified version

Edited February 8, 2013 by PhoenixXL