Add a new item to a listbox from user?

[iahngy]

I am going to create a list with certain items(_GUICtrlListBox_Create) ..but to get new items from user ...I create a single input box then get the data from input box (GUICtrlCreateInput) and display in the list?

what is the best way to display a list and can be added multiple items in by user?

Edited February 27, 2013 by iahngy

[PhoenixXL]

Example

#include <GUIConstants.au3>

GUICreate(@ScriptName, 300, 350)
$iList = GUICtrlCreateList("", 10, 10, 280, 180)
$btnAdd = GUICtrlCreateButton("Add To List:", 10, 220, 100)
$iInput = GUICtrlCreateInput("", 130, 220, 160)
GUISetState()

Local $sRead
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
GUIDelete()
Exit
Case $btnAdd
$sRead = GUICtrlRead($iInput)
If $sRead <> '' Then GUICtrlSetData($iList, $sRead)
EndSwitch
WEnd

Regards

[PhoenixXL]

Another example using the API

expandcollapse popup

#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

_Main()

Func _Main()
Local $hListBox

; Create GUI

GUICreate(@ScriptName, 300, 300)
$hListBox = GUICtrlCreateList("First Line", 10, 10, 280, 180)
$btnAdd = GUICtrlCreateButton("Add To List:", 10, 220, 100)
$iInput = GUICtrlCreateInput("", 130, 220, 160)
GUISetState()


; Loop until user exits
Do
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
ExitLoop
Case $btnAdd
AddString($hListBox, GUICtrlRead($iInput))
EndSwitch
Until 0
GUIDelete()
EndFunc   ;==>_Main

Func AddString($hListBox, $String)

; Add strings
_GUICtrlListBox_BeginUpdate($hListBox)
_GUICtrlListBox_AddString($hListBox, $String)
_GUICtrlListBox_UpdateHScroll($hListBox)
_GUICtrlListBox_EndUpdate($hListBox)

EndFunc   ;==>AddString

[iahngy]

Thanks PhoenixXL. The 2nd one is cool..is there a list box where i just double click on the item then it is transfered to the another list box ?

[PhoenixXL]

That you have to do !!

check LBN_DBLCLK,

with WM_COMMAND

Search the Forum for some examples

Regards

[iahngy]

found one example of Melba..Thanks PhoenixXL