StringRegExp doubt

[avechuche]

Hi guys, I need your help. I have a text file and I want to capture the contents using regular expressions. The way the text is so.

/ / First line, all this after "/ /" are comments
text
text2 / / Comment
text3
/ / More comments
text with spaces
text with spaces1 / / more and more comments

and I need the following

text
text2
text3
text with spaces
text with spaces1

Any solution?

Sorry for my english

[Melba23]

avechuche,

Welocme to the AutoIt forum.

The best I can do is this:

$sString = '/ / First line, all this after "/ /" are comments' & @CRLF & _
           'text' & @CRLF & _
           'text2 / / Comment' & @CRLF & _
           'text3' & @CRLF & _
           '/ / More comments' & @CRLF & _
           'text with spaces' & @CRLF & _
           'text with spaces1 / / more and more comments' & @CRLF & _
           'text4'

$sNewString = StringRegExpReplace($sString, "(?U)(.*)?(\/\s\/.*)(\v)", "$1$3")

MsgBox(0, "Result", $sNewString)

The blank lines should be easy enough to ignore!

But if you wait a bit, a real guru will doubtless how us both how to do it properly.

M23

[Malkey]

Here is another possible solution.

$sString =  '/ / First line, all this after "/ /" are comments' & @CRLF & _
            'text' & @CRLF & _
            'text2 / / Comment' & @CRLF & _
            'text3' & @CRLF & _
            '/ / More comments' & @CRLF & _
            'text with spaces' & @CRLF & _
            'text with spaces1 / / more and more comments' & @CRLF & _
            'text4'

$sNewString = StringRegExpReplace($sString, "(?m)(^\/\h*\/.*\v*)|(\/\h*\/[^\v]*)", "")

MsgBox(0, "Result", $sNewString)

[water]

Regular Expressions will always remain a mystery to me

[sentry07]

Just chiming in here to say that I use a program to check all my RegEx strings that is free/donationware. It will also help you build the string and show you the output so you can tweak it to fit.

http://www.redfernplace.com/software-projects/regex-builder/

I couldn't come up with a better way of doing this though.

[ChuckNorrious]

You can try this using stringsplit

Local $file = FileOpen("test.txt", 0)
Local $outfile = "output.txt"

While 1
Local $line = FileReadLine($file)
If @error = -1 Then ExitLoop
$tmp = stringsplit($line, '/')
if $tmp[0] > 0 and $tmp[1] then filewriteline($outfile, stringstripws($tmp[1], 3))
WEnd

FileClose($file)

if you're set on using regex then try this:

Local $file = FileOpen("test.txt", 0)
Local $outfile = "output.txt"

While 1
Local $line = FileReadLine($file)
If @error = -1 Then ExitLoop
local $tmp = stringregexp($line, '^([^/]*)', 1)
if isarray($tmp) and $tmp[1] then filewriteline($outfile, stringstripws($tmp[1], 3))
WEnd

FileClose($file)

Edited March 20, 2013 by ChuckNorrious

[guinness]

Regular Exp<b></b>ressi&#111;ns will always remain a mystery to me

Do you want someone to decode it for you?

[water]

No, thanks. I will stick with string functions. I can do what I need to do with this functions.

[Melba23]

water,

I really would recommend trying to get a basic understanding of SREs. I agree that you can do most things with the String* functions, but there are times when only a SRE will do (and they are usually a lot faster as well). I do not consider myself very good at them, but being able to produce even a simple SRE (usually at the expense of a bit of time, hair and profanity) has been very useful on many occasions.

M23

[guinness]

I agree with Melba23 as well as water that sometimes string functions just serve a purpose without overcomplicating the situation with a SRE. But sometimes string functions just "can't cut the mustard."

#include <Constants.au3>

; With string functions.
Local $sVersion = '20.0.10.1000' ; Some version number.
Local $sStrippedVersion = '', $sChr = ''
For $i = 1 To StringLen($sVersion)
    $sChr = StringMid($sVersion, $i, 1)
    If StringIsInt($sChr) Then
        $sStrippedVersion &= $sChr
    EndIf
Next
MsgBox($MB_SYSTEMMODAL, '', $sStrippedVersion)

; With a regular expression.
Local $sVersion = '20.0.10.1000' ; Some version number.
Local $sStrippedVersion = StringRegExpReplace($sVersion, '\D', '')
MsgBox($MB_SYSTEMMODAL, '', $sStrippedVersion)

[kylomas]

But sometimes string functions just "can't cut the mustard."

As a wise man once said "The thing about regexp's is knowing when to use them."

Who might have said that, M23?

kylomas

edit: ...Hmmmm, tongue in cheek does not translate well to this medium...

Edited March 21, 2013 by kylomas

[czardas]

I agree with Melba23 as well as water that sometimes string functions just serve a purpose without overcomplicating the situation with a SRE. But sometimes string functions just "can't cut the mustard."

