SOLVED:How run a telnet from script

[jacq]

Hi

When I turn on the cmd via start menu and then enter telnet command works but when I run cmd from the script and then I type telnet and press Enter telnet does not work.

Then writes me that does not recognize telnet command.

I have telnet service enabled on the system.

My code:

Run("cmd.exe")
WinWait("C:\Windows\system32\cmd.exe", "", 2)
ControlSend("C:\Windows\system32\cmd.exe", "", "", "telnet")
ControlSend("C:\Windows\system32\cmd.exe", "", "", "{ENTER}")

Edited February 15, 2013 by jacq

[jacq]

Help

[BrewManNH]

Run("telnet")

[jacq]

Run("telnet")

Does not work

[BrewManNH]

Try it with the full path to the telnet program then, it should work.

[jacq]

Try it with the full path to the telnet program then, it should work.

One folder with telnet is a system32 is not working.

The other is amd64 ........... with a very long name (a lot of numbers and letters) runs but it does not look like telnet and when i type commands nothing happens.

[BrewManNH]

Are you running this as a 32 bit program on a 64 bit OS?

If so, this script demonstrates what is going on, it's called File System Redirection, and it affects all 32 bit programs running on a 64 bit OS.

#autoit3wrapper_usex64=n ; runs the script in 32 bit program mode
_Wow64FsRedirection(False)
Run("C:\Windows\System32\telnet.exe")
ConsoleWrite('@SystemDir = ' & @SystemDir & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
; revert filesystem redirection for 32 bit process
MsgBox(0,"", "click me") ; pauses the script until you press OK
_Wow64FsRedirection(True)
 ; this won't show run Telnet because we turned off redirection.
ConsoleWrite(Run("C:\Windows\System32\telnet.exe") & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
; http://www.autoitscript.com/forum/topic/111647-macro-problem-in-win7-x64/#entry790037
Func _Wow64FsRedirection($state)
    ; Disables or reverts the filesystem redirector for a 32 bit process running on 64bit OS
    If Not @AutoItX64 And @OSArch = 'X64' Then
        If $state Then
            DllCall("kernel32.dll", "int", "Wow64RevertWow64FsRedirection", "int", 0)
        Else
            DllCall("kernel32.dll", "int", "Wow64DisableWow64FsRedirection", "int", 0); or 1 as per help
        EndIf
        If @error Then Return SetError(1)
    EndIf
EndFunc

[jacq]

Ok thanks.

If I run telnet in my program as you do in your code, it will be working on 32 and 64 system or do I have to change things?

Do I need to have two versions of the application one at 32 and one 64?

[BrewManNH]

If you compile the program as a 32 bit program and use this to momentarily turn off redirection to run the Telnet program, it won't matter which version of the OS it's being run on because it will just ignore the redirection request on a system that it doesn't apply to (x86 OS).

#autoit3wrapper_usex64=n ; runs the script in 32 bit program mode
; Use False to disable redirection, it will only apply to the program if running as 32 bit process
_Wow64FsRedirection(False)
Run("C:\Windows\System32\telnet.exe")
_Wow64FsRedirection(True)
; http://www.autoitscript.com/forum/topic/111647-macro-problem-in-win7-x64/#entry790037
Func _Wow64FsRedirection($state)
    ; Disables or reverts the filesystem redirector for a 32 bit process running on 64bit OS
    If Not @AutoItX64 And @OSArch = 'X64' Then
        If $state Then
            DllCall("kernel32.dll", "int", "Wow64RevertWow64FsRedirection", "int", 0)
        Else
            DllCall("kernel32.dll", "int", "Wow64DisableWow64FsRedirection", "int", 0); or 1 as per help
        EndIf
        If @error Then Return SetError(1)
    EndIf
EndFunc

[jacq]

Ok thanks