Sort Listview Items Alphabetically

[Reinhardt1julian]

How can i Sort the listviewitems alphabetically? Like in the Explorer, on a click on a collumn, this column gets sortet from A-Z, when you click another time this column gets sortet from Z-A

[Melba23]

Reinhardt1julian,

Search for "listview sort" in the Help file and _GUICtrlListView_SimpleSort would jump out as a candidate.

M23

[Reinhardt1julian]

But how can i say on click on column 1

_GUICtrlListView_SimpleSort($ListView, True, 1)

and on click on column 2

_GUICtrlListView_SimpleSort($ListView, True, 2)

Either i'm blind or its not in the helpfile.

Edited February 14, 2013 by Reinhardt1julian

[Melba23]

Reinhardt1julian,

It is one of the more confusing functions - does this help to explain it better?

#include <GUIConstantsEx.au3>
#include <GUIListView.au3>

; This array retains the sort state of each column
Global $aSorting[2]

$hGUI = GUICreate("Test", 500, 500)

$cLV = GUICtrlCreateListView("Col 0|Col 1", 10, 10, 200, 300, Default, $LVS_EX_FULLROWSELECT)
_GUICtrlListView_SetColumnWidth($cLV, 0, 100)
_GUICtrlListView_SetColumnWidth($cLV, 1, $LVSCW_AUTOSIZE_USEHEADER)
For $i = 1 To 14
    $sCol1 = Chr(Random(65, 90, 1))
    $sCol2 = Chr(Random(65, 90, 1))
    GUICtrlCreateListViewItem($sCol1 & "|" & $sCol2, $cLV)
Next

$cButton_0 = GUICtrlCreateButton("Sort Col 0", 10, 320, 80, 30)
$cButton_1 = GUICtrlCreateButton("Sort Col 1", 100, 320, 80, 30)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton_0
            ; We pass the array to the function each time so it know what state it needs to provide
            _GUICtrlListView_SimpleSort($cLV, $aSorting, 0)
        Case $cButton_1
            _GUICtrlListView_SimpleSort($cLV, $aSorting, 1)
    EndSwitch
WEnd

M23

[Reinhardt1julian]

I dont get this part:

For $i = 1 To 14
    $sCol1 = Chr(Random(65, 90, 1))
    $sCol2 = Chr(Random(65, 90, 1))
    GUICtrlCreateListViewItem($sCol1 & "|" & $sCol2, $cLV)
Next

What does it do?

Edited February 14, 2013 by Reinhardt1julian

[Melba23]

Reinhardt1julian,

What does it do to the ListView? What do the individual functions within those lines do?

Read the Help file for Chr and Random and look at the ASCII table in the Appendix - see if you can work it out for yourself. If you cannot after a reasonable time (say 30 mins) ask again.

[Reinhardt1julian]

Ohh, it gives out random letters, right? But can you make the Top of the list view buttons? That were in your script "col 1" or "Col 0" is, that this is a button?

[PhoenixXL]

If you want that way you should look at the example of

GUICtrlRegisterListViewSort

[Reinhardt1julian]

How can is say that 1 column should always be sorted from A-Z? I Can't figure it out. Just "True" wont work. And i don#t find anything in the help file, that could help me.

Edited February 14, 2013 by Reinhardt1julian

[Melba23]

PhoenixXL,

No need to go that far - you can still use the SimpleSort function as long as you do not want the little arrows on the headers:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>

; This array retains the sort state of each column
Global $aSorting[2]

$hGUI = GUICreate("Test", 500, 500)

$cLV = GUICtrlCreateListView("Col 0|Col 1", 10, 10, 200, 300, Default, $LVS_EX_FULLROWSELECT)
_GUICtrlListView_SetColumnWidth($cLV, 0, 100)
_GUICtrlListView_SetColumnWidth($cLV, 1, $LVSCW_AUTOSIZE_USEHEADER)
For $i = 1 To 14
    $sCol1 = Chr(Random(65, 90, 1))
    $sCol2 = Chr(Random(65, 90, 1))
    GUICtrlCreateListViewItem($sCol1 & "|" & $sCol2, $cLV)
Next

