[SOLVED] TAB: How to insert new control to existing tab item

[mLipok]

I create GUIi with 3 tabitems

I show the GUI

How to add a new control (for example ListView), into existing TabItem

of course after the GUI creatation process is finished (at the any moment).

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $listview, $button, $item1, $item2, $item3, $msg

GUICreate("listview items", 400, 350, 100, 200)
GUISetBkColor(0x00E0FFFF) ; will change background color


GUICtrlCreateTab(10, 50, 380, 290)

GUICtrlCreateTabItem("tab0")

GUICtrlCreateTabItem("tab1")
Global $button = GUICtrlCreateButton("Value?", 75, 170, 70, 20)

GUICtrlCreateTabItem("tab2")

GUICtrlCreateTabItem("") ; end tabitem definition

GUICtrlSetState(-1, $GUI_DROPACCEPTED) ; to allow drag and dropping
GUISetState()
Sleep(1000)


Example_2()
Do
$msg = GUIGetMsg()

Select
Case $msg = $button
MsgBox(0, "listview item", GUICtrlRead(GUICtrlRead($listview)), 2)
Case $msg = $listview
MsgBox(0, "listview", "clicked=" & GUICtrlGetState($listview), 2)
EndSelect
Until $msg = $GUI_EVENT_CLOSE


Func Example_2()
$listview = GUICtrlCreateListView("col1 |col2|col3 ", 100, 10, 200, 150);,$LVS_SORTDESCENDING)
$item1 = GUICtrlCreateListViewItem("item2|col22|col23", $listview)
$item2 = GUICtrlCreateListViewItem("item1|col12|col13", $listview)
$item3 = GUICtrlCreateListViewItem("item3|col32|col33", $listview)
[size=4]EndFunc ;==>Example_2[/size]

How you see my example create ListView which is over Tab not inside.

Edited April 8, 2013 by mlipok

[PhoenixXL]

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $listview, $button, $item1, $item2, $item3, $msg

GUICreate("listview items", 400, 350, 100, 200)
GUISetBkColor(0x00E0FFFF) ; will change background color


GUICtrlCreateTab(10, 50, 380, 290)

GUICtrlCreateTabItem("tab0")

GUICtrlCreateTabItem("tab1")
Global $button = GUICtrlCreateButton("Value?", 75, 170, 70, 20)

GUICtrlCreateTabItem("tab2")


GUICtrlSetState(-1, $GUI_DROPACCEPTED) ; to allow drag and dropping


Example_2()
GUISetState()
Do
$msg = GUIGetMsg()

Select
Case $msg = $button
MsgBox(0, "listview item", GUICtrlRead(GUICtrlRead($listview)), 2)
Case $msg = $listview
MsgBox(0, "listview", "clicked=" & GUICtrlGetState($listview), 2)
EndSelect
Until $msg = $GUI_EVENT_CLOSE


Func Example_2()
$listview = GUICtrlCreateListView("col1 |col2|col3 ", 100, 100, 200, 150);,$LVS_SORTDESCENDING)
$item1 = GUICtrlCreateListViewItem("item2|col22|col23", $listview)
$item2 = GUICtrlCreateListViewItem("item1|col12|col13", $listview)
$item3 = GUICtrlCreateListViewItem("item3|col32|col33", $listview)

GUICtrlCreateTabItem("") ; end tabitem definition
EndFunc ;==>Example_2

Note that the GUI is set visible after closing the tabitem definition.

orelse this

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $listview, $button, $item1, $item2, $item3, $msg

$hGUI = GUICreate("listview items", 400, 350, 100, 200)
GUISetBkColor(0x00E0FFFF) ; will change background color


GUICtrlCreateTab(10, 50, 380, 290)

GUICtrlCreateTabItem("tab0")

GUICtrlCreateTabItem("tab1")
Global $button = GUICtrlCreateButton("Value?", 75, 170, 70, 20)

$item2 = GUICtrlCreateTabItem("tab2")

GUICtrlCreateTabItem("") ; end tabitem definition

GUICtrlSetState(-1, $GUI_DROPACCEPTED) ; to allow drag and dropping
GUISetState()

Example_2()

Do
$msg = GUIGetMsg()

Select
Case $msg = $button
MsgBox(0, "listview item", GUICtrlRead(GUICtrlRead($listview)), 2)
Case $msg = $listview
MsgBox(0, "listview", "clicked=" & GUICtrlGetState($listview), 2)
EndSelect
Until $msg = $GUI_EVENT_CLOSE


Func Example_2()
GUISwitch( $hGUI, $item2)
$listview = GUICtrlCreateListView("col1 |col2|col3 ", 100, 90, 200, 150);,$LVS_SORTDESCENDING)
$item1 = GUICtrlCreateListViewItem("item2|col22|col23", $listview)
$item2 = GUICtrlCreateListViewItem("item1|col12|col13", $listview)
$item3 = GUICtrlCreateListViewItem("item3|col32|col33", $listview)
EndFunc ;==>Example_2

Edit: Firefox has posted before my editing Edited April 8, 2013 by PhoenixXL

[FireFox]

Hi,

Use the GUISwitch function.

Br, FireFox.

[mLipok]

thanks to You two

GUISwitch works correct

[mLipok]

by the way

I must say to myself RTFM

that was in HelpFile

but thanks for Your attention