Parse declaration line to find assigned variables only.

[guinness]

Is there a possibility with just a single regular exp<b></b>ressi&#111;n pattern to retrieve only $sEnd and $sStart?

Thanks for your time.

#include <Array.au3>

Local Const $sData = "$sEnd = BinaryToString('0x1010101010', $vVar), $sStart = BinaryToString('0x0101010101' & $sString = 'Example')"
#cs
    How would I achieve just returning the variables that are being assign i.e. $sEnd and $sStart?
#ce
Local $aArray = StringRegExp('$iVariableCount, ' & $sData, '(\$\w+)\h*=?', 3)
$aArray[0] = UBound($aArray) - 1
_ArrayDisplay($aArray)

Edit: Also certain users on here can confirm that I have been learning and not just posting at every available opportunity when I get stuck.

Edited February 24, 2013 by guinness

[guinness]

As proof that I'm not totally lazy. Here is the problem solved using native AutoIt string functions.

expandcollapse popup

#include <Array.au3>

#cs
    How would I achieve just returning the variables that are being assign i.e. $sEnd and $sStart?
    $sData = StringRegExpReplace($sData, '\h*(\w+)\h*\([^\n]+\)', '') ; Remove functions. By guinness. Fixed by czardas.
    Local $aArray = StringRegExp('$iVariableCount, ' & $sData, '(\$\w+)\h*=?', 3)
    $aArray[0] = UBound($aArray) - 1
#ce

Local Const $sData = "$sEnd = BinaryToString('0x1010101010', $vVar), $sStart = BinaryToString('0x0101010101' & $sString = 'Example')"
Local Const $aArray = _ParseDeclarationLine($sData)
_ArrayDisplay($aArray)

Func _ParseDeclarationLine(ByRef Const $sData)
    Local Enum $ePARSE_CONTINUE, $ePARSE_VARIABLE
    Local $fIgnoreVars = False, $iIndex = 0, $iParenthesis = 0, $iState = $ePARSE_CONTINUE, _
            $sChr = '', $sStack = '', $sVarList = ''

    While Not ($iIndex = StringLen($sData))
        $iIndex += 1
        $sChr = StringMid($sData, $iIndex, 1)

        Switch $iState
            Case $ePARSE_CONTINUE
                Switch $sChr
                    Case '('
                        $iParenthesis += 1
                    Case ')'
                        $iParenthesis -= 1
                        If Not $iParenthesis And $fIgnoreVars Then $fIgnoreVars = False
                    Case '='
                        $fIgnoreVars = True
                    Case ','
                        If Not $iParenthesis And $fIgnoreVars Then $fIgnoreVars = False
                    Case '$'
                        $iState = $ePARSE_VARIABLE
                        $sStack &= $sChr
                EndSwitch
            Case $ePARSE_VARIABLE
                Switch $sChr
                    Case 'A' To 'Z', 'a' To 'z', '0' To '9', '_', '[', ']', '$'
                        $sStack &= $sChr
                    Case Else
                        ConsoleWrite($sStack & @CRLF)
                        If Not $iParenthesis And Not ($sStack == '$') And Not ($sStack == '') And Not $fIgnoreVars Then
                            $sVarList &= $sStack & '|'
                        EndIf
                        $sStack = ''
                        $iState = $ePARSE_CONTINUE
                EndSwitch
                If $iState = $ePARSE_CONTINUE Then
                    $iIndex -= 1
                EndIf
        EndSwitch
    WEnd
    If $sVarList Then
        $sVarList = StringTrimRight($sVarList, StringLen('|'))
    EndIf
    Return SetError($sVarList == '', 0, StringSplit($sVarList, '|'))
EndFunc   ;==>_ParseDeclarationLine

Edit: Not completely full proof yet. - Should be working again.

Edited February 24, 2013 by guinness

[PhoenixXL]

Till I have tested the following regex should do the work

expandcollapse popup

#include <Array.au3>

Local Const $sData = "$sEnd = @ScriptFullPath, $n = True, $y = $z"
#cs - Limitations
The Regex would not work if
|Underscore is used
Another Limitation
|Some Backreferences were required hence flag 4 is used, as a result the array group 1 has to be checked
#ce

Local $sPattern = _
'(\$\w+)(?:[\s+-/*&]*=\s*)' & _ ;From the Variable name to the End of the Space(s) succeeding the equal sign
'(?i:([''"])(.*?\2)|' & _ ;String
'\d+|@\w+|true|false|' & _ ;Digit, macro, boolean
'\w+\(.*?\)|' & _ ;Function
'\$\w+)' & _ ;Another Variable
'[,\s]*' ;The left out comma and space

ConsoleWrite($sPattern & @CR)

Local $aArray = StringRegExp($sData, $sPattern, 4)
Local $l = 0, $sTxt
For $i = 0 To UBound($aArray) - 1
$l = $aArray[$i]
$sTxt &= $l[1] & @CR
Next
MsgBox(64, "Return:", StringTrimRight($sTxt, 1))

#cs - Basic Keypoints
The Assigned value could be
|Return of function
|A String
|A Digit
The next value would be separated by a comma
The character preceding the equal sign could be
|+
|-
|/
|*
|&
#ce

The Underscore part is left, if interested check the RegEx topic in my signature there is an example to proceed further.

I am assuming that since you have to check the assigned variables there would be no null variables present

Regards

Edited February 24, 2013 by PhoenixXL

[guinness]

Wow, fast response. Thanks.

Another example (that I didn't take into account above) was a variable being assigned another variable.

Local Const $sData = "$sEnd = BinaryToString('0x1010101010', $vVar), $sStart = BinaryToString('0x0101010101' & $sString = 'Example'), $sExample = $sText"

[PhoenixXL]

Very Right. I have modified the post above

[guinness]

Thanks ever so much. I truly have a lot to learn now. Thanks.

[PhoenixXL]

Missed out the boolean and macro characters,

have again edited the script

Regards