Hotkey press-release

[OliverA]

Hi community i have a problem with hotkey

HotKeySet("{F5}", "Test")

While 1
Sleep(100)
WEnd

Func Test()
ConsoleWrite("TEST" & @CRLF)
EndFunc

If i press F5 i have a ConsoleWrite, ok is good

But if i press and I hold down F5 i have multiple ConsoleWrite until i release it, and i want to avoid this

Please an help, many thanks

[OliverA]

Both solution are wrong and not working, the first call itself??? The second not work and i can't use _IsPressed for many reason. Thanks anyway

I have try to use a flag:

HotKeySet("{F5}", "Test")

$f = True

While 1
Sleep(100)
WEnd

Func Test()
If $f = True Then
  ConsoleWrite("TEST" & @CRLF)
  $f = False
EndIf
EndFunc   ;==>Test

But work only one time, the second time the flag is false so F5 don't do nothing

[OliverA]

Man, did you test what you post?

Not working, and i'll repeat i can't use _IsPressed, in the main script i read the Hotkey from another file and _IsPressed don't use standard "abc" but "123" codes

Thanks again

Edited March 30, 2013 by OliverA

[JohnOne]

Use hotkey udf example scripts, you can use NO_REPEAT flag.

[OliverA]

Hotkey UDF use integer values ​​instead of strings, so i have the same problem of _IsPressed but thanks for the suggestion.

I thought it was a simple thing to solve

[JohnOne]

Then I believe it's time to explain your problem with integers.

[OliverA]

in the main script i read the Hotkey from another file and _IsPressed don't use standard "abc" but "123" codes

That's mine problem

Edited March 30, 2013 by OliverA

[JohnOne]

Then I'd suggest you take what you read from another file, and parse it in some fashion to use the integers needed in UDF.

[OliverA]

I'll use it like one's last hope if noone have other solution

[water]

This has been asked and solved many times. Did you search the forum?

[OliverA]

Uhm, yes? I have not find anything useful, i'll search berfore post on the forum and on google using site:autoitscript.com

[water]

Check for "HotKeySet _IsPressed".

[OliverA]

Again with IsPressed...i can't use it, too much problem. You can't combine more then once key ( or you need to do if _IsPressed($hexkey) And _IsPressed($hexkey2) then ) and i need to convert the string to the hex value

There is no alternative solution like flags or things like that?

[Melba23]

OliverA,

As you refuse to use the sensible functions provided in AutoIt to do this, you need to think laterally:

HotKeySet("{F5}", "_Test")

; Declare a flag
Global $fRunning = False

While 1
    Sleep(10)
WEnd

Func _Test()
    If Not $fRunning Then
        ConsoleWrite("TEST" & @CRLF)
        ; Set the flag
        $fRunning = True
        ; Run a function to clear the flag after a delay
        AdlibRegister("_Kill_Test", 1000) ; Adjust the delay as required
    EndIf
EndFunc

Func _Kill_Test()
    ; Clear the flag
    $fRunning = False
    ; Stop the function
    AdlibUnRegister("_Kill_Test")
EndFunc

Not very elegant, but it works.

M23

[OliverA]

AdlibRegister seems a good compromize, i'll test it and let you know, thanks

[water]

Again with IsPressed...i can't use it, too much problem.

The example you showed us in your OP looks like a simplified version of the problem you try to solve. Can you please explain what you REALLY try to achieve?

[Melba23]

OliverA,

Or you could check which key was pressed as the HotKey fires and then wait for that key to be released:

#include <WinAPI.au3>

HotKeySet("{F5}", "_Test")
HotKeySet("{ESC}", "On_Exit")

Global $fRunning = False

While 1
    Sleep(10)
WEnd

Func _Test()
    If Not $fRunning Then
        ConsoleWrite("TEST" & @CRLF)
        ; Set flag to prevent multiple firings
        $fRunning = True
        ; Which F key was pressed?
        For $iF_Key = 0x70 To 0x7B
            If _WinAPI_GetAsyncKeyState($iF_Key) Then
                ExitLoop
            EndIf
        Next
        ; Wait until it is released
        While _WinAPI_GetAsyncKeyState($iF_Key)
            Sleep(10)
        WEnd
        ; Clear flag
        $fRunning = False
    EndIf
EndFunc

Func On_Exit()
    Exit
EndFunc

A word of warning: do not post any code which checks for more than a few keys (the above checks for the F1-F12 keys only) - this announcement explains why.

M23

[OliverA]

With the Melba's first code ( the adilib ) i have resolved, not like expeted but at last i have "stopped" to run the function every x second.

I have read the announcement but i'm "register" only one key, but i don't know what is the key because is in txt file.

Thanks to everyone for the effort

[Melba23]

OliverA,

Just to make clear - it does not matter how many keys you want to "register", it is the number of keys you scan within that If _WinAPI_GetAsyncKeyState loop that is the key to whether you are legal or not.

M23