A little problem with the speed for 'Summing Digits'

[Underdogger]

Is it possible for writing this programming without using Original function..?

this is the example:

f( n ) = 1+2+3+4+5+6+7+8+9+2 = 47

f(f( n )) = 4+7 = 11

f(f(f( n ))) = 1+1 = 2

g( 1234567892 ) = 2

And this is my script below,

but I used two Func >> StringMid & StringLeft

Local $step = 0
$xx = InputBox("", "")

while 1
    $s1 = _StrLen($xx)
    $xx = _LoopAccumulator($s1)
    $step += 1
    If _strlen($xx) == 1 Then
        ExitLoop
    EndIf
WEnd

MsgBox(0, "", $xx & @CRLF & $step & " STEP")

Func _LoopAccumulator($x)
    Local $s = 0
    For $i = 1 To $x
        $s += StringMid($xx, $i, 1)
    Next
    Return $s
EndFunc

Func _StrLen($char)
    Local $i = 0
    Do
        $i += 1
        $chr = StringLeft($char, $i)
        $n = $chr
    Until $n == $char
    Return $i
EndFunc

[Melba23]

Underdogger,

I would do it this way - no point in making it recursive:

$sNumbers = "1239"

Do
    $sNumbers = _Summer($sNumbers)
Until StringLen($sNumbers) = 1

ConsoleWrite($sNumbers & @CRLF)

Func _Summer($sInit)

    $aSplit = StringSplit($sInit, "")
    $iTotal = 0
    For $i = 1 To $aSplit[0]
        $iTotal += $aSplit[$i]
    Next
    ConsoleWrite($iTotal & @CRLF)
    Return String($iTotal)

EndFunc

M23

[jchd]

I'd do it all in one run:

Local $aValues[6] = [1234567892, 12345, "87564", 16418961607, -5889740361, "123.456"]

For $numb In $aValues
ConsoleWrite("The sum of the absolute value of the integer part of " & $numb & " is " & _DigitSum($numb) & @LF)
Next

Func _DigitSum($value)
$value = Abs(Int($value))
ConsoleWrite($value & @LF)
Local $aDigits = StringSplit($value, '', 2)
Local $iSum = 0
For $digit In $aDigits
ConsoleWrite($iSum & ' + ' & $digit & " --> ")
$iSum += $digit
ConsoleWrite($iSum & " --> ")
If $iSum > 9 Then $iSum = Mod($iSum, 10) + 1
ConsoleWrite($iSum & @LF)
Next
Return($iSum)
EndFunc

Geez, which idol should I implore to have tabs being kept verbatim in AutoIt code blocks?

Edited March 12, 2013 by jchd