Regex expression problem

[Travis]

I have a problem here with Regex,

If I were to use this expression

$arr = StringRegExp("STARTblablablaaENDblabSTARTlabENDlabSTARTblablaEND","START([a-z|A-Z]*)END",3)

Regex will return only one match, which will contain everything between the first "START" and the last "END"

I do not know how (if it is possible) to tell regex what I know: That between "START" and "END" there will never be the phrase "START" or "END"! but it doesn't know that, because it's only matching any alphabetical character.....

I need to return an array that would have each match separate like this: "blablablaa", "lab", "blabla".

The above expression was just an example, in my actual string it would be all uppercase. But I have tested this above expression and it performs exactly as my program does... Is there any possible way to tell it to match everything except a certain phrase?

[PhoenixXL]

Isnt a replace better at such a condition

#include <Array.au3>

$arr = StringRegExpReplace("STARTblablablaaENDblabSTARTlabENDlabSTARTblablaEND","START|END","")

ConsoleWrite( $arr & @CR )

Are you doing it for nesting purpose,

bcoz i had recently made an Regex for Nesting

[PhoenixXL]

A lazy operator may help

#include <Array.au3>

$String = "STARTRegularExpEND^^^^STARTHelpEND not to capture STARTsomemorecharsEND"
;Need to extrac "

$Ret_arr = StringRegExp( $String,"START([[:alpha:]]*?)END",3)

_ArrayDisplay( $Ret_arr )

Regards

Edited February 18, 2013 by PhoenixXL

[Malkey]

This example makes use of the lookahead and lookbehind assertions.

#include <Array.au3>

Local $sTestString = "STARTRegularExpEnd^^^^StartHelpENDAlso able to be captured.START Some more chars END"

; This Reg. Exp. pattern matches that which is ahead of START and is behind END.
Local $aArrayBetweenStart_EndOnly = StringRegExp($sTestString, "(?i)(?<=START).+?(?=END)", 3)
_ArrayDisplay($aArrayBetweenStart_EndOnly, "Between START and END Only")

; This Reg. Exp. pattern matches that which is ahead of START and is behind END, or,
; matches that which is ahead of END and is behind START.
; "Start" and "End" can be upper or lower case because of "(?i)" in the pattern.
Local $aArrayBetweenAllStarts_Ends = StringRegExp($sTestString, "(?i)(?<=START).+?(?=END)|(?<=End).+?(?=START)", 3)
_ArrayDisplay($aArrayBetweenAllStarts_Ends, "Between All STARTs and ENDs")