Using the GUIGetMsg ControlID return value as an array index value.

[guinness]

This is a proof of concept of using the ControlID returned by GUIGetMsg to use as an array index value. This is intended for those who have a basic understanding of AutoIt and GUI creation.

expandcollapse popup

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>

; Proof of concept for using the ControlID as an index item for an array.
Example()

Func Example()
    ; Create the GUI.
    Local $iHeight = 400, $iWidth = 400
    Local $hGUI = GUICreate('', $iWidth, $iHeight)
    GUISetState(@SW_SHOW, $hGUI)

    ; Declare variables to be used throughout the example.
    Local Const $iBUTTON_TOTAL = 8
    Local Enum $eMSG_ID, $eMSG_STRING
    Local $aMsg[1][2] = [['', '']], _
            $iButtonHeight = $iHeight / $iBUTTON_TOTAL, $iButtonWidth = $iWidth / $iBUTTON_TOTAL, $iControlID = 0

    For $i = 0 To $iBUTTON_TOTAL - 1
        For $j = 0 To $iBUTTON_TOTAL - 1
            $iControlID = GUICtrlCreateButton('', $i * $iButtonWidth, $j * $iButtonHeight, $iButtonWidth, $iButtonHeight, $BS_CENTER)
            GUICtrlSetData($iControlID, $iControlID)
            ; Increase the size if the ControlID is greater or equal to the total size of the array.
            If $iControlID >= UBound($aMsg) Then ReDim $aMsg[Ceiling($iControlID * 1.2)][2]
            ; Add to the array.
            $aMsg[$iControlID][$eMSG_ID] = 'ControlID: ' & $iControlID
            $aMsg[$iControlID][$eMSG_STRING] = 'Sample string for ControlID value - ' & $iControlID
        Next
    Next
    ; Clear empty items after the last created ControlID.
    ReDim $aMsg[$iControlID + 1][2]

    Local $iMsg = 0
    While 1
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $aMsg[0][$eMSG_ID] To UBound($aMsg)
                ; If $iMsg is greater than 0 and between the 0th index of $aMsg and the last item.
                If $iMsg Then ConsoleWrite($aMsg[$iMsg][$eMSG_ID] & ', ' & $aMsg[$iMsg][$eMSG_STRING] & @CRLF)
        EndSwitch
    WEnd
    GUIDelete($hGUI)
EndFunc   ;==>Example

[kylomas]

guinness,

Here's a couple more (if I'm getting your point)

#include <GUIConstantsEx.au3>

#AutoIt3Wrapper_Add_Constants=n

local $msg

local $gui010 = guicreate('Checkbox Controls Using eval("var") for the Control ID')

for $1 = 1 to 15
    guictrlcreatelabel('CheckBox #' & stringformat('%02i',$1),10, $1 * 25,90,20)
    assign('checkbox' & $1,GUICtrlCreateCheckbox('',95, $1 * 25,20,15))
Next

guisetstate()

while 1

    $msg = guigetmsg()

    switch $msg
        case $gui_event_close
            Exit
        case eval('checkbox' & 1) to eval('checkbox' & 15)
            for $1 = 1 to 15
                if guictrlread(eval('checkbox' & $1)) = $gui_checked then
                    ConsoleWrite('Checkbox #' & stringformat('%02i',$1) & ' checked' & @LF)
                else
                    ConsoleWrite('Checkbox #' & stringformat('%02i',$1) & ' unchecked' & @LF)
                endif
            next
    EndSwitch

wend

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

#AutoIt3Wrapper_Add_Constants=n

local $ckb_cntrls[16], $msg

local $gui010 = guicreate('Checkbox Controls Using an Array for the Control ID')

for $1 = 1 to 15
    $ckb_cntrls[$1] = GUICtrlCreateCheckbox('CheckBox #' & stringformat('%02i',$1),95, $1 * 25,140,15)
Next

guisetstate()

while 1

    $msg = guigetmsg()

    switch $msg
        case $gui_event_close
            Exit
        case $ckb_cntrls[1] to $ckb_cntrls[ubound($ckb_cntrls) - 1]
            local $h = _winapi_getfocus()
            ConsoleWrite($h & @LF)
            ConsoleWrite('Last action on ' & wingettitle($h) & @LF)
            for $1 = 1 to ubound($ckb_cntrls) - 1
                if guictrlread($ckb_cntrls[$1]) = $gui_checked then
                    ConsoleWrite('Checkbox #' & stringformat('%02i',$1) & ' checked' & @LF)
                else
                    ConsoleWrite('Checkbox #' & stringformat('%02i',$1) & ' unchecked' & @LF)
                endif
            next
    EndSwitch

wend

kylomas

[guinness]

Kind of. But I would use ExitLoop and not Exit, plus GUIDelete to tidy up at the end, just like I did.

[guinness]

This is where the table datatype would be useful, I truly believe.