And when SRE also fails, you just have to run multiple passes. I sometimes use SRE when it's not actually needed. It's good to see all these recent examples. I'm still only scratching the surface with SRE after two years. It's getting a lot easier though.

Edited March 21, 2013 by czardas

[water]

OK, the next time I have to "cut mustard" I will give SRE a try

[Melba23]

kylomas,

As a wise man once said "The thing about regexp's is knowing when to use them."

Who might have said that, M23?

It was actually GEOSoft when he was guiding me through my initial faltering steps with SREs.

The problem I have is that I seem to have passed directly from the "crawling" stage to the "zimmer frame" stage without ever really making it to proper "walking" on the way!

M23

[avechuche]

Thank you all for the help! But now I come with two things

1) Comments with are "//", not "/ /" (no space between the "/")

2) Somehow I can directly put the results into an array?

I use the following function

Func _llenarArray($sFileDir)

$fileRead = FileRead($sFileDir)
If Not @error Then
$aArray = StringRegExpReplace($fileRead, "(?m)(^//.*\v*)|(//[^\v]*)", "")
$aArray = StringRegExp($aArray, "\V+", 3)
If Not @error Then Return $aArray
EndIf

EndFunc ;==>_llenarArray

3) Someone can explain me who used the ER? I understand the following

(?m), not exactly what function does this, I read in the help but I do not understand

(^//.*v*), I understand that all this text after "//", it deleted, what role does not understand that this "v*"

(//[^v]*) Same as above, how it works "v*"

thanks for everything

Edited March 22, 2013 by avechuche

[Malkey]

Here is an example with the regular expression patterns explained.

expandcollapse popup

#include <Array.au3>

Local $sString, $aArr
$sString = '// First line, all this after "//" are comments' & @CRLF & _
'text' & @CRLF & _
'text2 // Comment' & @CRLF & _
'text3' & @CRLF & _
'// More comments' & @CRLF & _
'text with spaces' & @CRLF & _
'text with spaces1 // more and more comments' & @CRLF & _
'text4'
$aArr = _llenarArray($sString)
_ArrayDisplay($aArr)

#cs
(?m)^[^/\v]+ Explained
(?m)^ - Start matching at the beginning of each line.
[^/\v]+ - Match all characters, travelling travelling from left (the start of line) to right, that are
         not a "/" or any vertical white spaces (CR or LF).
         And, the "+" means those non-characters must exist at least once or many times for a match.


(?m)(^//.*\v*)|(//[^\v]*) Explained
(?m)     - Where "^" appears, and not inside square brackets, refers to the beginning of each line.
(^//.*\v*) - Capture the group of characters on a line that start with "//" followed by none or many
             any characters up to and including the vertical white spaces at the end of the line if it exists.
("*" meaning {0,} meaning the previous character or group can exist none or many times.)
|        - or (Match either the previous group or the following group.)
(//[^\v]*) - Capture the group of characters starting with "//" followed by none or many non-vertical white
             spaces.(That is: all characters that are not vertical white spaces like Carriage Returns (CR)
or Line Feeds (LF)).
             "(//[^\v]*)" is the same as "(//\V*)"
#ce
Func _llenarArray($fileRead) ; $sFileDir)
Local $aArray
;$fileRead = FileRead($sFileDir)
If Not @error Then
$aArray = StringRegExp($fileRead, "(?m)^[^/\v]+", 3)
MsgBox(0,"Text Message Box", StringRegExpReplace($fileRead, "(?m)(^//.*\v*)|(//[^\v]*)", ""), 4) ; For display purposes only.
If Not @error Then Return $aArray
EndIf
EndFunc ;==>_llenarArray

Edit:

avechuche

Might be best not to use my StringRegExp function to form an array because elements of the array will be formed when only one "/" is present.

Your example @ post#15 appears to work fine.

Edited March 22, 2013 by Malkey

[jchd]

If you whish to preserve empty lines (typically used to make C++ style source easier to read by making blocks stand out), make that:

#include <Array.au3>

$sSource =  '// First line, all this after "//" are comments' & @CRLF & _
            'text' & @CRLF & _
            'text2 // Comment' & @CRLF & _
            'text3' & @CRLF & _
            '// More comments' & @CRLF & _
            '' & @CRLF & _
            'text with spaces' & @CRLF & _
            'text with spaces1 // more and more comments' & @CRLF & _
            'text4'

$sNoComment = StringRegExpReplace($sSource, "(?m)(^//.*\R)|(//[^\v]*)", "")
ConsoleWrite($sNoComment & @LF)
$aActualCode = StringRegExp($sNoComment, '(?m)(^.*)', 3)
_ArrayDisplay($aActualCode)

[avechuche]

Thanks again to everyone, GREAT COMMUNITY THAT!.

@Malkey, your solution works perfectly, no matter if "/" is present

Thx @jchd