GUISetState()

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $iIDFrom
        Case $cLV
            Switch $iCode
                Case $LVN_COLUMNCLICK ; A column was clicked
                    $tInfo = DllStructCreate($tagNMLISTVIEW, $ilParam)
                    _GUICtrlListView_SimpleSort($cLV, $aSorting, DllStructGetData($tInfo, "SubItem"))
            EndSwitch
    EndSwitch

EndFunc

Reinhardt1julian,

I think this script is a bit advanced for you at the moment - but see if you can follow it. The GUIRegisterMsg tutorial in the Wiki might be helpful.

M23

Edit:

Just seen your next question. Just call the SimpleSort function from within your script:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>

; This array retains the sort state of each column
Global $aSorting[2]

$hGUI = GUICreate("Test", 500, 500)

$cLV = GUICtrlCreateListView("Col 0|Col 1", 10, 10, 200, 300, Default, $LVS_EX_FULLROWSELECT)
_GUICtrlListView_SetColumnWidth($cLV, 0, 100)
_GUICtrlListView_SetColumnWidth($cLV, 1, $LVSCW_AUTOSIZE_USEHEADER)
For $i = 1 To 14
    $sCol1 = Chr(Random(65, 90, 1))
    $sCol2 = Chr(Random(65, 90, 1))
    GUICtrlCreateListViewItem($sCol1 & "|" & $sCol2, $cLV)
Next

GUISetState()

; Always have the first column sorted
_GUICtrlListView_SimpleSort($cLV, $aSorting, 0)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

All clear?

M23

[Reinhardt1julian]

Yes, it is a bit too advanced. But i always want column 1 to be sorted from A-Z. But with the $ASort it changes everytime the script is called. But i want it just to sort every item in column 1 to sort from A-Z. But just Putting "true" in the

_GUICtrlListView_SimpleSort

won't work.

[Melba23]

Reinhardt1julian,

But with the $ASort it changes everytime the script is called

No it does not. Are you creating the ListView and running the sort in a function?

M23

[PhoenixXL]

For A-Z I guess it is Ascending

Hence you should use False

[Reinhardt1julian]

I call it after a function. But in my script it changes everytime the sort function is called

[Melba23]

PhoenixXL,

The parameter is passed ByRef - so it must be a predeclared variable or array and cannot be a straight Boolean.

M23

[Melba23]

Reinhardt1julian,

Then set the sort variable each time you call the function like this:

#include <GUIConstantsEx.au3>
#include <GUIListView.au3>

; This array retains the sort state of each column
Global $aSorting[2]

_ListView()

Func _ListView()

    $hGUI = GUICreate("Test", 500, 500)

    $cLV = GUICtrlCreateListView("Col 0|Col 1", 10, 10, 200, 300, Default, $LVS_EX_FULLROWSELECT)
    _GUICtrlListView_SetColumnWidth($cLV, 0, 100)
    _GUICtrlListView_SetColumnWidth($cLV, 1, $LVSCW_AUTOSIZE_USEHEADER)
    For $i = 1 To 14
        $sCol1 = Chr(Random(65, 90, 1))
        $sCol2 = Chr(Random(65, 90, 1))
        GUICtrlCreateListViewItem($sCol1 & "|" & $sCol2, $cLV)
    Next

    GUISetState()

    ; Set the sort like this - then the next sort will always be A-Z
    $fSort = False
    _GUICtrlListView_SimpleSort($cLV, $fSort, 0)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

EndFunc

Better?

M23

[Reinhardt1julian]

It toggles everytime Even if i remove the arguments from $aSorting and set it fo false...

EDIT: Ok, I'll try it as a non-Global variable... And that works

Edited February 14, 2013 by Reinhardt1julian

[Melba23]

Reinhardt1julian,

Then post the code you are using because you must be doing something else in the script to cause it - the code I have posted so far does not exhibit that behaviour when run.

M23

[Reinhardt1julian]

It seemed to be the problem, that i declared the variable as global.

[Melba23]

Reinhardt1julian,

That is the second time you tell us that changing the scope of a variable has solved your problem. Are you sure that you understand variable scope in AutoIt? Did you read, and understand, the tutorial to which I linked you earlier today?

M23