Click on a menu

[aleksa]

I'm just curious why this doesn't work. Why doesn't the program exit when exit menu is clicked. What am I doing wrong?

#include
#include

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 221, 173, 192, 114)
$exit = GUICtrlCreateMenu("Exit")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
     $nMsg = GUIGetMsg()
     Switch $nMsg
         Case $GUI_EVENT_CLOSE
             Exit
         Case $exit
             ;This doesn't get called
             Exit
     EndSwitch
WEnd

Edited March 15, 2013 by aleksa

[Nessie]

You are not using a MenuItem so GUIGetMsg doesn't get nothing. Create a menu item and all will work good:

#include <GUIConstantsEx.au3>

#region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 221, 173, 192, 114)
$Menu = GUICtrlCreateMenu("File")
$Menu_Exit = GUICtrlCreateMenuItem("Exit", $Menu)

GUISetState(@SW_SHOW)
#endregion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Menu_Exit
            Exit
    EndSwitch
WEnd

Hi!

Edited March 15, 2013 by Nessie

[Melba23]

aleksa,

You need a MenuItem in the menu:

#include <GUIConstantsEx.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 221, 173, 192, 114)
$Menu = GUICtrlCreateMenu("Exit")
$mExit = GUICtrlCreateMenuItem("Exit", $Menu) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
     $nMsg = GUIGetMsg()
     Switch $nMsg
          Case $GUI_EVENT_CLOSE, $mExit ; Note multiple controls <<<<<<<<<<<<<<<<<<<
               Exit
     EndSwitch
WEnd

Somewhere I once did manage to get a menu to fire directly - I will see if I can find it.

M23

[Melba23]

aleksa,

Found it - but it is probably too complex for your needs, so I suggest using a MenuItem as I suggested above:

expandcollapse popup

#include <GUIConstantsEx.au3>
#Include <GuiMenu.au3>

$hGUI = GUICreate("Test", 500, 500)

$mFilemenu = GUICtrlCreateMenu("File")
$mExititem = GUICtrlCreateMenuItem("Exit", $mFilemenu)
$mSpecialitem = GUICtrlCreateMenu("Special")
$mHelpmenu = GUICtrlCreateMenu("?")
$mAboutitem = GUICtrlCreateMenuItem("About", $mHelpmenu)

GUISetState()

$hMenu = _GUICtrlMenu_GetMenu($hGUI)
$iCount = _GUICtrlMenu_GetItemCount($hMenu) - 1

GUIRegisterMsg(0x0211,"_WM_ENTERMENULOOP") ; WM_ENTERMENULOOP

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $mExititem
            Exit
        Case $mAboutitem
            MsgBox(0, "Solved", "That was hard work!")
    EndSwitch

WEnd

Func _WM_ENTERMENULOOP($hWnd, $iMsg, $wParam, $lParam)

    For $i = 0 To $iCount

        Local $tRect = _GUICtrlMenu_GetItemRectEx($hGUI, $hMenu, $i)
        Local $aMousePos = MouseGetPos()
        Local $aRes = DllCall("User32.dll", "int", "PtInRect", "ptr", DllStructGetPtr($tRect), "int", $aMousePos[0], "int", $aMousePos[1])
        If Not @error And $aRes[0] Then
            ConsoleWrite("You clicked: " & _GUICtrlMenu_GetItemText($hMenu, $i) & @CRLF)
            ExitLoop
        EndIf

    Next

EndFunc

Note that clicking a menu is a modal operation - so you will need to click again to reactivate the script after having clicked a menu with no items.

M23

[aleksa]

Thanks for you replies. I'm glad I figured that out

Melba32 code will definitely be in my template list